Maya-如何取消动画分组并保留动画？

Question

有一些我想重用的旧动画，但是旧动画使用不同的轴（例如：old：面负Z，Y向上；新：面Y，负Z向上）。因此，我通过对动画进行分组并旋转该组使其面向右轴来解决此问题。但是当我取消分组时，它仅适用于当前帧（我将启用自动键）。

我搜索了多个论坛：

Grouping animated objects, Scaling, Ungrouping

Need help maintaining offset during ungroup

ungrouping but keeping animation

Grouping animated objects, Scaling, Ungrouping

但没有任何效果。

Answer 1

好，当您取消分组时，它适用于当前帧。因此，要使其适用于整个动画，可以对所有帧进行分组和取消分组。当然，我不会手工完成，但会使用脚本来完成。

proc GetPlaybackRange(string $bone, int $outStartEndTime[])
{
    float $arrKey[] = `keyframe -q $bone`;
    $arrKeyLength=size($arrKey);

    $outStartEndTime[0] = floor($arrKey[0]);
    $outStartEndTime[1] = ceil($arrKey[$arrKeyLength-1]);
}

proc UngroupAndGroupNextFrame(int $frame, string $groupName, float $transform[])
{
    currentTime $frame ;
    ungroup;

    currentTime ($frame + 1) ;
    group -n $groupName;
    xform -worldSpace -matrix 
    $transform[0]
    $transform[1]
    $transform[2]
    $transform[3]
    $transform[4]
    $transform[5]
    $transform[6]
    $transform[7]
    $transform[8]
    $transform[9]
    $transform[10]
    $transform[11]
    $transform[12]
    $transform[13]
    $transform[14]
    $transform[15]
    $groupName;
}

proc UnGroupForAnimation()
{
    string $sel[]= `ls -sl`;
    string $groupName = $sel[0];

    float $transform[];
    $transform = `xform -q -worldSpace -matrix $groupName`;

    string $bone[] = `listRelatives -children $groupName`;

    int $startEndTime[];
    GetPlaybackRange($bone[0], $startEndTime);

    for($i = $startEndTime[0]; $i <= $startEndTime[1]; $i++)
    {
        UngroupAndGroupNextFrame($i, $groupName, $transform);
    }
    currentTime ($startEndTime[1] + 1) ;
    ungroup;
    timeSliderClearKey;

    print ($bone[0] + " range "+$startEndTime[0]+" : "+$startEndTime[1]);
}

UnGroupForAnimation();

脚本的用法：

步骤1.选择组（组的子项应该是骨骼）

第2步。运行脚本。

就是这样。