Question

我尝试在Google上搜索图书馆，以便在CUDA上进行数字整合，但找不到任何库。

1）我想问一下，是否有可用于在CUDA上执行（功能）集成的库？

2）如果我在CUDA上编写自己的代码，例如实施Romberg集成，我该如何进行？假设我有功能，比如f(x);我是否需要针对不同的时间间隔计算此函数的积分，例如0.0 - 0.1，...，0.2 - 0.3，...，1.3 - 2.3？如何并行计算所有这些？

在我看来，策略是如果我必须执行，例如1000集成，我生成1000个线程，每个线程计算陷阱以及误差估计。但是，如果我想与其他积分并行计算积分区间之一的陷阱，我不知道如何以编程方式处理它。

Answer 1

正如Tera在他的评论中所提到的那样，从并行编程的角度来看，集成基本上是一种简化，因此在CUDA中实现集成的一种非常简单的方法是利用Thrust库的原语（另请参阅我的回答Simpson's method to integrate real valued functions with CUDA）。

下面是一个通过Thrust原语实现Romberg积分方法的简单示例。它是对此site提供的相应Matlab代码的“直接”翻译，因此该示例还显示了如何“简单地”将一些Matlab代码移植到CUDA，由Thurst。

#include <thrust/sequence.h>

#include <thrust/device_vector.h>
#include <thrust/host_vector.h>

#define pi_f  3.14159265358979f                 // Greek pi in single precision

struct sin_functor
{
    __host__ __device__
    float operator()(float x) const
    {
        return sin(2.f*pi_f*x);
    }
};

int main(void)
{
    int M = 5;                          // --- Maximum number of Romberg iterations

    float a     = 0.f;                  // --- Lower integration limit
    float b     = .5f;                  // --- Upper integration limit

    float hmin  = (b-a)/pow(2.f,M-1);   // --- Minimum integration step size 

    // --- Define the matrix for Romberg approximations and initialize to 1.f 
    thrust::host_vector<float> R(M*M,1.f);

    for (int k=0; k<M; k++) {

        float h = pow(2.f,k-1)*hmin;    // --- Step size for the k-th row of the Romberg matrix

        // --- Define integration nodes
        int N = (int)((b - a)/h) + 1;
        thrust::device_vector<float> d_x(N);
        thrust::sequence(d_x.begin(), d_x.end(), a, h);

        // --- Calculate function values
        thrust::device_vector<float> d_y(N);
        thrust::transform(d_x.begin(), d_x.end(), d_y.begin(), sin_functor());

        // --- Calculate integral
        R[k*M] = (.5f*h) * (d_y[0] + 2.f*thrust::reduce(d_y.begin() + 1, d_y.begin() + N - 1, 0.0f) + d_y[N-1]);

    }

    // --- Compute the k-th column of the Romberg matrix
    for (int k=1; k<M; k++) { 

        // --- The matrix of Romberg approximations is triangular!
        for (int kk=0; kk<(M-k+1); kk++) { 

            // --- See the Romberg integration algorithm
            R[kk*M+k] = R[kk*M+k-1] + (R[kk*M+k-1] - R[(kk+1)*M+k-1])/(pow(4.f,k)-1.f); 

        } 

    }

    // --- Define the vector Rnum for numerical approximations
    thrust::host_vector<float> Rnum(M); 
    thrust::copy(R.begin(), R.begin() + M, Rnum.begin());

    for (int i=0; i<M; i++) printf("%i %f\n",i,Rnum[i]);

    getchar();

    return 0;
}

使用CUDA的Romberg方法的数值积分

1 个答案: