Question

我有两个密切相关的问题：

首先，如何在Agda中对Haskell的Arrow类进行建模/表示？

 class Arrow a where 
      arr :: (b -> c) -> a b c
      (>>>) :: a b c -> a c d -> a b d
      first :: a b c -> a (b,d) (c,d)
      second :: a b c -> a (d,b) (d,c)
      (***) :: a b c -> a b' c' -> a (b,b') (c,c')
      (&&&) :: a b c -> a b c' -> a b (c,c')

（以下Blog Post表示应该可以......）

其次，在Haskell中，(->)是一等公民，只是另一个高阶类型，并且可以直接将(->)定义为Arrow类的一个实例。但在阿格达怎么样？我可能错了，但我觉得，Agdas ->是Agda的一个不可或缺的组成部分，而不是Haskell的->。那么，Agdas ->可以被视为高阶类型，即产生Set的类型函数可以成为Arrow的实例吗？

Answer 1

类型类通常被编码为Agda中的记录，因此您可以将Arrow类编码为：

open import Data.Product -- for tuples

record Arrow (A : Set → Set → Set) : Set₁ where
  field  
    arr    : ∀ {B C} → (B → C) → A B C
    _>>>_  : ∀ {B C D} → A B C → A C D → A B D
    first  : ∀ {B C D} → A B C → A (B × D) (C × D)
    second : ∀ {B C D} → A B C → A (D × B) (D × C)
    _***_  : ∀ {B C B' C'} → A B C → A B' C' → A (B × B') (C × C')
    _&&&_  : ∀ {B C C'} → A B C → A B C' → A B (C × C')

虽然你不能直接引用函数类型（像_→_这样的语法无效），你可以为它编写自己的名字，然后在编写实例时可以使用它：

_=>_ : Set → Set → Set
A => B = A → B

fnArrow : Arrow _=>_  -- Alternatively: Arrow (λ A B → (A → B)) or even Arrow _
fnArrow = record
  { arr    = λ f → f
  ; _>>>_  = λ g f x → f (g x)
  ; first  = λ { f (x , y) → (f x , y) }
  ; second = λ { f (x , y) → (x , f y) }
  ; _***_  = λ { f g (x , y) → (f x , g y) }
  ; _&&&_  = λ f g x → (f x , g x)
  }

Answer 2

虽然hammar的答案是Haskell代码的正确端口，但_=>_的定义与->相比过于有限，因为它不支持依赖函数。在调整Haskell中的代码时，如果要将抽象应用于可以在Agda中编写的函数，那么这是一个标准的必要更改。

此外，按照标准库的惯例，这个类型类将被称为RawArrow，因为为了实现它，你不需要提供你的实例满足箭头定律的证明;有关其他示例，请参阅RawFunctor和RawMonad（注意：从0.7版开始，Functor和Monad的定义在标准库中无处可见。）

这是一个更强大的变体，我用Agda 2.3.2和0.7标准库（也应该在0.6版本上工作）编写和测试。请注意，我只更改了RawArrow＆＃39}参数和_=>_的类型声明，其余部分未更改。但是，在创建fnArrow时，并非所有替代类型声明都像以前一样工作。

警告：我只检查了代码类型检查和那个=＆gt;可以理智地使用，我没有检查使用RawArrow类型检查的示例。

module RawArrow where

open import Data.Product --actually needed by RawArrow
open import Data.Fin     --only for examples
open import Data.Nat     --ditto

record RawArrow (A : (S : Set) → (T : {s : S} → Set) → Set) : Set₁ where
  field  
    arr    : ∀ {B C} → (B → C) → A B C
    _>>>_  : ∀ {B C D} → A B C → A C D → A B D
    first  : ∀ {B C D} → A B C → A (B × D) (C × D)
    second : ∀ {B C D} → A B C → A (D × B) (D × C)
    _***_  : ∀ {B C B' C'} → A B C → A B' C' → A (B × B') (C × C')
    _&&&_  : ∀ {B C C'} → A B C → A B C' → A B (C × C')

_=>_ : (S : Set) → (T : {s : S} → Set) → Set
A => B = (a : A) -> B {a}

test1 : Set
test1 = ℕ => ℕ
-- With → we can also write:
test2 : Set
test2 = (n : ℕ) → Fin n
-- But also with =>, though it's more cumbersome:
test3 : Set
test3 = ℕ => (λ {n : ℕ} → Fin n)
--Note that since _=>_ uses Set instead of being level-polymorphic, it's still
--somewhat limited. But I won't go the full way.

--fnRawArrow : RawArrow _=>_
-- Alternatively:
fnRawArrow : RawArrow (λ A B → (a : A) → B {a})

fnRawArrow = record
  { arr    = λ f → f
  ; _>>>_  = λ g f x → f (g x)
  ; first  = λ { f (x , y) → (f x , y) }
  ; second = λ { f (x , y) → (x , f y) }
  ; _***_  = λ { f g (x , y) → (f x , g y) }
  ; _&&&_  = λ f g x → (f x , g x)
  }

Haskell在Agda中的Arrow-Class和 - ＆gt;在阿格达

2 个答案: