Question

为什么函数组合（∘）和应用程序（$）具有https://github.com/agda/agda-stdlib/blob/master/src/Function.agda#L74-L76中可用的实现？为方便起见，在此处复制：

_∘_ : ∀ {a b c}
        {A : Set a} {B : A → Set b} {C : {x : A} → B x → Set c} →
        (∀ {x} (y : B x) → C y) → (g : (x : A) → B x) →
        ((x : A) → C (g x))
f ∘ g = λ x → f (g x)

_∘'_ : ∀ {a b c} {A : Set a} {B : Set b} {C : Set c} →
         (B → C) → (A → B) → (A → C)
f ∘' g = λ x → f (g x)

_$_ : ∀ {a b} {A : Set a} {B : A → Set b} →
      ((x : A) → B x) → ((x : A) → B x)
f $ x = f x

_$'_ : ∀ {a b} {A : Set a} {B : Set b} →
       (A → B) → (A → B)
f $' x = f x

最初，我认为这是因为$可以处理$'无法处理的高阶类型。例如，考虑A = Nat，B = List，f是 :: ，其中B取决于A。但是经过大量测试，我无法给出一个示例来表明$'的实现还不够。 $处理$'无法处理的哪些情况？（类似地，∘在什么情况下会处理∘'无法解决的问题？

open import Agda.Builtin.Nat public
open import Agda.Primitive public

--data List {a} (A : Set a) : Set a where
--  []  : List A
--  _∷_ : (x : A) (xs : List A) → List A

data Vec {a} (A : Set a) : Nat → Set a where
  []  : Vec A zero
  _∷_ : ∀ {n} (x : A) (xs : Vec A n) → Vec A (suc n)

tail : ∀ {a n} {A : Set a} → Vec A (suc n) → Vec A n
tail (x ∷ s) = s

_$_ : ∀ {a b} {A : Set a} {B : A → Set b} →
      ((x : A) → B x) → ((x : A) → B x)
f $ x = f x

_$'_ : ∀ {a b} {A : Set a} {B : Set b} →
       (A → B) → (A → B)
f $' x = f x

_∘_ : ∀ {a b c}
        {A : Set a} {B : A → Set b} {C : {x : A} → B x → Set c} →
        (∀ {x} (y : B x) → C y) → (g : (x : A) → B x) →
        ((x : A) → C (g x))
f ∘ g = λ x → f (g x)

_∘'_ : ∀ {a b c} {A : Set a} {B : Set b} {C : Set c} →
         (B → C) → (A → B) → (A → C)
f ∘' g = λ x → f (g x)

Vecc : ∀ {a} → Nat → (A : Set a) → (Set a)
Vecc x y = Vec y x

data Pair {a b} (A : Set a) (B : A → Set b) : Set (a ⊔ b) where
  _,_ : (x : A) → (y : B x) → Pair A B

-- Dependent Pair attempt
--fst : ∀ {a b} {A : Set a} {B : A → Set b} → Pair A B → A
--fst (a , b) = a
--
--f : Pair Nat $' Vec Nat
--f = _,_ zero $' []
--
--g : Pair (Pair Nat $' Vec Nat) $' λ x → Nat
--g = _,_ (_,_ zero $' []) $' zero

-- Some other attempt
--f : ∀ {a n} {A : Set a} → Vec A ((suc ∘' suc) n) → Vec A n
--f {a} = tail {a} ∘' tail {a}

-- Vec attempt
--f : ∀ {a} (A : Set a) → (Set a)
--f {a} = Vecc {a} (suc zero) ∘' Vecc {a} (suc zero)
--
--h = f Nat
--
--x : h
--x = (zero ∷ []) ∷ []

-- List attempt
--f : ∀ {a} (A : Set a) → (Set a)
--f {a} = List {a} ∘' List {a}
--
--g : ∀ {a} (A : Set a) → (Set a)
--g {a} = List {a} ∘ List {a}
--
--h = f Nat
--i = g Nat
--
--x : h
--x = (zero ∷ []) ∷ []

Answer 1

∘′和$′不适用于从属函数。您根本没有尝试使用依赖函数进行任何测试。对于f $ x示例，f必须是依赖的，对于f ∘ g，两个功能中的任何一个都必须是依赖的。示例：

open import Data.Nat
open import Data.Vec
open import Function
open import Relation.Binary.PropositionalEquality

replicate' : {A : Set} → A → (n : ℕ) → Vec A n
replicate' a n = replicate a

refl' : {A : Set}(a : A) → a ≡ a
refl' a = refl

-- fail1 : Vec ℕ 10
-- fail1 = replicate' 10 $′ 10

ok1 : Vec ℕ 10
ok1 = replicate' 10 $ 10

-- fail2 : ∀ n → replicate' 10 n ≡ replicate' 10 n
-- fail2 = refl' ∘′ replicate' 10

ok2 : ∀ n → replicate' 10 n ≡ replicate' 10 n
ok2 = refl' ∘ replicate' 10

Answer 2

如Andras Kovacs所述，其中一个可以使用依赖函数，而另一个则不能。

重要的区别在于，对于非依赖函数，可以构造更强的证明。例如：

eq : {A B} -> f : (A -> B) -> x y : A -> x == y -> (f x) == (f y)
eq f x .x refl = refl

在这里我们可以构造f x和f y的相等性。但是我们不能对依赖函数做同样的事情-因为没有办法证明B x == B y。因此，只有较弱的证据证明可以f x“投射”到f y。

transport : {A} {B : A -> Set} -> f : (x : A -> B x) -> x y : A -> x == y -> f x -> f y
transport f x .x refl fx = fx

（实际上，transport通常被定义为B x -> B y，而不是用于依赖函数；但是我只是想不出更好的名字）

为什么函数组成和应用程序在Agda中具有依赖的实现？

2 个答案: