Question

我想在2D平面中创建一组非退化的大量随机点云（整个集合中没有直线3个点）。我有一个天真的解决方案，它生成一个随机浮点对P_new（x，y），并检查到目前为止生成的每一对点（P1，P2），如果点（P1，P2，P）位于同一行或不同。这需要对添加到列表中的每个新点进行O（n ^ 2）检查，使得整个复杂度为O（n ^ 3），如果我想生成超过4000个点（需要超过40分钟），则非常慢。是否有更快的方法来生成这些非退化点？

Answer 1

您可以计算和比较线性方程的系数，而不是在每个循环迭代中检查可能的点共线性。这个系数应该存储在快速搜索的容器中。我考虑使用std :: set，但是unordered_map也可以适合，并且可以带来更好的结果。

总结一下，我建议采用以下算法：

生成随机点p;
计算p行A和现有点（我的意思是通常B，C＆amp; n）。在这里，您需要进行n*log(n^2)计算;
尝试在先前计算的集合中查找新计算的值。此步骤最多需要O(log(n))次操作。
如果是否定搜索结果，请添加新值并将其系数添加到相应的集合中。其成本约为O(n^2*log(n))。

整体复杂性降低到n^2*sizeof(Coefficient)。该算法需要额外存储{{1}}内存。但是，如果你只想计算4000点，这似乎没问题。

Answer 2

O（n ^ 2 log n）算法可以通过以下方式轻松构建：

对于集合中的每个点P：

按极角对其他点进行排序（交叉积作为比较函数，标准思路，参见2D凸壳礼品包装算法）。在此步骤中，您应该只考虑满足
的点Q.
```
Q.x > P.x || Q.y >= P.y
```
迭代排序列表，相等的点位于同一行。

在O（n log n）中完成排序，步骤2.是O（n）。这给出了O（n ^ 2 log n）来去除退化点。

Answer 3

确定一组点是否退化是3SUM-hard problem。（列出的第一个问题是确定三条线是否包含公共点;投射二元性下的等效问题是三个点是否属于公共线。）因此，希望生成和测试解决方案将是不合理的明显快于n ²。

您对发行的要求是什么？

Answer 4

生成随机点Q
以前的点数P计算(dx, dy) = P - Q
和B = (asb(dx) > abs(dy) ? dy/dx : dx/dy)
按照B值对P列表进行排序，这样与Q形成一条线的点将位于排序列表中的近位置。
遍历排序列表，检查Q在哪里形成一条线，其中包含正在考虑的当前P值以及一些接近给定距离的下一个值。

Perl实现：

#!/usr/bin/perl

use strict;
use warnings;
use 5.010;

use Math::Vector::Real;
use Math::Vector::Real::Random;
use Sort::Key::Radix qw(nkeysort);

use constant PI => 3.14159265358979323846264338327950288419716939937510;

@ARGV <= 2 or die "Usage:\n  $0 [n_points [tolerance]]\n\n";

my $n_points = shift // 4000;
my $tolerance = shift // 0.01;

$tolerance = $tolerance * PI / 180;
my $tolerance_arctan = 3 / 2 * $tolerance;
#     I got to that relation using no so basic maths in a hurry.
#     it may be wrong!

my $tolerance_sin2 = sin($tolerance) ** 2;

sub cross2d {
    my ($p0, $p1) = @_;
    $p0->[0] * $p1->[1] - $p1->[0] * $p0->[1];
}

sub line_p {
    my ($p0, $p1, $p2) = @_;
    my $a0 = $p0->abs2 || return 1;
    my $a1 = $p1->abs2 || return 1;
    my $a2 = $p2->abs2 || return 1;
    my $cr01 = cross2d($p0, $p1);
    my $cr12 = cross2d($p1, $p2);
    my $cr20 = cross2d($p2, $p0);
    $cr01 * $cr01 / ($a0 * $a1) < $tolerance_sin2 or return;
    $cr12 * $cr12 / ($a1 * $a2) < $tolerance_sin2 or return;
    $cr20 * $cr20 / ($a2 * $a0) < $tolerance_sin2 or return;
    return 1;
}

my ($c, $f1, $f2, $f3) = (0, 1, 1, 1);

my @p;
GEN: for (1..$n_points) {
    my $q = Math::Vector::Real->random_normal(2);
    $c++;
    $f1 += @p;
    my @B = map {
        my ($dx, $dy) = @{$_ - $q};
        abs($dy) > abs($dx) ? $dx / $dy : $dy / $dx;
    } @p;

    my @six = nkeysort { $B[$_] } 0..$#B;

    for my $i (0..$#six) {
        my $B0 = $B[$six[$i]];
        my $pi = $p[$six[$i]];
        for my $j ($i + 1..$#six) {
            last if $B[$six[$j]] - $B0 > $tolerance_arctan;
            $f2++;
            my $pj = $p[$six[$j]];
            if (line_p($q - $pi, $q - $pj, $pi - $pj)) {
                $f3++;
                say "BAD: $q $pi-$pj";
                redo GEN;
            }
        }
    }
    push @p, $q;
    say "GOOD: $q";
    my $good = @p;
    my $ratiogood = $good/$c;
    my $ratio12 = $f2/$f1;
    my $ratio23 = $f3/$f2;
    print STDERR "gen: $c, good: $good, good/gen: $ratiogood, f2/f1: $ratio12, f3/f2: $ratio23                                  \r";
}
print STDERR "\n";

当考虑三个点是否为π - max_angle(Q, Pi, Pj)时，公差表示可接受的度数误差。

没有考虑减去矢量时可能发生的数值不稳定性（即|Pi-Pj|可能比|Pi|小几个数量级）。消除该问题的一种简单方法是在任何两个给定点之间也需要最小距离。

设置1e-6的容差，程序只需几秒钟即可生成4000点。将它翻译成C / C ++可能会使它快两个数量级。

Answer 5

O（n）解决方案：

从0..1

r

添加到云端的点是P(cos(2 × π × r), sin(2 × π × r))

在2D - C ++中生成非退化点集

5 个答案: