Question

在OCaml中，似乎＆＃34;有趣＆＃34;是我的绑定操作符。 OCaml有内置替代吗？如果是，如何实施？是用de Bruijn指数实现的吗？

只想知道如何在OCaml中实现无类型的lambda演算，但是没有找到这样的实现。

Answer 1

作为Bromind，我也不能完全明白你的意思＆＃34; OCaml是否有内置替代？＆＃34;

关于lambda-calculus再一次我不太懂，但是，如果你在谈论编写某种lambda-calculus解释器，那么你需要首先定义你的＆＃34;语法＆＃34;：

(* Bruijn index *)
type index = int

type term =
  | Var of index
  | Lam of term
  | App of term * term

所以(λx.x) y将(λ 0) 1和我们的语法App(Lam (Var 0), Var 1)。

现在你需要实现减少，替换等等。例如，你可能有这样的东西：

(* identity substitution: 0 1 2 3 ... *)
let id i = Var i

(* particular case of lift substitution: 1 2 3 4 ... *)
let lift_one i = Var (i + 1)

(* cons substitution: t σ(0) σ(1) σ(2) ... *)
let cons (sigma: index -> term) t = function
  | 0 -> t
  | x -> sigma (x - 1)

(* by definition of substitution:
       1)  x[σ] = σ(x)
       2)  (λ t)[σ] = λ(t[cons(0, (σ; lift_one))])
               where (σ1; σ2)(x) = (σ1(x))[σ2]
       3)  (t1 t2)[σ] = t1[σ] t2[σ]
*)
let rec apply_subs (sigma: index -> term) = function
  | Var i -> sigma i
  | Lam t -> Lam (apply_subs (function
                              | 0 -> Var 0
                              | i -> apply_subs lift_one (sigma (i - 1))
                             ) t)
  | App (t1, t2) -> App (apply_subs sigma t1, apply_subs sigma t2)

正如您所看到的，OCaml代码只是直接重写定义。

现在小步减少：

let is_value = function
  | Lam _ | Var _ -> true
  | _ -> false

let rec small_step = function
  | App (Lam t, v) when is_value v ->
     apply_subs (cons id v) t
  | App (t, u) when is_value t ->
     App (t, small_step u)
  | App (t, u) ->
     App (small_step t, u)
  | t when is_value t ->
     t
  | _ -> failwith "You will never see me"

let rec eval = function
  | t when is_value t -> t
  | t -> let t' = small_step t in
         if t' = t then t
         else eval t'

例如，您可以评估(λx.x) y：

eval (App(Lam (Var 0), Var 1))
- : term = Var 1

Answer 2

我并不完全明白你的意思是说“OCaml是否有内置替换？......”，但关于如何在OCaml中实现lambda演算，你确实可以使用fun ：只需用fun替换所有lambdas，例如：对于教会数字：你知道zero = \f -> (\x -> x)，one = \f -> (\x -> f x)，所以在Ocaml，你有

let zero = fun f -> (fun x -> x)
let succ = fun n -> (fun f -> (fun x -> f (n f x)))

和succ zero按预期为您提供one，即fun f -> (fun x -> f x)（要突出显示它，您可以尝试(succ zero) (fun s -> "s" ^ s) ("0")或(succ zero) (fun s -> s + 1) (0)）。

据我记忆，您可以使用let和fun来更改评估策略，但需要确认...

N.B。：我把所有的括号都说清楚了，也许有些可以删除。

Answer 3

OCaml不执行正常顺序缩减并使用按值调用语义。 lambda演算的Some terms具有与evaluation strategy无法达到的正常形式。

请参阅The Substitution Model of Evaluation以及How would you implement a beta-reduction function in F#?。

如何在OCaml中实现lambda-calculus？

3 个答案: