Question

我想在Coq中使用Program Fixpoint或Function定义以下函数：

Require Import Coq.Lists.List.
Import ListNotations.
Require Import Coq.Program.Wf.
Require Import Recdef.

Inductive Tree := Node : nat -> list Tree -> Tree.

Fixpoint height (t : Tree) : nat :=
  match t with
   | Node x ts => S (fold_right Nat.max 0 (map height ts))
  end.

Program Fixpoint mapTree (f : nat -> nat) (t : Tree)  {measure (height t)} : Tree :=
  match t with 
    Node x ts => Node (f x) (map (fun t => mapTree f t) ts)
  end.
Next Obligation.

不幸的是，此时我有一个证明义务height t < height (Node x ts)而不知道t是ts的成员。

与Function而不是Program Fixpoint类似，只有Function检测到问题并中止定义：

Error:
the term fun t : Tree => mapTree f t can not contain a recursive call to mapTree

我希望获得In t ts → height t < height (Node x ts)的证明义务。

有没有办法解决不涉及重组函数定义的问题？（我知道需要在此处列出map的定义的解决方法 - 例如 - 我想避免这些。）

伊莎贝尔

为了证明这种期望，让我展示一下当我在Isabelle中使用function命令（即AFAIK）与Coq的Function命令相关时所发生的事情：

theory Tree imports Main begin

datatype Tree = Node nat "Tree list"

fun height where
  "height (Node _ ts) = Suc (foldr max (map height ts) 0)"

function mapTree where
  "mapTree f (Node x ts) = Node (f x) (map (λ t. mapTree f t) ts)"
by pat_completeness auto

termination
proof (relation "measure (λ(f,t). height t)")
  show "wf (measure (λ(f, t). height t))" by auto
next
  fix f :: "nat ⇒ nat" and x :: nat  and ts :: "Tree list" and t
  assume "t ∈ set ts"
  thus "((f, t), (f, Node x ts))  ∈ measure (λ(f, t). height t)"
    by (induction ts) auto
qed

在终止证明中，我得到了假设t ∈ set ts。

请注意，Isabelle此处不需要手动终止证明，以下定义也可以正常使用：

fun mapTree where
  "mapTree f (Node x ts) = Node (f x) (map (λ t. mapTree f t) ts)"

这是有效的，因为map函数具有

形式的“同余引理”

xs = ys ⟹ (⋀x. x ∈ set ys ⟹ f x = g x) ⟹ map f xs = map g ys

function命令用于查明终止证明只需要考虑t ∈ set ts ..

如果没有这样的引理，例如因为我定义了

definition "map' = map"

并在mapTree中使用它，我得到与Coq相同的无法证明的证明义务。我可以通过声明map'的同余引理再次使其工作，例如使用

declare map_cong[folded map'_def,fundef_cong]

Answer 1

在这种情况下，你实际上并不需要完全通用的有根据的递归：

Require Import Coq.Lists.List.

Set Implicit Arguments.

Inductive tree := Node : nat -> list tree -> tree.

Fixpoint map_tree (f : nat -> nat) (t : tree) : tree :=
  match t with
  | Node x ts => Node (f x) (map (fun t => map_tree f t) ts)
  end.

Coq能够自己弄清楚对map_tree的递归调用是在严格的子节点上执行的。但是，证明有关此函数的任何内容都很困难，因为为tree生成的归纳原则没有用处：

tree_ind : 
  forall P : tree -> Prop, 
    (forall (n : nat) (l : list tree), P (Node n l)) ->
    forall t : tree, P t

这与您之前描述的问题基本相同。幸运的是，我们可以通过证明我们自己的归纳原则来解决这个问题。

Require Import Coq.Lists.List.
Import ListNotations.

Unset Elimination Schemes.
Inductive tree := Node : nat -> list tree -> tree.
Set Elimination Schemes.

Fixpoint tree_ind
  (P : tree -> Prop)
  (IH : forall (n : nat) (ts : list tree),
          fold_right (fun t => and (P t)) True ts ->
          P (Node n ts))
  (t : tree) : P t :=
  match t with
  | Node n ts =>
    let fix loop ts :=
      match ts return fold_right (fun t' => and (P t')) True ts with
      | [] => I
      | t' :: ts' => conj (tree_ind P IH t') (loop ts')
      end in
    IH n ts (loop ts)
  end.

Fixpoint map_tree (f : nat -> nat) (t : tree) : tree :=
  match t with
  | Node x ts => Node (f x) (map (fun t => map_tree f t) ts)
  end.

Unset Elimination Schemes命令阻止Coq为tree生成其默认（无用）归纳原则。归纳假设上fold_right的出现只表示P中出现的每个树t'的谓词ts。

以下是您可以使用此归纳原则证明的声明：

Lemma map_tree_comp f g t :
  map_tree f (map_tree g t) = map_tree (fun n => f (g n)) t.
Proof.
  induction t as [n ts IH]; simpl; f_equal.
  induction ts as [|t' ts' IHts]; try easy.
  simpl in *.
  destruct IH as [IHt' IHts'].
  specialize (IHts IHts').
  now rewrite IHt', <- IHts.
Qed.

Answer 2

通常，建议避免此问题。但如果一个人真的想获得伊莎贝尔给你的证明义务，这是一种方式：

在Isabelle中，我们可以给出一个外部引理，即map仅将其参数应用于给定列表的成员。在Coq中，我们不能在外部引理中执行此操作，但我们可以在类型中执行此操作。而不是普通类型的地图

forall A B, (A -> B) -> list A -> list B

我们希望该类型说“f仅适用于列表中的元素：

forall A B (xs : list A), (forall x : A, In x xs -> B) -> list B

（它需要重新排序参数，以便f的类型可以提及xs）。

编写此函数并非易事，我发现使用校对脚本更容易：

Definition map {A B} (xs : list A) (f : forall (x:A), In x xs -> B) : list B.
Proof.
  induction xs.
  * exact [].
  * refine (f a _ :: IHxs _).
    - left. reflexivity.
    - intros. eapply f. right. eassumption.
Defined.

但你也可以“手工”写下来：

Fixpoint map {A B} (xs : list A) : forall (f : forall (x:A), In x xs -> B), list B :=
  match xs with
   | [] => fun _ => []
   | x :: xs => fun f => f x (or_introl eq_refl) :: map xs (fun y h => f y (or_intror h))
  end.

在任何一种情况下，结果都很好：我可以在mapTree中使用此功能，即

Program Fixpoint mapTree (f : nat -> nat) (t : Tree)  {measure (height t)} : Tree :=
  match t with 
    Node x ts => Node (f x) (map ts (fun t _ => mapTree f t))
  end.
Next Obligation.

我不需要对f的新参数做任何事情，但它会在终止证明义务中显示，如In t ts → height t < height (Node x ts)所示。所以我可以证明并定义mapTree：

  simpl.
  apply Lt.le_lt_n_Sm.
  induction ts; inversion_clear H.
  - subst. apply PeanoNat.Nat.le_max_l.
  - rewrite IHts by assumption.
    apply PeanoNat.Nat.le_max_r.
Qed.

不幸的是，它仅适用于Program Fixpoint，而不适用于Function。

Answer 3

您现在可以使用方程式执行此操作，并使用structural nested recursion或well-founded recursion

自动获取正确的消除原则

嵌套递归和`程序Fixpoint`或`Function`

伊莎贝尔

3 个答案: