Question

简介：我认为Nape是一个相对较新的引擎，所以有些人可能不知道它。它应该比box2d更快，我喜欢有体面的文档。这是网站：http://code.google.com/p/nape/

我对编程比较陌生。我很擅长AS3的基本功能，但每次我尝试实现某种引擎或框架时，我似乎都无法让它工作。有了Nape我觉得我比以前更进一步，但我仍然陷入困境。

我的问题：我正在使用Adobe CS5，我设法导入了如here所述的SWC文件。接下来，我尝试复制其中一个演示的源代码，如this one，并让它工作，但我一直在收到错误。我制作了一个新的类文件，将演示源复制到它，并尝试将其添加到舞台上。

我的舞台代码基本上是这样的：

import flash.Boot; // these 2 lines are as described in the tutorial
new Boot(); 

var demo = new Main(); // these 2 are me guessing what I'm supposed to do
addChild(demo);

好吧，似乎源代码甚至不被flash识别为有效的类文件。我尝试编辑它，但即使我得到它识别（给出一个包名并添加大括号）但我仍然得到一堆错误。它是伪造的代码还是什么？发生了什么事？

我的目标：我可以想象我会以错误的方式解决这个问题。那么让我解释一下我想要实现的目标。我基本上想学习如何使用引擎，从一个简单的基本示例开始，我可以编辑和乱用。如果我甚至无法得到一个有效的例子那么我就无法学到任何东西。我最好不要开始使用像FlashDevelop这样的东西（因为我必须学习如何使用该程序）但是如果它无法帮助那么我可以尝试一下。

Answer 1

网站上的代码示例是Haxe，而不是ActionScript，它解释了添加“包”时出现的错误。

以下是ActionScript类的修改版本：

package{ 

import flash.display.Graphics; 
import flash.display.Sprite; 
import flash.events.Event; 
import flash.events.MouseEvent; 
import flash.display.StageQuality; 

import nape.space.Space; 
import nape.space.UniformSleepSpace; 
import nape.util.Tools; 
import nape.geom.Vec2; 
import nape.geom.GeomPoly; 
import nape.phys.PhysObj; 
import nape.phys.Material; 
import nape.geom.AABB; 

//- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -  

public class Main extends Sprite
{ 
        private var space:Space; 

        private var g:Graphics; 
        private var vl:Array; 
        private var px:Number; private var py:Number; 

        //- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -  

        private function mouseDown(ev:MouseEvent):void { 
                var x = stage.mouseX; 
                var y = stage.mouseY; 

                g.lineStyle(1, 0, 0.5); 
                vl.push(new Vec2(x, y)); 
                g.moveTo(x, y); 
                px = x; py = y; 
        } 

        private function mouseUp(ev:MouseEvent):void { 
                if (vl.length >= 3) { 
                        var poly = new GeomPoly(vl); 
                        poly.simplify(50, 4); 
                        if (!poly.selfIntersecting()) { 
                                if (!poly.cw()) poly.points.reverse(); 

                                var p = Tools.createConcave(poly, 0, 0, 0, false, Material.Wood); 
                                space.addObject(p); 
                                addChild(p.graphic); 
                        } 
                } 
                g.clear(); 
                vl = new Array(); 
                px = -100; 
        } 

        //- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -  

        public function init(ev:Event = null)
        { 
                var s = new Sprite(); 
                g = s.graphics; 
                addChild(s); 
                s.cacheAsBitmap = true; 
                vl = new Array(); 
                px = -100; 

                space = new UniformSleepSpace(new AABB(0,0, 800,600), 30, new Vec2(0, 250)); 

                var p:PhysObj; 
                space.addObject(p = Tools.createBox(-20, 300, 50, 600, 0, 0, 0, true, Material.Wood)); 
                addChild(p.graphic); 
                space.addObject(p = Tools.createBox(820, 300, 50, 600, 0, 0, 0, true, Material.Wood)); 
                addChild(p.graphic); 
                space.addObject(p = Tools.createBox(400, -20, 800, 50, 0, 0, 0, true, Material.Wood)); 
                addChild(p.graphic); 
                space.addObject(p = Tools.createBox(400, 620, 800, 50, 0, 0, 0, true, Material.Wood)); 
                addChild(p.graphic); 

                stage.quality = StageQuality.MEDIUM; 
                stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDown); 
                stage.addEventListener(MouseEvent.MOUSE_UP,   mouseUp); 
                stage.addEventListener(Event.ENTER_FRAME,     enterFrame); 
        } 

        //- - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -  

    private function enterFrame(ev:Event) { 
                graphics.clear(); 
                graphics.lineStyle(1, 0, 1); 
                if (px != -100) { 
                        var x = stage.mouseX; 
                        var y = stage.mouseY; 
                        var dx = x - px; var dy = y - py; 
                        if (dx * dx + dy * dy > 5) { 
                                vl.push(new Vec2(x, y)); 
                                px = x; py = y; 
                                g.lineTo(x, y); 
                        }else { 
                                graphics.moveTo(px, py); 
                                graphics.lineTo(x, y); 
                        } 
                } 

        space.step(1/60, 6, 6); 
        } 
}
}

这是时间轴代码：

import flash.Boot; 
new Boot();

var m:Main = new Main();
m.addEventListener(Event.ADDED_TO_STAGE, m.init);
addChild(m)

此设置的fla应为800x600，frameRate为60。另外，请注意我已将构造函数更改为init方法。那是因为在那里访问舞台，直到Main的实例被添加到舞台，对舞台的引用将为空。

对于刚开始编程的人来说，混合AS3和Haxe并不容易。如果你对Haxe感兴趣，那就去吧，否则，为了更简单的2D物理，我建议给Box2D World Construction Kit一个去。它允许您使用组件定义直接在IDE中对世界进行原型设计，并且它应该比直接AS3端口快一点，因为它使用Alchemy。

World Construction Kit

此外，还有gotoAndLearn免费的介绍性视频教程，可帮助您入门。

古德勒克！

如何让像Nape这样的物理引擎工作？

1 个答案: