如何确定scilab 3dplot中顶点的方向？

Question

我想在scilab（3d）中绘制一个简单的对象。为了理解scilab在这方面的工作方式，我写了以下例子：

xx = [[2;2;1;3;],[2;2;3;3],[2;2;3;1],[2;2;1;1],[1;3;3;1],[3;3;3;3],[3;3;1;1],[1;1;1;1],[1;2;2;3],[1;1;2;2],[3;2;2;3],[3;2;2;1]]

yy = [[2;2;1;1;],[2;2;1;3],[2;2;3;3],[2;2;3;1],[1;1;1;1],[1;3;3;1],[3;3;3;3],[3;1;1;3],[1;2;2;1],[1;3;2;2],[1;2;2;3],[3;2;2;3]]

zz = [[0;0;1;1;],[0;0;1;1],[0;0;1;1],[0;0;1;1],[1;1;2;2],[1;1;2;2],[1;2;2;1],[1;1;2;2],[2;3;3;2],[2;2;3;3],[2;3;3;2],[2;3;3;2]]

col = ones(12,1)*3

plot3d(xx,yy,list(zz,col))
//h = get("hdl")
//h.hiddencolor = -1 // backside and frontside same color

具有以下结果：

虽然结构是绝对精细的，但两面上的着色是内在的。我试图以逆时针/顺时针方向以不同的方式绘制受影响面部的点，不同的起点等等。但是面部似乎保持向内的结构。我通过将面的背面设置为等于前端（代码中的2个注释行）找到了一种解决方法，但我想了解scilab如何确定面部的方向以便以后的工作。有线索吗？

编辑：

所以我尝试了PTRK的建议。虽然他提供的矩阵肯定是不同的：

结果仍然相同。即使提供的Testscript的输出也不同：

也许这就是某种版本/系统的东西？我在Windows 10上使用Scilab 6.0.0。

Answer 1

让一个表面由3个节点定义：[P1，P2，P3]。然后，您必须顺时针循环通过这些节点，以获得内部和外部的正确方向。这是一张解释它的图：

3个多边形是逆时针定义的，y = 1，y = 3和x = 1。当绘制4个点多边形时，要将旋转从顺时针切换到逆时针，只需交换第2个和第4个节点或第1个和第1个节点。第三

因此，您必须将您的积分设为：

xx = [[2;2;1;3;],[2;2;3;3],[2;2;3;1],[2;2;1;1],[1;1;3;3],[3;3;3;3],[3;3;1;1],[1;1;1;1],[1;2;2;3],[1;1;2;2],[3;2;2;3],[3;2;2;1]]

yy = [[2;2;1;1;],[2;2;1;3],[2;2;3;3],[2;2;3;1],[1;1;1;1],[1;1;3;3],[3;3;3;3],[3;3;1;1],[1;2;2;1],[1;3;2;2],[1;2;2;3],[3;2;2;3]]

zz = [[0;0;1;1;],[0;0;1;1],[0;0;1;1],[0;0;1;1],[1;2;2;1],[1;2;2;1],[1;2;2;1],[1;2;2;1],[2;3;3;2],[2;2;3;3],[2;3;3;2],[2;3;3;2]]

这将提供所需的输出：

Scilab 6.0.0 bug

在这个版本中，如果曲面与笛卡尔坐标轴平行，那么Scilab将沿着轴指向它，无论你如何定义它。因此你的问题。解决方法可能是通过一个小的delta来抵消一个坐标，这个delta必须不能太小，如下例所示。

关于你的问题，如果我们想要保持你的对象的几何形状，我们可以用一个小角度倾斜它：使用rotation matrix，如果由所有坐标的旋转引起的计算成本不打扰您。这是带有倾斜对象的脚本

clc
clear
xdel(winsid())

xx = [[2;2;1;3;],[2;2;3;3],[2;2;3;1],[2;2;1;1],[1;1;3;3],[3;3;3;3],[3;3;1;1],[1;1;1;1],[1;2;2;3],[1;1;2;2],[3;2;2;3],[3;2;2;1]]

yy = [[2;2;1;1;],[2;2;1;3],[2;2;3;3],[2;2;3;1],[1;1;1;1],[1;1;3;3],[3;3;3;3],[3;3;1;1],[1;2;2;1],[1;3;2;2],[1;2;2;3],[3;2;2;3]]

zz = [[0;0;1;1;],[0;0;1;1],[0;0;1;1],[0;0;1;1],[1;2;2;1],[1;2;2;1],[1;2;2;1],[1;2;2;1],[2;3;3;2],[2;2;3;3],[2;3;3;2],[2;3;3;2]]

col = ones(12,1)*3

figure(1)
set(gcf(),'background',-2)
subplot(2,1,1)
plot3d(xx,yy,list(zz,col))
title('Object with surfaces orthogonal to cartesian axis')
subplot(2,1,2)
// t is angle in radian showing the tilt
t = %pi/10000
c = cos(t)
s = sin(t)
rot = [1,0,0;0,c,-s;0,s,c]*[c,0,s;0,1,0;-s,0,c]*[c,-s,0;s,c,0;0,0,1]
for i=1:size(xx,1)
  for j = 1:size(xx,2)
   xyz=(rot*[xx(i,j);yy(i,j);zz(i,j)])
   x(i,j)=xyz(1)
   y(i,j)=xyz(2)
   z(i,j)=xyz(3)
  end
end
plot3d(x,y,list(z,col))
title('Object with surfaces tildted by an angle of '+string(t)+' rad')

脚本显示由相同节点定义的2个曲面，但顺序相反。

clc
clear
xdel(winsid())

figure(1)
set(gcf(),'background',-2)
cr=color('red') // color of the outside surface

P1 = [0,0,0] //
P2 = [0,1,0]
P3 = [1,0,0]

F1 = [P1;P2;P3] // defining surface clockwise
F2 = [P1;P3;P2] //                  counterclockwise

subplot(2,2,1)
plot3d(F1(:,1),F1(:,2),list(F1(:,3),cr*ones(F1(:,3))))
xstring(F1(:,1),F1(:,2),['P1','P2','P3']) 
title('surface is [P1,P2,P3] with z_P3=0')
set(gca(),'data_bounds',[0,1,0,1,-1,1])

subplot(2,2,2)
plot3d(F2(:,1),F2(:,2),list(F2(:,3),cr*ones(F2(:,3))))
xstring(F2(:,1),F2(:,2),['P1','P3','P2'])
title('surface is [P1,P3,P2] with z_P3=0, broken with Scilab 6.0.0')
set(gca(),'data_bounds',[0,1,0,1,-1,1])

subplot(2,2,3)
plot3d(F2(:,1),F2(:,2),list(F2(:,3)+[0;0;10^-7],cr*ones(F2(:,3))))
xstring(F2(:,1),F2(:,2),['P1','P3','P2'])
title('surface is [P1,P3,P2] with |z_P3| < 10^-8')
set(gca(),'data_bounds',[0,1,0,1,-1,1])

subplot(2,2,4)
plot3d(F2(:,1),F2(:,2),list(F2(:,3)+[0;0;10^-8],cr*ones(F2(:,3))))
xstring(F2(:,1),F2(:,2),['P1','P3','P2'])
title('surface is [P1,P3,P2] with |z_P3| = 10^-8, broken in 6.0.0')
set(gca(),'data_bounds',[0,1,0,1,-1,1])

Scilab 5.5.1

Scilab 6.0.0