Question

Emacs Lisp中的foldr，foldl相当于什么？

Answer 1

如果你

(require 'cl)

然后你可以使用Common Lisp函数reduce。为:from-end t传递关键字参数foldr。

ELISP> (reduce #'list '(1 2 3 4))
(((1 2) 3) 4)

ELISP> (reduce #'list '(1 2 3 4) :from-end t)
(1 (2 (3 4)))

Answer 2

从Emacs-24.3开始，我们建议使用cl-lib而不是cl（计划在不久的将来删除），所以它会是：

(require 'cl-lib)
(cl-reduce #'+ '(1 2 3 4))

从Emacs-25开始，你也可以使用seq包：

(require 'seq)
(seq-reduce #'+ '(1 2 3 4) 0)

Answer 3

Common Lisp library提供了大量sequence functions映射，过滤，折叠，搜索甚至排序。默认情况下，CL库随Emacs一起提供，因此您应该坚持使用它。然而，我真的很喜欢dash.el库，因为它为列表和树操作提供了大量的功能。它还支持anaphoric macros并鼓励函数式编程，这使代码简洁而优雅。

Haskell的折叠符合dash.el折叠：

foldl与-reduce-from
foldr与-reduce-r-from
foldl1与-reduce
foldr1与-reduce-r

使用折叠的范围1到10的总和可能在Haskell和dash.el中看起来像这样：

foldl (+) 0 [1..10] -- Haskell
(-reduce-from '+ 0 (number-sequence 1 10)) ; Elisp

您可能知道，折叠是非常通用的，并且可以通过折叠实现地图和过滤器。例如，要将每个元素递增2，Haskell的currying和section将允许简洁的代码，但在Elisp中，你通常会编写这样的详细的一次性lambdas：

foldr ((:) . (+2)) [] [1..10] -- Haskell
(-reduce-r-from (lambda (x acc) (cons (+ x 2) acc)) '() (number-sequence 1 10)) ; Elisp

猜测dash.el中是否有必要使用回指宏，它允许通过将lambda的变量暴露为快捷方式（如it和acc来实现特殊语法。照应函数以2个破折号开始，而不是1：

(--reduce-r-from (cons (+ it 2) acc) '() (number-sequence 1 10))

dash.el中有很多类似折叠的函数：

;; Count elements matching a predicate
(-count 'evenp '(1 2 3 4 5)) ; 2
;; Add/multiply elements of a list together
(-sum '(1 2 3 4 5)) ; 15
(-product '(1 2 3 4 5)) ; 120
;; Find the smallest and largest element
(-min '(3 1 -1 2 4)) ; -1
(-max '(-10 0 10 5)) ; 10
;; Find smallest/largest with a custom rule (anaphoric versions)
(--min-by (> (length it) (length other)) '((1 2 3) (4 5) (6))) ; (6)
(--max-by (> (length it) (length other)) '((1 2 3) (4 5) (6))) ; (1 2 3)

什么相当于Emacs Lisp中的foldr，foldl？

3 个答案: