Question

我想要做的是Autodesk Inventor。我编写的程序遍历草图中的一堆行。它收集连接线组并将它们放入一个集合中。然后它会处理这些集合的集合。

我试图通过将行添加到临时集合中，然后将此临时集合添加到循环集合中来实现此目的，这样我就不必为每个集合生成未知数量的集合环。但是，只要我使用Clear方法重置临时集合，它就会删除我刚刚推入循环集合的信息。有没有办法让循环集合中的信息独立于临时集合中的信息？

正如您所看到的，问题是我永远不知道将连接多少行，因此我永远不知道会有多少个子集合。

这是我的代码。

Dim oLoopColl As New Collection
Dim oSubColl As ObjectCollection
Set oSubColl = ThisApplication.TransientObjects.CreateObjectCollection

For j = 1 To oSLColl.Count
    oSubColl.Add (oSLColl.Item(j))
    'Check for last item to see if it is part of the first
    If j = oSLColl.Count Then
        If oSLColl.Item(j).EndSketchPoint Is oSLColl.Item(1).StartSketchPoint Then
            MsgBox ("Last SL is part of first coll!")
            oLoopColl.Item(1).Add (oSLColl.Item(j))
            oSubColl.Clear
        Else
            Call oLoopColl.Add(oSubColl, CStr(j))
        End If
    Else
        If Not oSLColl.Item(j).EndSketchPoint Is oSLColl.Item(j + 1).StartSketchPoint Then
            Call oLoopColl.Add(oSubColl, CStr(j))
            oSubColl.Clear
        End If
    End If
Next
oSubColl.Clear
Set oSubColl = Nothing

Answer 1

我在评论中试图说的是以下内容。在示例中，您可以看到没有必要知道items中container的数量。

新item应添加到container创建一个：

Set item = New Collection

然后将项添加到此新item

item.Add "Some-New-Item"

最后将这个新item的引用添加到container

container.Add item

container现在保存对item所在的内存位置的引用。所以可以添加下一个项目，然后添加下一个项目，依此类推。

Option Explicit

Private Const ColItem As String = "Col_Item_"

Sub Demo()
    Dim container As VBA.Collection
    Dim item As VBA.Collection

    Set container = New Collection

    Set item = New Collection
    item.Add ColItem & 1
    item.Add ColItem & 11
    item.Add ColItem & 111
    container.Add item

    Set item = New Collection
    item.Add ColItem & 2
    item.Add ColItem & 22
    item.Add ColItem & 222
    container.Add item

    ' Clear is not part of VBA-Collection so Remove-all could simulate it
    ' When Clear would be called here then all the items will be removed
    ' and the container will reference an empty collection
    item.Remove 2

    Dim outer, inner
    For Each outer In container
        For Each inner In outer
            Debug.Print inner
        Next inner
    Next outer
End Sub

输出：

Col_Item_1
Col_Item_11
Col_Item_111
Col_Item_2
Col_Item_222

请参阅why not use As New。

集合的集合 - 如何通过值而不是引用来创建子集合？

1 个答案: