在Delphi

Question

我有一个关于我必须将UTF8字符串转换为ANSI字符串的代码的问题。我的代码适用于元音中的重音，但是用字母Ñ它不起作用。代码打破了字符串。我该如何解决这个错误？

我在UTF8中的字符串：EDIFICIOPEÃ'ASLANYAS
如果正确的话我会在ANSI中使用的字符串：EDIFICIOPEÑASBLANCAS
我现在在ANSI中的字符串：EDIFICIO PE

代码在这里：

    function TFormMain.convertir_utf8_ansi(const Source: string):string;
    var
       Iterator, SourceLength, FChar, NChar: Integer;
    begin
       Result := '';
       Iterator := 0;
       SourceLength := Length(Source);
       while Iterator < SourceLength do
       begin
          Inc(Iterator);
          FChar := Ord(Source[Iterator]);
          if FChar >= $80 then
          begin
             Inc(Iterator);
             if Iterator > SourceLength then break;
             FChar := FChar and $3F;
             if (FChar and $20) <> 0 then
             begin
                FChar := FChar and $1F;
                NChar := Ord(Source[Iterator]);
                if (NChar and $C0) <> $80 then break;
                FChar := (FChar shl 6) or (NChar and $3F);
                Inc(Iterator);
                if Iterator > SourceLength then break;
             end;
             NChar := Ord(Source[Iterator]);
             if (NChar and $C0) <> $80 then break;
             Result := Result + WideChar((FChar shl 6) or (NChar and $3F));
          end
          else
             Result := Result + WideChar(FChar);
       end;
    end;

感谢。

Answer 1

如果您使用的是Delphi 2009或更高版本，则应让RTL为您进行转换：

type
  Latin1String = type AnsiString(28591); // codepage 28591 = ISO-8859-1
var
  utf8: UTF8String;
  latin1: Latin1String;
begin
  utf8 := ...; // your source UTF-8 string
  latin1 := Latin1String(utf8);
end;

如果您使用的是Delphi 2007或更早版本，您仍然可以进行转换，只需让操作系统为您完成：

var
  utf8: UTF8String;
  latin1: AnsiString;
  ws: WideString;
  len: Integer;
begin
  utf8 := ...; // your source UTF-8 string
  len := MultiByteToWideChar(CP_UTF8, 0, PAnsiChar(utf8), Length(utf8), nil, 0);
  SetLength(ws, len);
  MultiByteToWideChar(CP_UTF8, 0, PAnsiChar(utf8), Length(utf8), PWideChar(ws), len);
  len := WideCharToMultiByte(28591, 0, PWideChar(ws), Length(ws), nil, 0, nil, nil);
  SetLength(latin1, len);
  WideCharToMultiByte(28591, 0, PWideChar(ws), Length(ws), PAnsiChar(latin1), len, nil, nil);
end;

Answer 2

除了我的函数之外，我解决了调用问题的内部函数UTF8toAnsi。我正在研究Delphi 2010.

这样： Utf8toAnsi（con​​vertir_utf8_ansi（源））;