Question

我正在尝试为基于SPI的IO扩展器创建通用驱动程序。我们的想法是在实例化中传递与所请求的IO设置匹配的初始化值。

我目前的尝试看起来像这样：

entity max7301_simple is
   generic ( 
        IO_cfg : array (1 to 7) OF integer range 0 to 255 := (16#55#, 16#55#, 16#55#, 16#55#, 16#55#, 16#55#, 16#55#)
           );
     port  (
        -- Application interface :
        clk_i       :   in std_logic;        -- input clock, xx MHz.
        rst_i       :   in std_logic;        -- sync reset.
        en_i        :   in std_logic;        -- enable, forces re-init of pins on MAX7301.
        output_i    :   in std_logic_vector(27 downto 0);   --data to write to output pins on MAX7301
        irq_o       :   out std_logic;       -- IRQ, TODO: what triggers, change on inputs ?
        input_o     :   out std_logic_vector(27 downto 0);  --data read from input pins on MAX7301
        -- MAX7301 SPI interface
        sclk        :   out std_logic;        -- SPI clock
        din         :   in std_logic;        -- SPI data input
        dout        :   out std_logic;       -- SPI read data
        cs          :   out std_logic        -- SPI chip select
    );
end max7301_simple;

问题在于IO_cfg数组，我尝试了各种尝试w / wo init值等。似乎无法想象如何指定数组。

我相信已经读过你可以传递一个数组作为通用数据，但仍然没有太多运气。 Xilinx ISE只是告诉med“'数组'附近的语法错误”，这些信息不足以让我前进。

任何帮助将不胜感激

实例化此模块时，我总是需要7个值。

Answer 1

您可以使用数组作为通用参数，但不允许声明在那里，即时作为匿名类型。

您必须首先在单独的包中声明您的整数数组类型（可以在同一个文件中或在单独的文件中），然后use实体中的包以及实例化时。

以下是如何执行此操作的示例：

-- package declaration
package mytypes_pkg is

     type my_array_t is array (1 to 7) of integer range 0 to 255;

end package mytypes_pkg;

-- entity "uses" the package   
use work.mytypes_pkg.all;

entity max7301_simple is
   generic ( 
        IO_cfg : my_array_t := (16#55#, 16#55#, 16#55#, 16#55#, 16#55#, 16#55#, 16#55#)
           );
   -- ports [...]
end max7301_simple;

还要小心use实例化实体的体系结构中的包。

（可选阅读）

为什么要像你一样写语法错误？

查看VHDL (2002) standard中的VHDL语法，每个泛型参数的声明都是interface_constant_declaration，并且您有以下语法规则：

[§ 4.3.2]
interface_constant_declaration ::=  
            [ constant ] identifier_list : [ in ] subtype_indication [ := static_expression ]

[§ 4.2]
subtype_indication ::= 
            [ resolution_function_name ] type_mark [ constraint ]

类型引用只能是现有类型的名称（type_mark）或现有类型的限制。

Answer 2

我通过使用 2008 VHDL 标准和预定义属性提出了更通用的方法 - 这允许传递任意长度的数组。在包中定义您的类型，如下所示：

package data_types is
    type array_of_integers is array(integer range <>) of integer;
end package;

现在在您的代码中传递泛型数组，如下所示：

generic(
    COEFFICIENTS : array_of_integers := (-1, 0, 1)
);

现在软件将使用默认索引方案。它可以与预定的'左一起考虑属性（引用可在以下位置找到：http://www.csee.umbc.edu/portal/help/VHDL/attribute.html）：

-- First coefficient
    ... <= COEFFICIENTS(COEFFICIENTS'left);
-- Second coefficient
    ... <= COEFFICIENTS(COEFFICIENTS'left + 1);

通常，您应该在某种循环或生成语句中使用此数组：

GENERATE_STATEMENT: for entry in 0 to COEFFICIENTS'length-1 generate
    out(entry) <= std_logic_vector(to_signed(COEFFICIENTS(COEFFICIENTS'left + entry), out(entry)'length));
end generate;

作为 Quartus II 用户的一点注意事项 - 也可以在 .bdf 原理图文件中使用通用数组。将参数类型设置为自动并以此格式重写参数值 - A（D“-1”，D“0”，D“1”） ，其中 D 代表十进制数据类型（有用的链接：http://quartushelp.altera.com/14.0/mergedProjects/assign/asd/asd_tab_param.htm）

Answer 3

如果你不介意约束较少的泛型，你可以这样做：

generic (IO_cfg : integer_vector);

只要你有VHDL-2008编译器。

如何在VHDL中将整数数组指定为泛型？

3 个答案: