Question

我从my last question about translating an XML file得到了答案，这激励我玩它。我提出了一个不同的解决方案，但我觉得最后两个选择是不理想的。这可以以更好的方式完成还是更有效率？

样式表：

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output omit-xml-declaration="yes" indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:param name="pFrom" select="'en'"/>
  <xsl:param name="pTo" select="'de'"/>


  <xsl:variable name="translations" select="document('translations.xml')"/>

  <xsl:template match="node()|@*">
    <xsl:copy>
      <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@name">
    <xsl:variable name="thisname" select="." />

    <xsl:variable name="entry" select="$translations/translations/entry[attribute::node()[name()=$pFrom and $thisname=.]]"></xsl:variable>
    <xsl:attribute name="name" select="$entry/attribute::node()[local-name() = $pTo]"></xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

来源：

<?xml version="1.0" encoding="UTF-8"?>
<grammar>
  <element name="table" />
  <element name="chair" />
</grammar>

翻译文件（translations.xml）：

<?xml version="1.0" encoding="UTF-8"?>
<translations>
    <entry en="table" de="Tisch" fr="Table" />
    <entry en="chair" de="Stuhl" fr="Chaise"/>
</translations>

结果是：

<grammar>
   <element name="Tisch"/>
   <element name="Stuhl"/>
</grammar>

一个例子：当我从'en'转到'de'并且我在源文件中的第一个name属性（'table'）时，我会查看en entry的翻译文件，其中en =“table”并选择名称的“de”属性。

Answer 1

使用键：

<xsl:key name="en" match="translations/entry" use="@en"/>
<xsl:key name="de" match="translations/entry" use="@de"/>
<xsl:key name="fr" match="translations/entry" use="@fr"/>

然后

  <xsl:template match="@name">
    <xsl:attribute name="name" select="key($pFrom, current(), $translatations)/@*[local-name() = $pTo]"/>
  </xsl:template>

（我假设您使用XSLT 2.0）。

这个XSLT效率低下吗？

1 个答案: