Question

我正在研究比较有无语言环境的矩阵乘法，并且试图使用稀疏矩阵与线性代数模块一起工作。我正在计划使用blockdist并通过循环手动将其分解，但是我现在想看看是否可以仅使用更简单的方法来加快速度。如果有一种我可以忽略的轻松使用blockdist的方法，我将不胜感激。无论如何，当我只用一个值填充稀疏数组时，我就能使代码工作并看到加速，但是用随机值填充它似乎不起作用：

use LayoutCS;
use Time;
use LinearAlgebra, Norm;
use LinearAlgebra.Sparse;
use Random;
use IO;

writeln("Please type the filename with your matrix dimensions. One matrix on each line. The rows in the second need to match the columns in the first");
var filename: string;
filename = stdin.read(string);

// Open an input file with the specified filename in read mode.
var infile = open(filename, iomode.r);
var reader = infile.reader();

// Read the number of rows and columns in the array in from the file.
var r = reader.read(int), c = reader.read(int);

const parentDom = {1..r, 1..c};
var csrDom: sparse subdomain(parentDom) dmapped CS();
var A: [csrDom] real; 
A = 2; //instead of this I would like to do something like fillRandom(A) but it seems to not work

var X: [1..r, 1..c] real; 
fillRandom(X);

//read in the other matrix
var r1 = reader.read(int), c1 = reader.read(int);

const parentDom1 = {1..r1, 1..c1};
var csrDom1: sparse subdomain(parentDom1) dmapped CS();
var B: [csrDom1] real;
B = 3; //same thing as with matrix A

var Y: [1..r1, 1..c1] real; 
fillRandom(Y);

// Close the file.
reader.close();
infile.close();

var t: Timer; //sets up timer
t.start();

var result: [1..r, 1..c1] real; //sets up matrix for results
  
forall i in 1..r do //goes through rows in 1st
  for j in 1..c1 do //goes through 2nd matrix columns
    for k in 1..c do { //goes through columns in 1st
      result[i, j] += X[i, k] * Y[k, j]; //adds the multiplications to the new slot in results
    }

t.stop();
writeln("multiplication took ", t.elapsed()," seconds");
t.clear();


t.start();
var res = A * B;
t.stop();

writeln("loc multiplication took ", t.elapsed()," seconds");
t.clear();

fillRandom是否不适用于稀疏数组，或者我做错了吗？我是否需要遍历并使用循环手动分配数组中的每个值？当然，也有可能我走在完全错误的道路上，应该更多地关注blockdist，并且我肯定会感谢有关此的任何建议或技巧，因为我不太确定如何确保每个并行任务都在实际运行在由blockdist创建的正确的语言环境部分上。

提前谢谢！

Answer 1

fillRandom是否不适用于稀疏数组，或者我做错了吗？

Random.fillRandom()在今天的教堂（1.22.0）中不支持稀疏数组。但是，如果您有兴趣向其提交GitHub问题，我认为这将是一个合理的功能请求。

即使fillRandom支持稀疏数组，用户仍然需要指定哪些非零元素，然后再使用随机值填充那些非零元素。这是通过将索引作为(int, int)元组（或(int, int)元组的数组）添加到稀疏域来完成的。

这是一个生成带有10个非零随机元素的100x100压缩稀疏行（CSR）数组的小例子：

/* Example tested with Chapel 1.22 */
import LayoutCS.{CS, isCSType};
import Random;

/* Parent domain dimensions: NxN */
config const N = 100;
/* Number of non-zero elements */
config const nnz = 10;

const parentDom = {1..N, 1..N};
var csrDom: sparse subdomain(parentDom) dmapped CS();
var A: [csrDom] real;

populate(A, csrDom, nnz);

// Print non-zero elements
for (i,j) in csrDom do
  writeln((i,j), ':', A[i, j]);


/* Populate sparse matrix with `nnz` random values */
proc populate(ref A, ref ADom, nnz: int) where isCSType(ADom.dist.type) && isCSType(A.domain.dist.type) {

  // Generate array of random non-zero indices
  var indices: [1..nnz] 2*int;
  var randomIndices = Random.createRandomStream(eltType=int);

  // Replace any duplicate indices with a new random index
  for idx in indices {
    var newIdx = idx;
    while indices.find(newIdx)(1) {
      newIdx = (randomIndices.getNext(ADom.dim(0).low, ADom.dim(0).high),
                randomIndices.getNext(ADom.dim(1).low, ADom.dim(1).high));
    }
    idx = newIdx;
  }

  // Add the non-zero indices to the CSR domain
  ADom += indices;

  // Generate random elements - maybe fillRandom(A) could do this for us some day
  var randomElements = Random.createRandomStream(eltType=A.eltType);
  for idx in ADom {
    A[idx] = randomElements.getNext();
  }
}

在Chapel中是否有一种方便的方法来用随机值填充稀疏数组？

1 个答案: