Question

我有以下代码，它们创建了一个座席网格，并在对之间有距离的情况下在成对之间放置链接。

breed [ readers reader ]
undirected-link-breed [ rris rri ]

globals [
  interf-rri-radius
  num-readers
  distance-var-x
  distance-var-y
  readers-per-row
  readers-per-column
  num-checkouts
]


to setup
  ca
  setup-globals
  ask patches [ set pcolor blue - 3 ]
  spawn-by-row-col
  reset-ticks
end

to setup-globals
  set  interf-rri-radius 1005
  set num-readers 40
  set distance-var-x 12
  set distance-var-y 22
  set readers-per-row 8
  set readers-per-column 5
  set num-checkouts 0
end

to spawn-by-row-col
  let half-step 0.5 * distance-var-x
  let d-vals ( range ( min-pxcor + half-step ) ( min-pxcor + (readers-per-row * distance-var-x)) distance-var-x )

  let dc-vals ( range ( min-pxcor + half-step ) ( min-pycor + (readers-per-column * distance-var-y)) distance-var-y )
  show dc-vals
  ; Create an empty list to build into
  let possible-coords []

  ; For each possible vertical value, map all horizontal values in order and
  ; combine these into an ordered list starting at the lowest px and py coords

  foreach dc-vals [
    d ->
    set possible-coords ( sentence possible-coords map [ i -> (list i d) ] d-vals )
  ]

  show (word "possible-coords = " possible-coords)
  ; Use the number of readers to sublist the possible coordinates, and
  ; create a turtle at each of the coordinate combinations left.
  let max-positions length possible-coords
  if max-positions > (num-readers + num-checkouts) [ set max-positions (num-readers + num-checkouts) ]
  let use-coords sublist possible-coords num-checkouts max-positions
  foreach use-coords [
    coords ->
    create-readers 1 [
      setxy item 0 coords item 1 coords
      set shape "square 2"
      set size 2
      set color 15
    ]
  ]
  ask readers [ create-rris-with other readers in-radius (interf-rri-radius / 10) ]
end

阅读器0的邻居是

show [sort [who] of rri-neighbors] of reader 0
[1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39]

但是，阅读器0和阅读器39之间的距离是

show [distance reader 0] of reader 39
121.6552506059644

，并且连接半径为1005/10 = 100.5，因此它们不应与rri链接连接。

通知，我使用以原点为中心的世界，在X和Y维度上为-50到50。

我已经测试了以前的Netlogo 6.0.4版中的代码，并且读取器39不是读取器0的邻居。我不知道可能是什么问题。我相信是新版本，但我想确定。

Answer 1

万一其他人遇到此问题，NetLogo 6.1.0发行版中存在一个已确认的in-radius错误，并且详细信息位于the bug report on GitHub中。

该问题仅在用于非包装的世界中使用时才影响in-radius，仅在用于乌龟时才使用，并且仅在半径占世界宽度很大百分比的情况下使用时才影响。如果您使用的是环绕的世界，或者使用带有补丁的in-radius，或者使用相对于世界大小较小的半径，则您的数据将是正确的，并且不需要以下解决方法。

作为解决方案，如果您的模型受到影响，则可以在模型中使用简单的用户定义的NetLogo过程，直到发布修订。如果您的海龟每次滴答多次计算in-radius不会很快，但是如果您的海龟很少或仅在设置过程中使用它，那应该没问题：

to-report temp-in-radius [agentset r]
  report agentset with [ distance myself <= r ]
end

然后，您将执行create-rris-with other readers in-radius (interf-rri-radius / 10)而不是create-rris-with (temp-in-radius other readers (interf-rri-radius / 10))。

或更笼统地说，不是像count other turtles in-radius 5这样的东西，而是会变成count temp-in-radius (other turtles) 5。

Netlogo 6.1.0中的半径范围与以前的版本不同

1 个答案: