Question

我要制作的东西类似于绘画程序。问题是当我画一些线（不仅是线。在这种情况下包括了我画的所有东西。），那些线只画了我在画之前插入的图像的背面。

起初，我认为这只是代码顺序的问题。但这不是。

我只想在图像上画一些线，例如绘画程序。像这样：enter image description here

Answer 1

您可以使用PGraphics绘制成单独的“图层”。初始化实例后，您可以在beginDraw() / endDraw()中使用典型的绘制方法（如参考示例所示）。

剩下的唯一事情就是使用save()

保存最终图像。

这是示例>基础>图像> LoadDisplay 的修改示例，该示例使用单独的PGraphics实例在拖动鼠标时绘制到其中，并在按下s键时保存最终图像按下：

/**
 * Based on Examples > Basics > Image > Load and Display 
 * 
 * Images can be loaded and displayed to the screen at their actual size
 * or any other size. 
 */

PImage img;  // Declare variable "a" of type PImage
// reference to layer to draw into
PGraphics paintLayer;

void setup() {
  size(640, 360);
  // The image file must be in the data folder of the current sketch 
  // to load successfully
  img = loadImage("moonwalk.jpg");  // Load the image into the program

  // create a separate layer to draw into
  paintLayer = createGraphics(width,height);
}

void draw() {
  // Displays the image at its actual size at point (0,0)
  image(img, 0, 0);
  // Displays the paint layer
  image(paintLayer,0,0);
}

void mouseDragged(){
  // use drawing commands between beginDraw() / endDraw() calls
  paintLayer.beginDraw();
  paintLayer.line(mouseX,mouseY,pmouseX,pmouseY);
  paintLayer.endDraw();
}

void keyPressed(){
  if(key == 's'){
    saveFrame("annotated-image.png");
  }
}

如何将我画的油漆的图像放回去？

1 个答案: