Question

我在尝试了解Haskell上的折叠实现时遇到很多问题。我需要使用fold的两个函数来输出此结果

> runLengthEncode "aaaaaaabbb"
[(7,'a'),(3,'b')]
> runLengthDecode [(1,'h'), (5,'i')]
"hiiiii"

因此，我要做的是像编写模式匹配一样（工作）先编写函数，但是现在我不知道如何使用向左折叠或向右折叠来“翻译”该函数。

runLengthEncode :: String -> [(Int,Char)]
runLengthEncode [] = []
runLengthEncode (x:xs) = runLengthEncode 1 x xs
    where
        runLengthEncode n x [] = [(n,x)]
        runLengthEncode n x (y:ys) | x == y = runLengthEncode (n + 1) y ys
                                   | otherwise = (n,x) : runLengthEncode 1 y ys

runLengthDecode :: [(Int,Char)] -> String
runLengthDecode [] = []
runLengthDecode ((a,b):xs) = replicate a b ++ (runLengthDecode xs)

Answer 1

想一想就拿一个术语表吧：

[a,b,c,d]

，并在以下各项之间添加初始值zz和二进制运算符<+>：

foldl (<+>) zz [a,b,c,d] = (((zz <+> a) <+> b) <+> c) <+> d
foldr (<+>) zz [a,b,c,d] = a <+> (b <+> (c <+> (d <+> zz)))

请注意，初始值也是折叠应用于空列表时将具有的值，因此通常很容易弄清楚。困难的部分是定义适当的二进制运算符。

因此，要将runLengthEncode表示为正确的折叠，您需要：

'a' <+> ('a' <+> ('a' <+> ('b' <+> zz))) = [(3,'a'),(1,'b')]

用于运算符<+>和一些初始值zz。

我们可以轻松地为zz“解决”，因为我们知道runLengthEncode [] = []，所以zz = []也是如此。我们需要定义<+>，以便满足从上面的示例（从右到左）得出的方程式：

'b' <+> [] = [(1, 'b')]
'a' <+> [(1, 'b')] = [(1, 'a'), (1, 'b')]
'a' <+> [(1, 'a'), (1, 'b')] = [(2, 'a'), (1, 'b')]
'a' <+> [(2, 'a'), (1, 'b')] = [(3, 'a'), (1, 'b')]

定义这样的运算符实际上很容易：

(<+>) :: Char -> [(Int, Char)] -> [(Int, Char)]
x <+> ((n, y) : rest) | x == y = ((n+1), y) : rest
x <+> rest                     = (1, x) : rest

所以我们得到：

runLengthEncode' :: String -> [(Int,Char)]
runLengthEncode' = foldr (<+>) []

也尝试向左折叠：

(((zz + 'a') <+> 'a') <+> 'a') <+> 'b' =>  [(3,'a'),(1,'b')]

您会发现，当需要定义<+>时，您必须检查当前RLE的 last 元素，而不是第一个。当然可以做到，但是自然程度要低一些，这就是为什么我在上面使用了正确的折痕的原因。

对于runLengthDecode，这是相同的业务：

(1, 'h') <+> ((5, 'i') <+> zz) = "hiiiii"

再次确定zz应该是什么。然后，弄清楚如何编写二进制运算符来解决：

(5, 'i') <+> zz = "iiiii"
(1, 'h') <+> "iiiii" = "hiiiii"

剧透跟随...

当然，您实际上不需要使用运算符语法，因此完整的解决方案如下所示：

runLengthEncode'' :: String -> [(Int,Char)]
runLengthEncode'' = foldr step []
  where step x ((n, y) : rest) | x == y = ((n+1), y) : rest
        step x rest                     = (1, x) : rest

runLengthDecode'' :: [(Int,Char)] -> String
runLengthDecode'' = foldr step ""
  where step (n, x) str = replicate n x ++ str

Haskell中的Folds实现

1 个答案: