Question

我对Unix命令不太满意，并且努力做到这一点。

我有一个如下文件

输入

ABCDEF_XY_12345_PQRTS_67367
1,a,b,c1
2,a,b,c2
3,a,b,c3
.....
APRTEYW_XY_23456_GDJHJH_232434
1,a,b,c4
2,a,b,c5
3,a,b,c6
......
GDHGJHG_XY_35237_FHDJFH_738278
1,a,b,c7
2,a,b,c8
3,a,b,c9
......

输出

12345,1,a,b,c1
12345,2,a,b,c2
12345,3,a,b,c3
23456,1,a,b,c4
23456,2,a,b,c5
23456,3,a,b,c6
35237,1,a,b,c7
35237,2,a,b,c8
35237,3,a,b,c9

从本质上讲，在_XY_[<STRING>]_之间获取子字符串，并将其放在<STRING>,1,a,b,c1之类的以下行之前，直到遇到字符串匹配模式_XY_[<STRING>]_，然后重复相同的过程直到EOF。

我正在尝试使用awk或将主文件拆分为多个较小的文件来找到一种简便的方法。您能朝正确的方向吗？

Answer 1

尝试使用多个定界符的awk

awk -F"[_,]" -v OFS=, ' { if(/_/) { k=$3 } else { print k,$0 } } ' file

感谢@EdMorton，单个分隔符就足够了

awk -F_ -v OFS=, ' { if(/_/) { k=$3 } else { print k,$0 } } ' file

它可以进一步缩短为

awk -F_ -v OFS=, ' /_/ {k=$3;next} { print k,$0 } ' file

使用您给定的输入

$ cat filex.txt
ABCDEF_XY_12345_PQRTS_67367
1,a,b,c1
2,a,b,c2
3,a,b,c3
APRTEYW_XY_23456_GDJHJH_232434
1,a,b,c4
2,a,b,c5
3,a,b,c6
GDHGJHG_XY_35237_FHDJFH_738278
1,a,b,c7
2,a,b,c8
3,a,b,c9

$ awk -F_ -v OFS=, ' { if(/_/) { k=$3 } else { print k,$0 } } ' filex.txt
12345,1,a,b,c1
12345,2,a,b,c2
12345,3,a,b,c3
23456,1,a,b,c4
23456,2,a,b,c5
23456,3,a,b,c6
35237,1,a,b,c7
35237,2,a,b,c8
35237,3,a,b,c9

$

Answer 2

第一个解决方案： 。请您尝试一次。

awk 'BEGIN{FS="_";OFS=","}/^[a-zA-Z]+/{val=$3;next} !/^\..*\.$/{print val,$0}' Input_file

第二种解决方法： ：如果XY字符串的位置未固定在行中，请尝试执行以下操作。

awk '
BEGIN{
  FS="_"
  OFS=","
}
/^[a-zA-Z]+/ && match($0,/XY_[0-9]+_/){
  val=substr($0,RSTART+3,RLENGTH-4)
  next
}
!/^\..*\.$/{
  print val,$0
}
'   Input_file

Unix awk命令执行特定的逻辑

2 个答案: