Question

我试图在不使用LearnOpenGL方法的情况下学习OpenGL上的反射，但是我无法弄清楚反射的问题所在。相机视图的某些部分似乎发生某种变形和翻转。到目前为止，我只是使用视图矩阵来简化代码。

这是球形反射的样子。

我也尝试使用多维数据集。即使我的鼠标继续向右移动，反射也会扭曲，然后最终显示扭曲之前存在的图像。

立方体反射

Skybox图片

这是天空盒顶点着色器

#version 330 core
layout (location = 0) in vec3 aPos;

out vec3 o_pos;

void main()
{
    o_pos = aPos;
    gl_Position = vec4(aPos, 1.0);
}

这是skybox片段着色器。我将视图矩阵直接传递给片段着色器。

#version 330 core
out vec4 FragColor;

in vec3 o_pos;

uniform vec3 view_up;
uniform vec3 view_right;
uniform vec3 view_forward;

uniform samplerCube cubeTex;

void main()
{
    vec3 pv = mat3(view_right, view_up, view_forward) * vec3(o_pos.xy, 1.0);
    FragColor = vec4(texture(cubeTex, pv).rgb, 1.0);
}

这是对象顶点着色器

#version 330 core
layout (location = 0) in vec3 aPos;
layout (location = 1) in vec3 normal;

out vec3 o_normal;
out vec3 o_pos;

void main()
{
    o_pos = aPos;
    o_normal = normal;
    gl_Position = vec4(o_pos, 1.0f);
}

这是对象片段着色器。它类似于learnopengl着色器。

#version 330 core
in vec3 o_pos;
in vec3 o_normal;

out vec4 fragColor;

uniform vec3 eye_pos;
uniform samplerCube cubeTex;

void main()
{
    vec3 incident = normalize(o_pos - eye_pos);
    vec3 reflection = reflect(incident, normalize(o_normal));
    fragColor = vec4(texture(cubeTex, reflection).rgb, 1.0);
}

这是渲染循环

    while (!glfwWindowShouldClose(window))
    {
        // input
        processInput(window);

        // render
        glClearColor(0.9f, 0.8f, 0.5f, 1.0f);
        glClear(GL_COLOR_BUFFER_BIT | GL_DEPTH_BUFFER_BIT);

        // change view using mouse input
        double xpos, ypos;
        glfwGetCursorPos(window, &xpos, &ypos);
        ypos = (ypos/SCR_HEIGHT) * PI * PI * 0.5;
        xpos = (xpos/SCR_WIDTH) * 2 * PI - PI;
        if (ypos < PI/2) ypos = 1.6f;
        if (ypos > 3*PI/2) ypos = 4.7f;
        eye_forward = normalize(glm::vec3{(GLfloat)(cos(ypos) * cos(xpos)),
                                (GLfloat)sin(ypos),
                                (GLfloat)(cos(ypos) * sin(xpos))});
        eye_right = glm::normalize(glm::cross(eye_forward, glm::vec3{0.0, 1.0, 0.0}));
        eye_up = glm::cross(eye_right, eye_forward);

        // draw skybox
        glUseProgram(shaderProgram);
        glUniform1i(u_cubeTex, 0);
        glUniform3fv(u_view_up, 1, (GLfloat*)&eye_up);
        glUniform3fv(u_view_right, 1, (GLfloat*)&eye_right);
        glUniform3fv(u_view_forward, 1, (GLfloat*)&eye_forward);
        glBindVertexArray(vao);
        glDrawArrays(GL_TRIANGLE_STRIP, 0, cube.size());

        // draw UV sphere
        glUseProgram(sphereProgram);
        glUniform1i(u_cubeTex2, 0);
        glUniform3fv(u_eye_pos, 1, (GLfloat*)&eye_forward);
        glBindVertexArray(sphereVAO);
        glDrawArrays(GL_TRIANGLE, 0, sphere.size());

        glfwSwapBuffers(window);
        glfwPollEvents();
    }

Answer 1

eye_pos在世界空间中的位置。
o_pos是视图空间，剪辑空间和规范化设备空间中的位置。这与您的情况相同，因为您没有投影矩阵，并且顶点坐标属性直接分配给顶点着色器中的剪辑空间位置：

 gl_Position = vec4(aPos, 1.0);

无论如何，像这样做一样，计算从世界空间位置到视图空间位置的向量毫无意义：

 vec3 incident = normalize(o_pos - eye_pos);

视图空间中的眼睛位置为（0，0，0）。因此，视图空间中的事件视图矢量为：

vec3 incident = normalize(o_pos - vec3(0.0, 0.0, 0.0));

此向量必须从视图空间转换为世界空间，这可以通过视图的方向矩阵（mat3(view_right, view_up, view_forward)）来实现，就像在skybox片段着色器中一样：< / p>

vec3 incident = mat3(view_right, view_up, view_forward) * normalize(o_pos);

法线向量o_normal也是视图空间向量。因此必须将其转换为世界空间：

vec3 wordlNormal = mat3(view_right, view_up, view_forward) * normalize(o_normal);

代替变换入射向量和法向向量，可以在反射之后变换结果向量。
您必须更改对象片段着色器以解决您的问题：

#version 330 core

in vec3 o_pos;
in vec3 o_normal;

out vec4 fragColor;

uniform vec3 view_up;
uniform vec3 view_right;
uniform vec3 view_forward;
uniform samplerCube cubeTex;

void main()
{
    mat3 invNormalM      = mat3(view_right, view_up, view_forward);

    vec3 viewIncident    = normalize(o_pos);
    vec3 viewNormal      = normalize(o_normal);
    vec3 worldReflection = invNormalM * reflect(viewIncident, viewNormal);

    fragColor            = vec4(texture(cubeTex, worldReflection).rgb, 1.0);
}

我将视图矩阵直接传递给片段着色器。

mat3(view_right, view_up, view_forward)不是视图矩阵。它是相机的方向矩阵。因此，它是逆视图（正常）矩阵。

OpenGL反射无法正确映射天空盒

1 个答案: