Question

我目前正在编写一个基于属性的测试，以测试带有4个float参数的f＃中的费率计算函数，并且所有参数都有使其有效的特定条件（例如，a> 0.0 && a <1.0，和b > a）。我确实有一个函数检查是否满足这些条件并返回布尔值。我的问题是，在使用FsCheck.Xunit中[Property>]的测试代码中，如何限制生成器仅使用满足我特定条件的参数值来测试代码？

Answer 1

如果使用的是FsCheck，则可以使用Gen.filter函数和Gen.map函数。

假设您正在测试的函数funToBeTested要求一个

let funToBeTested a b = if a < b then a + b else failwith "a should be less than b"

您正在测试funToBeTested与输入成比例的属性：

let propertyTested a b = funToBeTested a b / 2. = funToBeTested (a / 2.) (b / 2.)

您还有一个谓词，用于检查a和b的条件要求：

let predicate a b = a > 0.0 && a < 1.0 && b > a

我们首先使用float和Gen.choose生成Gen.map个数字，这种方式只能产生0.0到1.0的值：

let genFloatFrom0To1 = Gen.choose (0, 10000) |> Gen.map (fun i -> float i / 10000.0 )

然后我们生成two从0到1的浮点数，并使用上面的filter函数predicate将它们浮点数

let genAB            = Gen.two genFloatFrom0To1 |> Gen.filter (fun (a,b) -> predicate a b )

现在，我们需要创建一个新类型TestData来使用这些值：

type TestData = TestData of float * float

，我们将结果值映射到TestData

let genTest = genAB |> Gen.map TestData

接下来，我们需要注册genTest作为TestData的生成器，因为我们创建了一个静态类型为Arbitrary<TestData>的新类：

type MyGenerators =
    static member TestData : Arbitrary<TestData> = genTest |> Arb.fromGen

Arb.register<MyGenerators>() |> ignore

最后，我们使用TestData作为输入来测试属性：

Check.Quick (fun (TestData(a, b)) -> propertyTested a b )

更新：

组成不同生成器的一种简单方法是使用gen计算表达式：

type TestData = {
    a : float
    b : float 
    c : float 
    n : int
}

let genTest = gen {
    let! a = genFloatFrom0To1
    let! b = genFloatFrom0To1
    let! c = genFloatFrom0To1
    let! n = Gen.choose(0, 30)
    return {
        a = a
        b = b
        c = c
        n = n
    }
}

type MyGenerator =
    static member TestData : Arbitrary<TestData> = genTest |> Arb.fromGen

Arb.register<MyGenerator>() |> ignore


let ``Test rate Calc`` a b c n =                               
    let r = rCalc a b c
    (float) r >= 0.0 && (float) r <= 1.0    


Check.Quick (fun (testData:TestData) -> 
    ``Test rate Calc`` 
        testData.a 
        testData.b 
        testData.c 
        testData.n)

Answer 2

@AMieres的回答很好地说明了解决此问题所需的一切！

一个小小的补充是，如果谓词不能容纳生成器生成的大量元素，则使用Gen.filter可能会很棘手，因为生成器需要运行很长时间才能找到足够的数量有效元素。

在@AMieres的示例中，这很好，因为生成器已经生成了正确范围内的数字，因此它仅检查第二个数字是否较大，大约一半的随机生成的对就是这种情况。

如果可以编写此代码以便始终生成有效值，那会更好。对于这种情况，我的版本是使用map交换数字，以便较小的数字始终排在最前面：

let genFloatFrom0To1 = Gen.choose (0, 10000) |> Gen.map (fun i -> float i / 10000.0 )
let genAB = Gen.two genFloatFrom0To1 |> Gen.map (fun (a, b) -> min a b, max a b)

使用条件参数在F＃中进行基于属性的测试

2 个答案: