根据2个条件查找并合并字符串

Question

在B列中，我想从C：D范围中找到每个Source（col A）的所有“ Add：”字符串。我不想获取任何其他值。我曾尝试使用vlookups和index / match，但是我无法获取字符串数组，无法使用公式连接它们。我不想使用VBA。

Answer 1

如果您拥有Office 365，则可以将TEXTJOIN用作数组公式：

=TEXTJOIN(" ",TRUE,IF(($C$2:$C$12 = A2)*(ISNUMBER(SEARCH("ADD:",$D$2:$D$12))),$D$2:$D$12,""))

作为数组公式，退出编辑模式时必须使用Ctrl-Shift-Enter而不是Enter进行确认。

---

如果您没有Office 365 Excel，则需要VBA。

将其放在工作簿所附的模块中，并使用上述公式：

Function TEXTJOIN(delim As String, skipblank As Boolean, arr) As String
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    If TEXTJOIN <> "" Then
        TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
    Else
        TEXTJOIN = ""
    End If
End Function

我必须在照片的公式中使用TEXTJOIN2作为函数名称。