tableplot中的xlabel行为不符合预期

Question

我已经使用社区贡献的命令tableplot制作了一张图表。

图形本身很好，但是在x-axis上有很多年，它们重叠且不清晰。因此，我仅尝试标注每十年或类似的内容。我最初的尝试没有用，所以我检查了Stata手册。

但是，该手册似乎确认我已正确xlabel(1935(5)1955)对其进行了编码。然后，我尝试为Stata提供固定数量的标签xlabel(#10)。这样效果更好，但是第一个标签是年份0。显然年份0不在数据中，并且数据没有缺失值或任何其他问题。

我用下面的示例数据集重现了该问题，并且这些问题是相同的：

use http://www.stata-press.com/data/r15/grunfeld.dta, clear
codebook year

tableplot rbar invest company year, graphregion(color(none)) bgcolor(white) subtitle("") ///
xtitle("Year") ytitle("Firm")

tableplot rbar invest company year, graphregion(color(none)) bgcolor(white) subtitle("") ///
xtitle("Year") ytitle("Firm") xlabel(1935(5)1955)

*Coding is in line with Stata manual page 9: 
*https://www.stata.com/manuals13/g-3axis_label_options.pdf

tableplot rbar invest company year, graphregion(color(none)) bgcolor(white) subtitle("") ///
xtitle("Year") ytitle("Firm") xlabel(#10)

如果有人可以指出我如何说服Stata和tableplot将x-axis标记为从指定的开始年份（1935）到结束年份（1955），我将感到高兴。两者之间有给定的间隔

我使用Stata 15和tableplot的最新版本。

Answer 1

您不是在绘制year的图形，而是time：

tableplot rbar invest company year, graphregion(color(none)) bgcolor(white) ///
subtitle("") xtitle("Year") ytitle("Firm") xlabel(1(19)20)

因此，根据您的数据得出的最佳结果如下：

tableplot rbar invest company year, graphregion(color(none)) bgcolor(white) ///
subtitle("") xtitle("Year") ytitle("Firm") xlabel(1(6)20)

您可以通过进一步摆弄不同的选项来获得更好的结果。

---

编辑：

显然我已经忘记了xasis选项也可以使用：

tableplot rbar invest company year, graphregion(color(none)) bgcolor(white) ///
subtitle("") xtitle("Year") ytitle("Firm") xlabel(1935(5)1955) xasis

Answer 2

tableplot（SSC）的最新修订于2009年。我建议改为使用tabplot（ Stata Journal ），该文件正在维护中。

webuse grunfeld

tabplot company year [iw=invest], graphregion(color(none))  bgcolor(white) /// 
subtitle("") xtitle("Year") ytitle("Firm") xasis xla(, format(%tyY))

tabplot company year [iw=invest], graphregion(color(none))  bgcolor(white)  /// 
subtitle("") xtitle("Year") ytitle("Firm") xasis xla(1935(5)1955)

tabplot（以及tableplot后面）的主要缺点是使用表数据，其含义是您想知道哪一行和哪一列。但是在此示例中，期限为20年，您可以在轴标签上仅显示最后两位数字或仅显示几年。