Question

我目前正在尝试使用倾斜传感器来设置发酵比重监控器。该过程可能需要数周时间，并且必须装在无菌容器中，因此必须由电池供电。我使用的是经过稍微修改的ESP8266-01，它进入睡眠模式，然后每小时唤醒一次以进行测量，传输数据并返回睡眠模式。我将MPU6050用于倾斜传感器。首先，当esp关闭时，我似乎无法将mpu置于睡眠模式，它似乎总是需要4mA电流；其次，我只需要一个轴，是否可以禁用其他所有功能以进一步限制功耗？我似乎无法在手册中找到任何内容来禁用轴，只能对其进行校准。我的代码在下面

使用下面的寄存器进行实验似乎没有什么区别，添加它们，将它们全部取出，仍然需要大约4mA的电流。尝试将其设置为1，以使MPU在周期结束时进入睡眠状态，但没有区别。 Wire.write（0x6B）; Wire.write（0）;

我对此很陌生，在引用地址6b中的bit6时，我难以理解该手册，我该如何设置bit 6？

如果我只能将MPU限制在1轴上，没有加速度，并且在两次测量之间可以进入深度睡眠状态，那么我应该能够获得0.5mA左右的功耗，这使我一次使用18650就能获得良好的电池寿命。任何建议都是非常感谢！

#include <ESP8266WiFi.h>
#include <PubSubClient.h>
#include <OneWire.h>
#include <DallasTemperature.h>
#include "MPU6050.h"
#include "I2Cdev.h"
#include "Wire.h"

// Update these with values suitable for your network.

const char* ssid = "****";
const char* password = "******";
IPAddress server(192, 168, 1, 90);

WiFiClient espClient5;
PubSubClient client(espClient5);
long lastMsg = 0;
char msg[50];
const uint8_t scl = 5; //D1
const uint8_t sda = 4; //D2
int val;
int prevVal = 0;
String pubString;
char gravity[50];
MPU6050 mpu;
const int sleepTimeS = 10; //only 10 seconds for testing purposes, set to 
1hr when operational
int counter=0;


int16_t ax, ay, az;
int16_t gx, gy, gz;

void setup_wifi() {

  delay(10);
  // We start by connecting to a WiFi network
  Serial.println();
  Serial.print("Connecting to ");
    Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  randomSeed(micros());

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

}

void callback(char* topic, byte* payload, unsigned int length) { //not 
required in this application
}

void reconnect() {
  // Loop until we're reconnected
  while (!client.connected()) {
    Serial.print("Attempting MQTT connection...");
    // Create a random client ID
    String clientId = "test";
    clientId += String(random(0xffff), HEX);
    // Attempt to connect
    if (client.connect(clientId.c_str())) {
      Serial.println("connected");
      // Once connected, publish an announcement...
      client.publish("AliveRegister", "FermentMon");
    } else {
      Serial.print("failed, rc=");
      Serial.print(client.state());
      Serial.println(" try again in 5 seconds");
      // Wait 5 seconds before retrying
      delay(5000);
    }
  }
}

#define ONE_WIRE_BUS 2  //  D4 on physical board

 OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature DS18B20(&oneWire);
float prevTemp = 0;

void setup() {
  counter = 0;
  Serial.begin(9600);
  Wire.begin(0,2);
  Wire.write(0x6B); //PWR_MGMT_1 register
  Wire.write(0); // set to zero wakes teh 6050
  Wire.endTransmission(true);
 delay(100);
  setup_wifi();
  client.setServer(server, 1883);
  client.setCallback(callback);
 if (!client.connected()) {
    reconnect();
  }
  Serial.println("Initialize MPU");
  mpu.initialize();
  Serial.println(mpu.testConnection() ? "Connected" : "Connection failed");
 float temp;
  DS18B20.requestTemperatures();
  temp = DS18B20.getTempCByIndex(0); // first temperature sensor
  char buff[100];
  dtostrf(temp, 0, 2, buff);
  temp = temp + 0.5;
  int tRound = int(temp);
   client.publish("Fermenter/temperature", buff);
    Serial.print("Fermenter Temperature: ");
    Serial.println(temp);
    prevTemp = tRound;

  mpu.getMotion6(&ax, &ay, &az, &gx, &gy, &gz);
  val = map(ax, -17000, 17000, 0, 180);
    pubString = String(val);
    pubString.toCharArray(gravity, pubString.length() + 1);
    client.publish("Fermenter/angle", gravity);
    Serial.print("Gravity angle: ");
    Serial.println(val);
    delay(500);
//    counter = counter+1;
    Serial.println("sleep mode");
    Wire.write(0x6B); //PWR_MGMT_1 register
    Wire.write(1); // set to zero wakes teh 6050
    // sleep
    ESP.deepSleep(sleepTimeS * 1000000);
    delay(2000);

  }


void loop() {

  client.loop();

      }

Answer 1

您是否为MPU6050使用了分线板？例如GY-521。通常，他们使用线性稳压器和LED会消耗额外的功率。可能有必要将其卸下并从直接电源运行IMU。

MPU6050中的每个寄存器均为8位宽。将单个位设置为所需值时，您可以使用按位操作（此处不实际，因为我们不直接与寄存器进行交互），也可以将寄存器中的所有位直接设置为寄存器的新状态，例如0b00100000〜0x20。尝试将MPU6050置于睡眠状态时，与其将1写入0x6B，不如将其写入0x20。

https://www.invensense.com/wp-content/uploads/2015/02/MPU-6000-Register-Map1.pdf

请参阅第40-42页，如果您想更进一步，可以禁用温度传感器，加速计和冗余陀螺仪轴，以在设备启动时节省电能。

Answer 2

我对此很陌生，在引用地址6b中的bit6时，我难以理解该手册，我该如何设置bit 6？

设置一点很简单。使用跟随功能可以避免任何头脑风暴。

// Write register bit
void writeRegisterBit(uint8_t reg, uint8_t pos, bool state)
{
  uint8_t value;
  value = readRegister8(reg);

  if (state)
  {
    value |= (1 << pos);
  } 
 else
  {
    value &= ~(1 << pos);
  }

  writeRegister8(reg, value);
}

// Write 8-bit to register
void writeRegister8(uint8_t reg, uint8_t value)
{
  Wire.beginTransmission(MPU_addr);

#if ARDUINO >= 100
  Wire.write(reg);
  Wire.write(value);
#else
  Wire.send(reg);
  Wire.send(value);
#endif
  Wire.endTransmission();
}

用法示例：writeRegisterBit(MPU6050_REG_INT_PIN_CFG, 5, 1); //Register 37;Interrupt Latch Enable

对于您的应用程序：

void acclSetSleepEnabled(bool state)
{
  writeRegisterBit(MPU6050_REG_PWR_MGMT_1, 6, state);
}

如果我只能将mpu限制在1个轴上，没有加速度，并且在两次测量之间可以进入深度睡眠状态，那么我应该能够将功耗降低到0.5mA左右，这样一次使用18650就可以延长电池寿命

要进入低功耗加速度计模式，请使用以下功能：

void lowPowerAccel(uint8_t frequency) {
  uint8_t value;
  value = readRegister8(MPU6050_REG_PWR_MGMT_2);
  value &= 0b00111000;
  value |= (frequency << 6) | 0b111;
  writeRegister8(MPU6050_REG_PWR_MGMT_2, value);

  value = readRegister8(MPU6050_REG_PWR_MGMT_1);
  value &= 0b10010111;
  value |= 0b00111000;
  writeRegister8(MPU6050_REG_PWR_MGMT_1, value);
}

此lowPowerAccel功能还将陀螺仪置于待机模式。该功能需要一个唤醒频率参数。定义如下：

/*
  * LP_WAKE_CTRL | Wake-up Frequency
  * -------------+------------------
  * 0            | 1.25 Hz
  * 1            | 2.5 Hz
  * 2            | 5 Hz
  * 3            | 10 H

*/

#define  LP_WAKE_CTRL_1_25        0x00
#define  LP_WAKE_CTRL_2_5         0x01
#define  LP_WAKE_CTRL_5           0x02
#define  LP_WAKE_CTRL_10          0x03

我希望我能回答您的一些问题。祝好运！：）

如何在超低功耗模式下使用MPU 6050

2 个答案: