如何绘制（x，y，z）点以显示其密度

Question

我的数据文件是围绕轴原点的一组（x，y，z）点。它们代表一种措施失败的点。 这些要点在此link中。

Gnuplot可以绘制它们，

set encoding iso_8859_1
set term postscript eps enhanced color size 4.7in,4in
set xlabel "X"
set ylabel "Y"
set zlabel "Z"
set output "test_gp.eps"
set style line 1 lc rgb '#0060ad' pt 7 ps 0.5 lt 1 lw 0.5 # --- blue
set style fill  transparent solid 0.15 noborder
splot "data.dat" u 1:2:3 w p ls 1 title "P_{error}"

及其结果图

问题在于该图未显示更可能发生错误的位置。 如果可能的话，我想展示点密度的变化。

我不知道是否可以改变点的颜色或赋予它们透明性，并尝试代表点密度最高的位置。

如果无法表示3D点的密度，则另一种方法可能是使点在三个平面中的投影密度（x = 0，y，z），（x，y = 0，z ），（x，y，z = 0）。

致谢

编辑：

我可以用不同的颜色绘制实验的成功（0）和错误（1）点的位置。 link中的文件的第4列包含所有数据样本（0和1）。

splot数字

splot "data_all.dat" u 1:2:3:4 w points ls 1 palette title "P_{error}"

是

，但该图未显示点的密度。 例如，在Mathematica中，这些数据样本的密度图为

如何使用Gnuplot获得密度图？ Mathematica可能正在对中间的点进行插值并将其值设置为0到1之间，但我不知道如何使用Gnuplot来实现。

Answer 1

@ user1993416，我想您可以使用gnuplot做一些事情。您可能需要使用参数Delta。使用我8岁的计算机，大约需要1000点积分。 2分钟。

关注代码：

### 3D density plot
reset session
set term wxt

N = 1000      # number of datapoints
Delta = 2    # half boxwidth

TimeStart = time(0.0)
# create dummy some dummy data
set samples N
set table $Data
    plot '+' u (invnorm(rand(0))):(invnorm(rand(0))):(invnorm(rand(0))) with table
unset table

# put the datafile/dataset into arrays
stats $Data nooutput
RowCount = STATS_records
array ColX[RowCount]
array ColY[RowCount]
array ColZ[RowCount]
array ColC[RowCount]
do for [i=1:RowCount] {
set table $Dummy
    plot $Data u (ColX[$0+1]=$1,0):(ColY[$0+1]=$2,0):(ColZ[$0+1]=$3,0) with table
unset table
}

# look at each datapoint and its sourrounding
do for [i=1:RowCount] {
    print sprintf("Datapoint %g of %g",i,RowCount)
    x0 = ColX[i]
    y0 = ColY[i]
    z0 = ColZ[i]
    # count the datapoints with distances <Delta around the datapoint of interest
    set table $Occurrences
        plot $Data u ((abs(x0-$1)<Delta) & (abs(y0-$2)<Delta) & (abs(z0-$3)<Delta) ? 1 : 0):(1) smooth frequency
    unset table
    # extract the number from $Occurrences which will be used to color the datapoint
    set table $Dummmy
        plot $Occurrences u (c0=$2,0):($0) every ::1::1 with table
    unset table
    ColC[i] = c0
}

# put the arrays into a dataset again
set print $Data
do for [i=1:RowCount] {
    print sprintf("%g\t%g\t%g\t%g",ColX[i],ColY[i],ColZ[i],ColC[i])
}
set print

TimeEnd = time(0.0)
print sprintf("Duration: %.3f sec",TimeEnd-TimeStart)

set palette rgb 33,13,10
splot $Data u 1:2:3:4 w p ps 1 pt 7 lc palette z notitle

set terminal gif animate delay 30
set output "Density.gif"
Amin = 40
Amax = 60
AFrames = 25
do for [i=0:AFrames] {
    print sprintf("Frame %g, Angle: %.1f", i, sin(2*pi*i/AFrames)*(Amax-Amin)+Amin)
    set view 45,(sin(2*pi*i/AFrames)*(Amax-Amin)+Amin)
    replot
}
set output

应导致：