Question

我正在使用Prolog求解简单的几何方程。例如，我可以将通过两个点p3和p1的直线上的所有点p2定义为：

   line((X1, Y1, Z1), (X2, Y2, Z2), T, (X3, Y3, Z3)) :-
        {(X2 - X1) * T = X3},
        {(Y2 - Y1) * T = Y3},
        {(Z2 - Z1) * T = Z3}.

然后像line((0, 0, 0), (1, 1, 1), _, (2, 2, 2))这样的谓词为真。

但是我真正想要的是写下这样的内容：

line(P1, P2, T, P3) :- {(P2 - P1) * T = P3}.

其中P1，P2和P3是实向量。

达到类似目标的最佳方法是什么？到目前为止，我发现最好的方法是重写自己的add，subtract和multiply谓词，但这并不那么方便。

Answer 1

这是一个解决方案，您仍然必须为要处理的每个运算符编写一些代码，但是在使用时仍可以提供很好的语法。

让我们从评估向量到向量的算术表达式的概念开始。这本质上是逐个应用算术运算。（但是您可以添加点产品或任何您喜欢的产品。）

:- use_module(library(clpr)).

vectorexpr_value((X,Y,Z), (X,Y,Z)).
vectorexpr_value(V * T, (X,Y,Z)) :-
    vectorexpr_value(V, (XV,YV,ZV)),
    { X = XV * T },
    { Y = YV * T },
    { Z = ZV * T }.
vectorexpr_value(L + R, (X,Y,Z)) :-
    vectorexpr_value(L, (XL,YL,ZL)),
    vectorexpr_value(R, (XR,YR,ZR)),
    { X = XL + XR },
    { Y = YL + YR },
    { Z = ZL + ZR }.
vectorexpr_value(L - R, (X,Y,Z)) :-
    vectorexpr_value(L, (XL,YL,ZL)),
    vectorexpr_value(R, (XR,YR,ZR)),
    { X = XL - XR },
    { Y = YL - YR },
    { Z = ZL - ZR }.

例如：

?- vectorexpr_value(A + B, Result).
A =  (_1784, _1790, _1792),
B =  (_1808, _1814, _1816),
Result =  (_1832, _1838, _1840),
{_1808=_1832-_1784},
{_1814=_1838-_1790},
{_1816=_1840-_1792} .

鉴于此，我们现在可以通过“评估”两个向量表达式并在结果上断言逐点相等来定义向量表达式的“相等性”。为了使它看起来不错，我们可以为其定义一个运算符：

:- op(700, xfx, ===).

这将===定义为与其他相等运算符=，=:=等具有相同优先级的中缀运算符。Prolog不允许您重载运算符，因此我们做了换一个新的。您可以认为运算符中的三个=符号在三个维中表示相等。

以下是相应的谓词定义：

ExprL === ExprR :-
    vectorexpr_value(ExprL, (XL,YL,ZL)),
    vectorexpr_value(ExprR, (XR,YR,ZR)),
    { XL = XR },
    { YL = YR },
    { ZL = ZR }.

现在我们几乎可以根据需要定义line/4：

line(P1, P2, T, P3) :-
    (P2 - P1) * T === P3.

测试：

?- line((0,0,0), (1,1,1), Alpha, (2,2,2)).
Alpha = 2.0 ;
false.

?- line((0,0,0), (1,1,1), Alpha, (2,3,4)).
false.

如何将Prolog CLP（R）与实向量相连接？

1 个答案: