Question

我正在继续研究格子和半格，并突然有了这个问题。

基本上，我们有一个[a，b]对的RelationList，这意味着（a，b）是一个边。现在我们应该知道，这是一个由RelationList 1连接形成的图形。顺便说一下，我们有一个有序图，所以（a，b）的顺序很重要。

clear_link(X, Y, RelationList) :-
    (member([X,Y], RelationList)
    ;
    member([Y,X], RelationList)),
    X =\= Y.

linked(X, Y, RelationList) :-
    clear_link(X, Y, RelationList),
    !.
linked(X, Y, RelationList) :-
    clear_link(X, Z, RelationList),
    linked(Z, Y, RelationList).

simple_connect(RelationList, E) :-
    forall((member(X, E),
    member(Y, E), X < Y),
    linked(X, Y, RelationList)).

但是，对于6元素图，我有stackoverflow。

?- simple_connect([[2,1],[2,3],[4,3],[4,5],[6,5]],[1,2,3,4,5,6]).
ERROR: Out of local stack

我定义错了吗？

Answer 1

我纠正了一些。现在很好

clear_link(X, Y, RelationList) :-
    member([X,Y], RelationList),
    X =\= Y.

linked(X, Y, RelationList) :-
    clear_link(X, Y, RelationList),
    !.
linked(X, Y, RelationList) :-
    clear_link(X, Z, RelationList),
    linked(Z, Y, RelationList),
    !.

simple_connect(RelationList, E) :-
    forall((member(X, E),
    member(Y, E), X < Y),
    linked(X, Y, RelationList)).

connective_graph(RelationList, E) :-
    findall(Relation, (
        member(X, RelationList),
        sort(X, Relation)
    ),SortRelationList),
    simple_connect(SortRelationList, E).

和

?- connective_graph([[2,1],[2,3],[4,3],[4,5],[6,5]],[1,2,3,4,5,6]).
true.

?- connective_graph([[2,1],[4,3],[4,5],[6,5]],[1,2,3,4,5,6]).
false.

正确答案（复制到发布）

connected(X, Y, RelationList) :-
    (member([X,Y], RelationList);
    member([Y,X], RelationList)).

path(X, Y, RelationList, Path) :-
    travel(X, Y, RelationList, [X], ReversePath),
    reverse(ReversePath, Path),!.

travel(X, Y, RelationList, Point, [Y | Point]) :-
    connected(X, Y, RelationList).
travel(X, Y, RelationList, Visited, Path) :-
    connected(X, Z, RelationList),
    Z =\= Y,
    \+member(Z, Visited),
    travel(Z, Y, RelationList, [Z|Visited], Path).

connective_graph(RelationList, E) :-
    forall((member(X, E),
        member(Y, E),
        X < Y)
    ,path(X,Y,RelationList,_)).

在Prolog中定义连接图

1 个答案: