Question

我一直在寻找Delphi中chi-square发布的可用和完整代码。通过网络有一些代码，但通常它们不工作或缺少部分，不编译等。还有一些库，但我对一些我可以简单实现的代码感兴趣。

我发现了一些差不多工作的东西。一些德语部分已修复，它编译并为大多数数据提供p-values：

function LnGamma (x : Real) : Real;    
const 
  a0 =  0.083333333096; 
  a1 = -0.002777655457; 
  a2 =  0.000777830670; 
  c  =  0.918938533205;     
var  
  r : Real;     
begin 
  r := (a0 + (a1 + a2 / sqr(x)) / sqr(x)) / x; 
  LnGamma := (x - 0.5) * ln(x) - x + c + r; 
end; 

function LnFak (x : Real) : Real;     
var 
  z : Real;     
begin 
  z := x+1; 
  LnFak := LnGamma(z); 
end; 

function Reihe (chi : Real; f : Real) : Real;
  const MaxError = 0.0001;    
var
  Bruch,
  Summe,
  Summand : Real;
  k, i    : longint;    
begin
  Summe := 1;
  k := 1;
  repeat
    Bruch := 1;
    for i := 1 to k do
      Bruch := Bruch * (f + 2 * i);
    Summand := power(chi, 2 * k) / Bruch;
    Summe := Summe + Summand;
    k := succ(k);
  until (Summand < MaxError);
  Reihe := Summe;
end;

function IntegralChi (chisqr : Real; f : longint) : Real;
var
  s : Real;
begin
  S := power((0.5 * chisqr), f/2) * Reihe(sqrt(chisqr), f)
                  * exp((-chisqr/2) - LnGamma((f + 2) / 2));
  IntegralChi := 1 - s;
end;

它对于相对较大的结果非常有用。

例如：

对于Chi = 1.142132和df = 1，我p获得0.285202，这是完美的。与SPSS结果或其他程序相同。

但是例如Chi = 138.609137和df = 4我应该收到关于0.000000的内容，但我在Reiche函数中遇到浮点溢出错误。 Summe和Summand非常大。

我承认理解分配功能不是我的强项，所以也许有人会告诉我我做错了什么？

非常感谢您提供的信息

Answer 1

您应该调试程序并发现存在溢出在你的循环中k = 149。对于k = 148，Bruch的值是3.3976725289e + 304。布鲁赫的下一次计算溢出。修复是代码

for i := 1 to k do
  Bruch := Bruch / (f + 2 * i);
Summand := power(chi, 2 * k) * Bruch;

通过此更改，您将在第156次迭代后获得值IntegralChi(138.609137,4) = 1.76835197E-7。

请注意，您的计算（即使对于这个简单的算法）也是次优的因为你一遍又一遍地计算布鲁赫值。只需更新一次每个循环：

function Reihe (chi : Real; f : Real) : Real;
  const MaxError = 0.0001;
var
  Bruch,
  Summe,
  Summand : Real;
  k    : longint;
begin
  Summe := 1;
  k := 1;
  Bruch := 1;
  repeat
    Bruch := Bruch / (f + 2 * k);
    Summand := power(chi, 2 * k) * Bruch;
    Summe := Summe + Summand;
    k := succ(k);
  until (Summand < MaxError);
  Reihe := Summe;
end;

应该对计算power(chi, 2*k)进行类似的考虑，然后将其与布鲁赫的改进评估相结合。

修改：作为对评论的回复，此处基于power函数属性的改进版本，即power(chi, 2*(k+1)) = power(chi, 2*k)*sqr(chi)

function Reihe (chi : Real; f : Real) : Real;
  const MaxError = 0.0001;
var
  chi2,
  Summe,
  Summand : Real;
  k    : longint;
begin
  Summe := 1;
  k := 1;
  Summand := 1;
  chi2 := sqr(chi);
  repeat
    Summand := Summand * chi2 / (f + 2 * k);
    Summe := Summe + Summand;
    k := succ(k);
  until (Summand < MaxError);
  Reihe := Summe;
end;

Delphi中卡方分布函数的代码

1 个答案: