Question

我不是XSLT的专家。我要求检查所有“代码”值，按照以下规则设置状态代码。

如果所有代码值均为200，则将状态代码设置为200并将其设置为成功
如果所有代码值都是200或204，则将状态代码设置为200，并且reasonphrase是所有原因的结果，其中包含200以外的代码。
如果至少有一个代码包含200和204以外的值，则将状态代码设置为503，并且reasonphrase是所有具有200以外代码的原因的concatnatiopn。

我尝试了几种方法，将所有代码值存储在一个变量中，execeute包含具有上述条件的函数，以及创建代码变量和存储值，然后检查字符串长度。但我没有取得任何成功。

我正在寻找一些更通用的方法，因为这个要求是复杂xslt的一部分，下面只是一个需求的例子。一旦我获得了以下代码的逻辑，我应该能够在复杂的xslt中使用逻辑。

我也尝试搜索答案，但无法获得符合此要求的任何解决方案。

我在xslt 1.0中寻找解决方案，因为xslt的其他部分是用xslt 1.0编写的

输入 -

            <root>
                <Node1>
                        <code>200</code>
                        <reason>Success</reason>
                </Node1>
                <Node1>
                        <code>200</code>
                        <reason>Success</reason>
                </Node1>
                <Node1>
                        <code>204</code>
                        <reason>Business Error</reason>
                </Node1>
                <Node1>
                        <code>500</code>
                        <reason>Tech Error</reason>
                </Node1>
                <Node1>
                        <code>200</code>
                        <reason>Success</reason>
                </Node1>
            </root>

输出 -

            <root>
            <output>
                <statuscode></statuscode>
                <reasonphrase></reasonphrase>
            </output>
            </root>

谢谢。

Answer 1

以此为出发点：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/root">
    <xsl:copy>
        <output>
            <xsl:choose>
                <xsl:when test="not(Node1[code!=200])">
                    <!-- all code values are 200 -->
                    <statuscode>200</statuscode>
                    <reasonphrase>success</reasonphrase>
                </xsl:when>
                <xsl:when test="not(Node1[code!=200 and code!=204])">
                    <!-- all code values are either 200 or 204 -->
                    <statuscode>200</statuscode>
                    <reasonphrase>
                        <xsl:for-each select="Node1[code!=200]">
                            <xsl:value-of select="code"/>
                            <xsl:if test="position()!=last()">
                                <xsl:text> </xsl:text>
                            </xsl:if>
                        </xsl:for-each>  
                    </reasonphrase>
                </xsl:when>
                <xsl:otherwise>
                    <statuscode>503</statuscode>
                    <reasonphrase>
                        <xsl:for-each select="Node1[code!=200]">
                            <xsl:value-of select="code"/>
                            <xsl:if test="position()!=last()">
                                <xsl:text> </xsl:text>
                            </xsl:if>
                        </xsl:for-each>  
                    </reasonphrase>
                </xsl:otherwise>
            </xsl:choose>
        </output>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

请注意，这可以简化以消除重复代码 - 但这里的重点是展示如何测试给定条件。

XSLT检查每个元素的值和元素的设置值

1 个答案: