Question

我正在尝试用VHDL实现一个4位移位寄存器。我觉得我的实际转换的实现是正确的，但我的输出不起作用。每一个都是“0”。

我一直在玩放置，但我对VHDL很新。有什么想法吗？

我几乎肯定这个问题来自这一部分：

signal temp: std_logic_vector(3 downto 0):="0000"; -- initial value of output
begin
process (clock)
begin
O <= temp;

但我不确定如何解决它。

library ieee;
use ieee.std_logic_1164.all;

entity shift_reg is
port(   I:  in std_logic_vector (3 downto 0);
        I_SHIFT_IN: in std_logic;
        sel:        in std_logic_vector(1 downto 0); -- 00:hold; 01: shift left; 10: shift right; 11: load
        clock:      in std_logic; 
        enable:     in std_logic; -- 0: don't do anything; 1: shift_reg is enabled
        O:  out std_logic_vector(3 downto 0)
);
end shift_reg;

architecture behav of shift_reg is
signal temp: std_logic_vector(3 downto 0):="0000"; -- initial value of output
begin
process (clock)
begin
O <= temp;
if (enable = '1') then
if (clock='1') then --rising_edge(clock) and
case sel is
when "00" => -- hold
temp <= temp;
O <= temp;
when "01" => -- left shift
temp <= (temp(2 downto 0) & I_SHIFT_IN);
O <= (temp(2 downto 0) & I_SHIFT_IN);
when "10" => -- right shift
temp <= (I_SHIFT_IN & temp(3 downto 1));
O <= (I_SHIFT_IN & temp(3 downto 1));
when "11" => -- load
temp <= I;
O <= I;
when others => --other? exception handling? wouldn't compile without this
temp <= "1111";
O <= "1111";
end case;
end if;
--else null;
end if;
end process;
end behav;

Answer 1

我几乎肯定这个问题来自这一部分：
signal temp: std_logic_vector(3 downto 0):="0000"; -- initial value of output
begin
process (clock)
begin
O <= temp;
但我不确定如何解决它。

这个问题有点微妙。 O分配实际上不是问题。温度与以后再次分配的温度相同。

任何模拟时间只有一个投影输出波形值，两个任务意味着最新的一个将取代较早的。

当任何进程尚未恢复或尚未暂停时，也不会发生信号更新。在当前模拟周期期间，而不是在下一个开始时，不会发生没有相对延迟（相当于0 ns后）的信号更新。变量分配立即发生。

因此，您希望temp成为流程语句中声明的变量。您还可以注意到，使用VHDL -2008，您可以评估O并且不需要temp。

您的代码中还有一些综合问题。虽然它将使用clock = '1'作为检测时钟上升沿的if语句条件成功模拟，但用于合成的约定是显式的。例如，您可以使用包std_logic_1164中定义的rising_edge(clock)，当输入信号从“0”转换为“1”（而不是从“X”转换为“1”等时，它会返回布尔值（用于条件评估））。

如果使用带有启用的if语句的语句将导致门控时钟而不是使用合成中的启用来推断存储，那么还存在围绕时钟边缘的含义。解决这个问题的方法是交换两个if语句条件。

清理所有这些东西，你可以得到一些看起来像的东西：

architecture behav of shift_reg is
    -- signal temp: std_logic_vector(3 downto 0):="0000";
begin
    process (clock)
        variable temp: std_logic_vector(3 downto 0):="0000";
    begin
        -- O <= temp;
        if rising_edge(clock) then 
            if enable = '1' then  -- don't gate clock, enable
                case sel is
                    when "00" => -- hold
                        temp := temp;
                    when "01" => -- left shift
                        temp := (temp(2 downto 0) & I_SHIFT_IN);
                    when "10" => -- right shift
                        temp := (I_SHIFT_IN & temp(3 downto 1));
                    when "11" => -- load
                        temp := I;
                    when others => 
                        -- temp <= "1111"; -- temp <= NULL; -- null statement
                end case;
                O <= temp;
            end if;
        end if;
    end process;
end architecture behav;

您可以注意到案例陈述中的其他选择下没有任何陈述。每个case语句替代都包含一系列语句（IEEE Std 1076-2008 10.9 Case语句）。

在10.1下，我们看到一系列语句可以是空的或一个或多个顺序语句（参见1.3.2句法描述f），大括号中的项目出现零次或多次。

如果要明确显示此处没有任何内容，则可以使用空语句（10.14）。

因为在case语句中sel的每个二进制值都发生了对O的赋值，所以我们只需要一个赋值。如果它在过程开始时会导致半个时钟延迟（直到下一个时钟事件）。

要演示问题或更改的代码是否有效，您可以使用测试平台，提供Minimal, Complete, and Verifiable example：

library ieee;
use ieee.std_logic_1164.all;

entity shift_reg_tb is
end entity;

architecture foo of shift_reg_tb is
    signal I:          std_logic_vector (3 downto 0);
    signal I_SHIFT_IN: std_logic;
    signal sel:        std_logic_vector(1 downto 0); 
    signal clock:      std_logic := '0'; 
    signal enable:     std_logic; 
    signal O:          std_logic_vector(3 downto 0);
    type op is (HOLD, LEFT, RIGHT, LOAD);
    signal shftop:     op;
    use ieee.numeric_std.all;
begin
    shftop <= op'val(to_integer(unsigned(sel)) );
DUT:
    entity work.shift_reg
        port map (
            I => I,
            I_SHIFT_IN => I_SHIFT_IN,
            sel => sel,
            clock => clock,
            enable => enable,
            O => O
        );
CLOCK_PROC:
    process
    begin
        wait for 5 ns;
        clock <= not clock;
        if now > 160 ns then
            wait;
        end if;
    end process;
STIMULI:
    process
    begin
        wait until rising_edge(clock);
        I <= x"C";
        I_SHIFT_IN <= '0';
        enable <= '0';
        sel <= "00";                    -- HOLD
        wait until rising_edge(clock);
        enable <= '1';
        wait until rising_edge(clock);
        sel <= "11";                     -- LOAD
        wait until rising_edge(clock);
        sel <= "10";                     -- shift right
        wait until rising_edge(clock);
        wait until rising_edge(clock);
        I_SHIFT_IN <= '1';
        wait until rising_edge(clock);
        wait until rising_edge(clock);
        I_SHIFT_IN <= '0';
        sel <= "01";                     -- shift left
        wait until rising_edge(clock);
        wait until rising_edge(clock);
        I_SHIFT_IN <= '1';
        enable <= '1';
        wait until rising_edge(clock);
        wait until rising_edge(clock);
        wait until rising_edge(clock);
        wait until rising_edge(clock);
        wait until rising_edge(clock);
        wait until rising_edge(clock);
        enable <= '0';
        wait;

    end process;
end architecture;

注意创建一个枚举类型来定义移位寄存器操作，该类型的信号（shftop）被赋予从sel值转换的值，以使波形显示更容易解释：

好消息是你的案例陈述中的表达方式是有效的。

用于4位移位寄存器的VHDL输出有问题

1 个答案: