Question

我一直在尝试使用单纯形噪声在程序上生成球体表面，我认为为了获得平滑，无失真的噪声，我需要将每个uv像素映射到xyz坐标。我尝试了一些不同的算法，以下是我的最爱：

function convert2d3d(r1, r2, x, y) {
    let z = -1 + 2 * x / r1;
    let phi = 2 * Math.PI * y / r1;
    let theta = Math.asin(z);
    return {
        x: r2 * Math.cos(theta) * Math.cos(phi),
        y: r2 * Math.cos(theta) * Math.sin(phi),
        z: r2 * z,
    }
}

虽然生成的点看起来是连续的，但纹理接缝周围会出现严重的扭曲，并且纹理的拉伸最多：

simplex noise

我知道我要做的事情叫做UV贴图，但我正在努力正确地实现它。要么我得到严重的扭曲，要么是丑陋的接缝。为了渲染球体，我正在使用Three.JS MeshPhongMaterial，并且我正在使用noisejs。

Answer 1

你想要THIS之类的东西吗？在场景右上方的gui中 - ＆gt;几何选择球体。

无需乱用紫外线：）

上面链接的演示中的顶点着色器：

varying vec3 vPosition;
void main() {
  vPosition = normalize(position);
  gl_Position = projectionMatrix * modelViewMatrix * vec4(position,1.0);
}

上面链接的演示中的片段着色器：

varying vec3 vPosition;
uniform float scale;

//
// Description : Array and textureless GLSL 2D/3D/4D simplex 
//               noise functions.
//      Author : Ian McEwan, Ashima Arts.
//  Maintainer : ijm
//     Lastmod : 20110822 (ijm)
//     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
//               Distributed under the MIT License. See LICENSE file.
//               https://github.com/ashima/webgl-noise
// 

vec3 mod289(vec3 x) {
  return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 mod289(vec4 x) {
  return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 permute(vec4 x) {
     return mod289(((x*34.0)+1.0)*x);
}

vec4 taylorInvSqrt(vec4 r)
{
  return 1.79284291400159 - 0.85373472095314 * r;
}

float snoise(vec3 v)
  { 
  const vec2  C = vec2(1.0/6.0, 1.0/3.0) ;
  const vec4  D = vec4(0.0, 0.5, 1.0, 2.0);

// First corner
  vec3 i  = floor(v + dot(v, C.yyy) );
  vec3 x0 =   v - i + dot(i, C.xxx) ;

// Other corners
  vec3 g = step(x0.yzx, x0.xyz);
  vec3 l = 1.0 - g;
  vec3 i1 = min( g.xyz, l.zxy );
  vec3 i2 = max( g.xyz, l.zxy );

  //   x0 = x0 - 0.0 + 0.0 * C.xxx;
  //   x1 = x0 - i1  + 1.0 * C.xxx;
  //   x2 = x0 - i2  + 2.0 * C.xxx;
  //   x3 = x0 - 1.0 + 3.0 * C.xxx;
  vec3 x1 = x0 - i1 + C.xxx;
  vec3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
  vec3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y

// Permutations
  i = mod289(i); 
  vec4 p = permute( permute( permute( 
             i.z + vec4(0.0, i1.z, i2.z, 1.0 ))
           + i.y + vec4(0.0, i1.y, i2.y, 1.0 )) 
           + i.x + vec4(0.0, i1.x, i2.x, 1.0 ));

// Gradients: 7x7 points over a square, mapped onto an octahedron.
// The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
  float n_ = 0.142857142857; // 1.0/7.0
  vec3  ns = n_ * D.wyz - D.xzx;

  vec4 j = p - 49.0 * floor(p * ns.z * ns.z);  //  mod(p,7*7)

  vec4 x_ = floor(j * ns.z);
  vec4 y_ = floor(j - 7.0 * x_ );    // mod(j,N)

  vec4 x = x_ *ns.x + ns.yyyy;
  vec4 y = y_ *ns.x + ns.yyyy;
  vec4 h = 1.0 - abs(x) - abs(y);

  vec4 b0 = vec4( x.xy, y.xy );
  vec4 b1 = vec4( x.zw, y.zw );

  //vec4 s0 = vec4(lessThan(b0,0.0))*2.0 - 1.0;
  //vec4 s1 = vec4(lessThan(b1,0.0))*2.0 - 1.0;
  vec4 s0 = floor(b0)*2.0 + 1.0;
  vec4 s1 = floor(b1)*2.0 + 1.0;
  vec4 sh = -step(h, vec4(0.0));

  vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
  vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;

  vec3 p0 = vec3(a0.xy,h.x);
  vec3 p1 = vec3(a0.zw,h.y);
  vec3 p2 = vec3(a1.xy,h.z);
  vec3 p3 = vec3(a1.zw,h.w);

//Normalise gradients
  vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
  p0 *= norm.x;
  p1 *= norm.y;
  p2 *= norm.z;
  p3 *= norm.w;

// Mix final noise value
  vec4 m = max(0.6 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
  m = m * m;
  return 42.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1), 
                                dot(p2,x2), dot(p3,x3) ) );
  }

void main() {
  float n = snoise(vPosition * scale);
  gl_FragColor = vec4(1.0 * n, 1.0 * n, 1.0 * n, 1.0);
}

上面采用了scale类型为float的统一。

var uniforms = {
    scale: { type: "f", value: 10.0 }
};

更多ShaderMaterial demos

Answer 2

权衡WebGL与Textures的优缺点，我决定使用以下函数：

function convert2d3d(r, x, y) {
    let lat  = y / r * Math.PI - Math.PI / 2;
    let long = x / r * 2 * Math.PI - Math.PI;

    return {
        x: Math.cos(lat) * Math.cos(long),
        y: Math.sin(lat),
        z: Math.cos(lat) * Math.sin(long),
    }
}

在大小为r×r的方形纹理上给出一个点，转换为lat / long，返回一个3d坐标，其中纹理被映射到半径为1的球体上。

我从a blog post on inear.se改编了函数，将其转换为使用度。如果没有2phas回答给我一个替代方案，并帮助我寻找我需要的东西，我就不会管理它。这是它的样子：

green-black globe

现在它很难看，但这是第一步。

将2D uv点平滑地映射到3D xyz球体上

2 个答案: