Question

我几天前发布了这个问题：Haskell performance using dynamic programming并且建议使用ByteStrings而不是字符串。在使用ByteStrings实现算法后，程序崩溃，超出了内存限制。

import Control.Monad
import Data.Array.IArray
import qualified Data.ByteString as B

main = do
  n <- readLn
  pairs <- replicateM n $ do
    s1 <- B.getLine
    s2 <- B.getLine
    return (s1,s2)
  mapM_ (print . editDistance) pairs

editDistance :: (B.ByteString, B.ByteString) -> Int
editDistance (s1, s2) = dynamic editDistance' (B.length s1, B.length s2)
  where
    editDistance' table (i,j)
      | min i j == 0 = max i j
      | otherwise = min' (table!((i-1),j) + 1) (table!(i,(j-1)) + 1) (table!((i-1),(j-1)) + cost)
      where
        cost =  if B.index s1 (i-1) == B.index s2 (j-1) then 0 else 1
        min' a b = min (min a b)

dynamic :: (Array (Int,Int) Int -> (Int,Int) -> Int) -> (Int,Int) -> Int
dynamic compute (xBnd, yBnd) = table!(xBnd,yBnd)
  where
    table = newTable $ map (\coord -> (coord, compute table coord)) [(x,y) | x<-[0..xBnd], y<-[0..yBnd]]
    newTable xs = array ((0,0),fst (last xs)) xs

内存消耗似乎随n缩放。输入字符串的长度为1000个字符。我希望Haskell在打印每个解决方案后释放editDistance中使用的所有内存。这不是这种情况吗？如果没有，我该怎么强迫这个？

我看到的唯一其他实际计算是针对cost，但强迫seq没有做任何事情。

Answer 1

如果您在计算任何结果和打印输出之前读取所有n输入，那么您的记忆肯定会随着n而增加。您可以尝试交错输入和输出操作：

main = do
  n <- readLn
  replicateM_ n $ do
    s1 <- B.getLine
    s2 <- B.getLine
    print (editDistance (s1,s2))

或者使用懒惰IO（未经测试，可能需要无偿B.）：

main = do
  n <- readLn
  cont <- getContents
  let lns = take n (lines cont)
      pairs = unfoldr (\case (x:y:rs) -> Just ((x,y),rs) ; _ -> Nothing) lns
  mapM_ (print . editDistance) pairs

编辑：其他可能的节省包括使用未装箱的阵列，而不是在阵列构建期间通过strLen^2强制整个last大小列表。考虑array ((0,0),(xBnd,yBnd)) xs。

Answer 2

我的感觉是问题是你的min'不够严格。因为它不强制它的参数，它只是为每个数组元素构建一个thunk。这会导致使用更多内存，GC时间增加等等。

我会尝试：

{-# LANGUAGE BangPatterns #-}

...
min' !a !b !c = min a (min b c)

动态Haskell中的空间泄漏

2 个答案: