Question

我在团结中创建简单的谷歌纸板游戏，我想添加分数。我知道如何正常地做到这一点，但在VR中它并不适合我。我试着把文字和显示分数放在里面，它看起来很好（不完全是因为它只显示在一只眼睛上）但是在我在手机上测试后，文字处于完全不同的地方。你知道这样做的正确方法吗？

Answer 1

创建一个World Space画布并将该画布连接到相机。这就是我如何在VR游戏中获取UI。

您需要为您的World Space UI对象设置自定义着色器，该对象具有渲染顺序以覆盖并关闭ZTest。

这是默认UI着色器的副本，并带有必要的更改。应该做的伎俩。只需使用此着色器制作材质，然后将其应用于您希望在WorldSpace UI中绘制几何图形顶部的所有内容。

 Shader "UI/Default_OverlayNoZTest"
 {
     Properties
     {
         [PerRendererData] _MainTex ("Sprite Texture", 2D) = "white" {}
         _Color ("Tint", Color) = (1,1,1,1)

         _StencilComp ("Stencil Comparison", Float) = 8
         _Stencil ("Stencil ID", Float) = 0
         _StencilOp ("Stencil Operation", Float) = 0
         _StencilWriteMask ("Stencil Write Mask", Float) = 255
         _StencilReadMask ("Stencil Read Mask", Float) = 255

         _ColorMask ("Color Mask", Float) = 15
     }

     SubShader
     {
         Tags
         { 
             "Queue"="Overlay" 
             "IgnoreProjector"="True" 
             "RenderType"="Transparent" 
             "PreviewType"="Plane"
             "CanUseSpriteAtlas"="True"
         }

         Stencil
         {
             Ref [_Stencil]
             Comp [_StencilComp]
             Pass [_StencilOp] 
             ReadMask [_StencilReadMask]
             WriteMask [_StencilWriteMask]
         }

         Cull Off
         Lighting Off
         ZWrite Off
         ZTest Off
         Blend SrcAlpha OneMinusSrcAlpha
         ColorMask [_ColorMask]

         Pass
         {
         CGPROGRAM
             #pragma vertex vert
             #pragma fragment frag
             #include "UnityCG.cginc"

             struct appdata_t
             {
                 float4 vertex   : POSITION;
                 float4 color    : COLOR;
                 float2 texcoord : TEXCOORD0;
             };

             struct v2f
             {
                 float4 vertex   : SV_POSITION;
                 fixed4 color    : COLOR;
                 half2 texcoord  : TEXCOORD0;
             };

             fixed4 _Color;

             v2f vert(appdata_t IN)
             {
                 v2f OUT;
                 OUT.vertex = mul(UNITY_MATRIX_MVP, IN.vertex);
                 OUT.texcoord = IN.texcoord;
 #ifdef UNITY_HALF_TEXEL_OFFSET
                 OUT.vertex.xy += (_ScreenParams.zw-1.0)*float2(-1,1);
 #endif
                 OUT.color = IN.color * _Color;
                 return OUT;
             }

             sampler2D _MainTex;

             fixed4 frag(v2f IN) : SV_Target
             {
                 half4 color = tex2D(_MainTex, IN.texcoord) * IN.color;
                 clip (color.a - 0.01);
                 return color;
             }
         ENDCG
         }
     }
 }

信用额转到http://answers.unity3d.com/questions/878667/world-space-canvas-on-top-of-everything.html

Answer 2

我说;设置一个RenderTexture并使你的/ UI成为唯一被绘制到它上面的东西，然后将RenderTexture粘贴到你世界的其他东西上

用于Unity中的Google Cardboard的VR中的GUI

2 个答案: