Maple Plot功能

Question

是否有人知道如何绘制左上角的狄拉克函数和图中给出的正弦函数。我设法轻松地绘制了第二个和第三个。你会用分段函数做到这一点，还是有一个简单的方法用于＃1和＃4？非常感谢你！

Arbitrary Excitations

Answer 1

如果这是家庭作业，那么我想，对于鼻窦的例子，你被要求调查尺度和移位的影响。

一个接一个地考虑这些情节。观察它们的不同之处。首先，我将幅度（y方向）缩放10.然后我在x方向上缩放。最后我向x方向移动。

plots:-setoptions(size=[300,0.6],tickmarks=[decimalticks,default]):
plot( 10*sin( x ), x=0 .. Pi, view=[0..Pi, 0..18] );

plot( 10*sin( x*Pi ), x=0 .. 1, view=[0..1, 0..18] );

plot( 10*sin( x*Pi/0.3 ), x=0 .. 0.3, view=[0..1, 0..18] );

plot( 10*sin( (x-0.1)*Pi/0.3 ), x=0.1 .. 0.4, view=[0..1, 0..18] );

plots:-setoptions();

可以使其看起来与您很容易链接的图像中的第4幅图相似。你可以尝试使用和不使用各种选项。

P:= plot( 10*sin( (x-0.1)*Pi/0.3 ), x=0.1 .. 0.4
          , axes=none
          , color=black
          , size=[300,0.7]
          , thickness=2
        ):

plots:-display( P
                , view=[0.0 .. 0.6, 0..18]
                , tickmarks=[[0.1,0.4],[10=10*N]]
                , axes=normal, labels=[`t[s]`,`F(t)`]
                , size=[300,0.6]
              );

通过更多努力，可以在视觉上使其更加贴近。

plots:-display( P
            , plottools:-arrow([0,0],[0.6,0], 0.05, 0.9, 0.05)
            , plottools:-arrow([0,0],[0,16], 0.001, 0.02, 0.08)
            , plots:-textplot([0.6, -3.5, `t[s]`, font=["courier",16]])
            , plots:-textplot([0.0, 18, `F(t)`, font=["courier",16]])
            , seq(plots:-textplot([X, -1.5, X]), X=[0,0.1,0.4])
            , plots:-textplot([-0.05, 10, "10 N"])
              );

对于你的其他情节，你可以简单地绘制一系列线条。

T:=table([1=60,2=100,3=0,4=20]):
P2:=seq(plottools:-line([i,0],[i,T[i]],thickness=2,color=black),
        i=1..4):

如上所述，您可以调整最终情节的外观和感觉。我会把它留给你。

plots:-display(P2
               , size=[300,0.7]
               , view=[0..6, 0..120]
               , labels=["",""]
              );