Question

我有一组实验数据（P），我想获得“实验性与预测性”图。为此，我使用另一组依赖于P（Q）的数据，绘制ScatterPlot，使用适当的拟合，然后获得回归线，并在适当的微分方程中使用其系数。 P的图看起来不错，但我需要在其中添加实验数据。为简单起见，我使用了间隔t=0..150。

如何绘制实验数据，以便P(0) = Pvals[1], P(10)=Pvals[2]等？此外，我该如何分发数据（例如，我有t=0..800并想绘制Pval以便于P(0) = Pvals[1] and P(800) = Pvals[16]）？

Pvals := [3.929, 5.308, 7.24, 9.638, 12.866, 17.069, 23.192, 31.433, 38.558, 50.156, 62.948, 
75.996, 91.972, 105.711, 122.775, 131.669]:

for i to 15 do Qval[i] := .1*(Pvals[i+1]/Pvals[i]-1); end do:
Qvals := [seq(Qval[i], i = 1 .. 15), 0.144513895e-1]:               
    with(Statistics);
ScatterPlot(Pvals, Qvals, fit = [a*v^2+b*v+c, v], thickness = 3, 
legend = [points = "Point data", fit = typeset("fit to a", 2^nd, "degree polynomial")]);

with(CurveFitting);
LeastSquares(Pvals, Qvals, v, curve = a*v^2+b*v+c);

de := diff(P(t), t) = (0.370152282598477e-1-0.272504103112702e-3*P(t))*P(t);

sol := dsolve({de, P(0) = 3.929}, P(t));

P := plot(rhs(sol), t = 0 .. 160);

Answer 1

我不确定我是否完全遵循您的方法。但这是否类似于您要实现的目标？

restart;
with(Statistics):

Pvals := [3.929, 5.308, 7.24, 9.638, 12.866, 17.069, 23.192, 31.433,
          38.558, 50.156, 62.948, 75.996, 91.972, 105.711, 122.775, 131.669]:

for i to 15 do Qval[i] := .1*(Pvals[i+1]/Pvals[i]-1); end do:
Qvals := [seq(Qval[i], i = 1 .. 15), 0.144513895e-1]:

form := a*v^2+b*v+c:

CF := CurveFitting:-LeastSquares(Pvals, Qvals, v, curve = form);

       CF := 0.0370152282598477 - 0.000272504103112702 v

                               -7  2
              + 5.60958249026713 10   v

现在我在DE中使用CF（因为我不明白为什么删除了v ^ 2项），

#de := diff(P(t), t) = (0.370152282598477e-1-0.272504103112702e-3*P(t))*P(t);
de := diff(P(t), t) = eval(CF, v=P(t))*P(t);

           d         /                                              
    de := --- P(t) = \0.0370152282598477 - 0.000272504103112702 P(t)
           dt                                                       

                            -7     2\     
       + 5.60958249026713 10   P(t) / P(t)

我将使用dsolve命令的numeric选项，并获得一个为数字P(t)值计算t的过程。

sol := dsolve({de, P(0) = 3.929}, P(t), numeric, output=listprocedure ):

Pfunc := eval(P(t), sol);

              Pfunc := proc(t)  ...  end;

Pfunc(0.0), Pvals[1];

                3.92900000000000, 3.929

现在进行一些调整（再次，这是我对您的目标的猜测），

endpt := fsolve(Pfunc(t)-Pvals[16]);

                  endpt := 135.2246055

Pfunc(endpt), Pvals[16];

               131.669000003321, 131.669

plot(Pfunc(t), t=0 .. endpt, size=[500,200]);

a,b,N := 0.0, 800.0, nops(Pvals);

                a, b, N := 0., 800.0, 16

Pfuncscaled := proc(t) 
                 if not t::numeric then
                   return 'procname'(args);
                 end if;
                 Pfunc(t*endpt/b);
               end proc:

Pfuncscaled(0), Pvals[1];

                3.92900000000000, 3.929

Pfuncscaled(800), Pvals[N];

               131.669000003321, 131.669

PLscaled := plot( Pfuncscaled(t), t=a .. b,
                  color=red, size=[500,200] );

现在也要针对Pdata显示0 .. 800，

V := Vector(N, (i)->a+(i-1)*(b-a)/(N-1)):

V[1], V[-1];

                    0., 800.0000000

Pdatascaled := plot( < V | Vector(Pvals) >,
                     color=blue, size=[500,200],
                     style=pointline, symbol=solidcircle );

然后，显示重新缩放的数据以及来自dsolve的重新缩放过程，

plots:-display( PLscaled, Pdatascaled, size=[500,500] );

如何在特殊点绘制实验数据？

1 个答案: