Question

当不再要求计时器运行时，我需要能够暂停计时器并保留其ET值。当接近开关的输入不存在时，定时器计时，但我只希望它在材料上转发的泵运行时计时。泵可能只运行30秒，但是接近开关可能需要120秒的泵送，因此在检测到任何材料之前需要运行4次泵。

如果有帮助，我正在使用Codesys v2.3

到目前为止，我有：

IF Motor AND NOT Proxy.P1 THEN (*If the motor is running and the proxy doesn't energise, then start that proxy's timer*)
    Proxy.P1_Timer.IN:= TRUE;
ELSE
    Proxy.P1_Timer.IN:=FALSE;
END_IF

但上述情况会导致ET值在Motor关闭时重置，而不仅仅是Proxy.P1变为TRUE时。 ET只应在Proxy.P1设置为TRUE

时重置

对此有何建议？我很惊讶FB上没有保留选项。

Answer 1

这是TON_Pausable。

TON_Pausable的行为就像普通的TON一样。此外，通过PAUSE输入暂停TON_Pausable，暂停时IN必须保持为真。

FUNCTION_BLOCK TON_Pausable
VAR_INPUT
    IN : BOOL;
    PT : TIME;
    PAUSE : BOOL;
END_VAR
VAR_OUTPUT
    Q : BOOL;
    ET : TIME;
END_VAR
VAR
    rtPause : R_TRIG;
    tTimePaused : TIME;
    ton : TON;
END_VAR

IF NOT IN THEN
    tTimePaused := T#0s;
END_IF

rtPause(CLK := PAUSE);

IF rtPause.Q THEN
    tTimePaused := tTimePaused + ton.ET;
END_IF

ton(IN := IN AND NOT PAUSE, PT := PT - tTimePaused);

Q := ton.Q;
ET := tTimePaused + ton.ET;

这种逻辑被封装并可重复使用。

Answer 2

暂停计时器我将使用以下代码

rEdgeTrig(CLK:=startTimer);

IF rEdgeTrig.Q THEN
    actualTime := actualTime - eTime;
END_IF;

(* TON timer *)
timer(IN:=startTimer,PT:=actualTime);

IF startTimer THEN
    eTime := timer.ET;
END_IF;

if timer.Q then
    acutalTime:=initialTime;
end_if;

当不再要求您的计时器运行时，将经过的时间加载到变量。然后在您想要重新开始时减去预设时间。

Answer 3

另一种方法是在CASE OF中调用定时器，如果Case没有调用TON，它将被暂停，在CASE和CASE之外小心处理TON的输入和输出

Answer 4

另一种方法可以是手动递增/递减计时器变量，在泵启动时在每次扫描时添加/减去扫描时间。可以使用必要的输入将此功能隐藏在功能块中一个简单的实现如下所示。

VAR
    tRun: TIME;
    bResetTimer: BOOL;
END_VAR
VAR_CONSTANT
    T_SCAN := t#10ms;
END_VAR

IF Pump.run AND NOT Proximity.on THEN
    tRun := tRun + tScan;
END_IF;
IF tRun >= t#120s THEN
    ; (* Do something *)
END_IF;
IF bResetTimer THEN
    tRun := t#0s;
    bResetTimer := FALSE;
END_IF;

Answer 5

这是一个计时器，可以配置为：

循环= FALSE，并且resetWhenOFF = TRUE | 运行起来就像普通的TON
循环=假，并且resetWhenOFF =假| 关闭时会暂停的音调
循环= TRUE，然后重置WhenOFF = FALSE | 到达timeLimit时具有上升沿输出的TON，此后它将重置并重新开始（循环）
loop = TRUE和resetWhenOFF = TRUE | 到达timeLimit时具有上升沿输出的TON，此后它将重置并重新开始（循环），并在OFF时暂停

FUNCTION_BLOCK TIMER
  VAR_INPUT
    ON: BOOL;
    reset: BOOL;
    timeLimit: TIME;
    loop: BOOL;
    resetWhenOFF: BOOL;
  END_VAR
  VAR_OUTPUT
    finished: BOOL;
    elapsedTime: TIME;
    remainingTime: TIME;
  END_VAR
  VAR
    _TON_INST: TON;
    _lastElapsedTime: TIME;
    _onTrigger: F_TRIG;
    _resetTrigger: R_TRIG;
    _doReset: BOOL;
  END_VAR

  _onTrigger(CLK := ON);

  IF (_onTrigger.Q) THEN
    IF (resetWhenOFF) THEN
        _lastElapsedTime := T#0MS;
        _doReset := TRUE;
    ELSE
        _lastElapsedTime := _TON_INST.ET + _lastElapsedTime;
    END_IF
  END_IF

  _resetTrigger(CLK := reset);
  _TON_INST(IN := ON AND NOT (_resetTrigger.Q OR _doReset), PT := timeLimit - _lastElapsedTime);

  finished := _TON_INST.Q;
  elapsedTime := _TON_INST.ET + _lastElapsedTime;
  remainingTime := _timeLimit - _lastElapsedTime - _TON_INST.ET;

  IF (_TON_INST.Q AND _loop) THEN
    _lastElapsedTime := T#0MS;
    _doReset := TRUE;
  END_IF

END_FUNCTION_BLOCK

暂停结构化文本中的计时器

5 个答案: