Question

我有一个XML文件，如下所示：

<components>
       <comp>
      <ref>q7</ref>
      <partnumber>foo</partnumber>
   </comp>
   <comp>
      <ref>q1</ref>
      <partnumber>foo</partnumber>
   </comp>
   <comp>
      <ref>q6</ref>
      <partnumber>bar</partnumber>
   </comp>
   <comp>
      <ref>q3</ref>
      <partnumber>bar</partnumber>
   </comp>
</components>

我需要通过partnumber和ref来排序，以便输出文件看起来像这样：

q1 q7, foo
q3 q6, bar

但是我得到了这个输出：

q3 q6, bar
q1 q7, foo

这是我的XSL：

<!DOCTYPE xsl:stylesheet [
  <!ENTITY nl  "&#xd;&#xa;">    <!--new line CR, LF, or LF, your choice -->
]>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="text"/>
    <xsl:key name='compspec' match="comp" use="partnumber" />
    <xsl:template match="/components">
        <xsl:for-each select="comp[generate-id(.)=generate-id(key('compspec',partnumber)[1])]">
            <xsl:sort select="ref"/>
            <xsl:for-each select="key('compspec',partnumber)">
                <xsl:sort select="ref"/>
                <xsl:value-of select="ref"/>
                <xsl:text> </xsl:text>
            </xsl:for-each>
            <xsl:text>,</xsl:text>
            <xsl:value-of select="partnumber"/>
            <xsl:text>&nl;</xsl:text>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

我理解为什么我会得到这个序列，但我对XSLT很新，我不知道如何修复它。我应该修复我的代码吗？我正在使用XSLT 1.0。谢谢！

Answer 1

如果您删除此行，您将获得所需的输出：

 <xsl:sort select="partnumber"/>

在您的第一个for-each循环中，因为您按partnumber（bar和foo）按字母顺序排序。

Answer 2

我需要按照最小值对具有相同部件号的组进行排序 COMP / REF

要在XSLT 1.0中执行此操作，您必须进行两次传递：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:key name='compspec' match="comp" use="partnumber" />

<xsl:template match="/components">
    <!-- first pass -->
    <xsl:variable name="groups">
        <xsl:for-each select="comp[generate-id(.)=generate-id(key('compspec',partnumber)[1])]">
            <group name="{partnumber}">
                <xsl:for-each select="key('compspec', partnumber)">
                    <xsl:sort select="ref"/>
                    <value>
                        <xsl:value-of select="ref"/>
                    </value>
                </xsl:for-each>
            </group>
        </xsl:for-each>
    </xsl:variable>
    <!-- output -->
    <xsl:for-each select="exsl:node-set($groups)/group">
        <xsl:sort select="value[1]"/>
        <xsl:for-each select="value">
            <xsl:value-of select="."/>
            <xsl:if test="position()!=last()">
                <xsl:text> </xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:text>, </xsl:text>
        <xsl:value-of select="@name"/>
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

注意：
在您的示例中，ref包含文本值，并在上面的代码中将排序为文本。因此， comp / ref 的最小值实际上是按字母顺序排列的第一个ref 。

XSLT复杂的排序和分组

2 个答案: