Question

目的：创建一个程序，它接受两个单独的文件，打开并读取它们，将它们的内容分配给数组，对这些数组进行一些数学计算，创建一个带有产品编号的新数组，打印到一个新文件。够简单吧？

我的输入文件在开头有注释字符。一个问题是，它们是'＃'，它们是大多数绘图程序的注释字符，但不是FORTRAN。什么是告诉计算机不要查看这些字符的简单方法？由于我之前没有FORTRAN经验，我正在通过两个测试文件来完成这项工作。以下是我到目前为止的情况：

PROGRAM gain
  IMPLICIT NONE
  REAL, DIMENSION (1:4, 1:8)     :: X, Y, Z
  OPEN(1, FILE='test.out', &
        STATUS='OLD', ACTION='READ')            ! opens the first file
  READ(1,*), X
  OPEN(2, FILE='test2.out', &
    STATUS='OLD', ACTION='READ')            ! opens the second file
  READ(2,*), Y
  PRINT*, X, Y

  Z = X*Y
!  PRINT*, Z
  OPEN(3, FILE='test3.out', STATUS='NEW', ACTION='WRITE')   !creates a new file
  WRITE(3,*), Z
  CLOSE(1)
  CLOSE(2)
  CLOSE(3)
END PROGRAM

PS。请不要用一堆代码猴子gobblety gook压倒我。我是一个总编程新手。我不懂所有的术语，这就是为什么我来到这里而不是在现有网站上寻求帮助的原因。感谢。

Answer 1

如果你的意思是注释只在文件的开头，那就很简单了 - 不需要计算注释行或倒带文件 - 你可以将这些行读成一个字符串并测试它们是否是一个评论。然后你最终会遇到一个非评论行。问题：它将被读入一个字符串，因此无法用于常规读取...解决方案...使用“退格”来读取一条记录，以便您现在可以使用普通文件读取来读取文件的其余部分。如果注释行穿插在整个文件中，则需要稍微复杂的解决方案 - 如前所述，将行读入字符串，然后从字符串中读取。

这是一个有用的例子......我假设“＃”在第一列和各种其他简化假设中。一些建议：将子程序和函数放入模块并“使用”该模块 - 这将允许编译器检查接口。在开发程序时，尽可能多地使用代码检查和警告选项 - 特别是下标边界检查 - 最终会节省时间。

P.S。自Fortran 90以来它正式成为“Fortran” - 它是FORTRAN 77及更早版本的“FORTRAN”。

module read_file_module

   implicit none

contains

   subroutine read_file (UnitNum, FileName, NumRows, NumCols, Array )

      integer, intent (in) :: UnitNum
      character (len=*), intent (in) :: FileName
      integer, intent (in) :: NumRows, NumCols
      real, dimension (1:NumRows, 1:NumCols), intent (out) :: Array

      character (len=300) :: line
      integer :: i, j

      open (unit=UnitNum, file=FileName, status='old', action='read' )

      ReadComments: do
         read (UnitNum, '(A)') line
         if (line (1:1) /= "#") exit ReadComments
      end do ReadComments

      backspace (UnitNum)

      do i=1, NumRows
         read (UnitNum, *) (Array (i, j), j=1,NumCols)
      end do

      close (UnitNum)

      return

   end subroutine read_file

end module read_file_module 




program test_prog

use read_file_module

implicit none

real, dimension (1:8, 1:4) :: Array
integer :: i, j

call read_file (66, 'TestFile.txt', 8, 4, Array)

do i=1, 8
  write (*, '( 4(2X, F7.3) )' ) (Array (i, j), j=1,4)
end do

end program test_prog

一些测试数据显示输入数据的灵活性：

#  comment one
#  comment two
1.1   2.0  3.0  4.1
1.2   2.0  3.0  4.2
1.3   2.0  3.0  4.3
1.4   
  2.0  3.0  4.4
1.5   2.0  3.0  4.5
1.6   2.0  3.0  4.6


1.7   2.0  3.0  4.7
1.8   2.0  3.0  4.8

Answer 2

编写一个子程序，将此逻辑放入一个位置，以便您可以为两个文件调用它。您需要将每行读作字符串并添加IF测试以检查给定行是否以“＃”开头。如果该行以“＃”开头，则只需阅读下一行。如果没有，请将字符串转换为值并将其添加到您要返回的值数组中。

Answer 3

我对FORTRAN 77之外的任何事情都不熟悉，但这里有一些指针（以及你在答案中发布的工作版本）。首先是工作代码（我添加了行号）：

1   REAL FUNCTION myfile(unit, file, rows, columns)
2   IMPLICIT NONE
3   INTEGER, INTENT(IN) :: unit, rows, columns
4   CHARACTER(LEN=*) :: file
5   REAL, DIMENSION (1:columns, 1:rows) ::X
6   OPEN(unit, FILE=file, STATUS='OLD', ACTION='READ')
7   READ(unit,*), X
8   PRINT*, X         
9   CLOSE(unit)
10  myfile= 0
11  END FUNCTION myfile
12
13  PROGRAM gain
14  errno = myfile(1, "test.out", 8, 4)
15  END PROGRAM

区别在于：

第6行 - 您需要删除FILE ='file'分配中'file'周围的引号。如上所述，您使用的是名为file的文件，而不是传入的名称作为文件参数。
第10行 - 由于您将此声明为函数，因此在离开函数之前需要为函数名指定返回值。我只是给它赋值0以允许它编译。我想你在这里想要的是将你从文件中读入的数组传递回例程。在这种情况下，您需要修改函数的类型（并将X分配给myfile）或将数组作为参数传递，并允许在函数中修改它。（在旧的FORTRAN 77世界中，这是通过公共块或指向数组的指针完成的，不确定如何在更高版本的Fortran中执行此操作）。
第14行 - 您需要将函数的返回值赋给变量。至少你用我的gfortran编译器做了。它不会让我编译程序。
第14行（再次） - 函数调用需要引号中的文件名（test.out）。你有没有引号，所以有问题（这可能是你的数组引用错误的来源，我的编译器出现了不同的错误。）

您可以将myfile例程定义为子例程，而不是使用函数。在这种情况下，您肯定需要传入您想要填充的数组作为参数。您不需要第10行，而是将返回值分配给主程序中您将“调用”例程的变量。即第14行看起来像这样：

call myfile(1, "test.out",8,4)

编辑：我发布了这个，然后意识到我忘了回答原来的问题。我这样做然后由于某种原因无法连接到SO上传编辑。所以他们终于来了。

这会让你的日常编译。要真正处理注释行，您有几个选项（至少这些是最初想到的）。这些是从最简单/最脆弱到更强大/一般的顺序：

如果您确切地知道数据文件中有多少注释行（并且对于所有文件都是相同的），您可以读取那么多行，扔掉读入的内容然后从数组中读取点。这将使您超越注释，然后读入数组。但是，如果不同输入文件中的注释行数不同，则不起作用。同样，如果将来发生变化，则需要更改代码。这个选项可能不是最好的。
将文件传递作为字符串一次读取一行，并检查它是否以＃标记开头。如果这样增加一个计数器。当您找到第一个非注释行时，停止，将文件重置为开头，然后按照上面＃1中的步骤使用计数器值作为要跳过的行数。这比＃1更灵活，因为它可以处理任意数量的注释行，但它们仍然必须位于文件的开头。数据中间的任何评论都会让你感到困惑。
以字符串形式读取每一行，查找＃符号，如果不存在，则解析该行并手动填充该数组。这是最复杂的，但为输入文件格式提供了最大的灵活性。它允许您在数据文件中的任何位置拥有（并忽略）注释。

您选择哪种方法（以及其他人可能有其他建议）取决于您的特定应用。祝你好运。

在FORTRAN中读取输入文件

3 个答案: