Question

有人使用以下子程序为我生成输出

subroutine write(...)
REAL*8 v(a), h(b), f(b)
integer iv(b+1), jv(a)

 write(ium) a, b, c, d, e
 write(ium) (iv(i),i=1,b+1)
 write(ium) (jv(i),i=1,a)
 write(ium) (v(i),i=1,a)
 write(ium) (f(i),i=1,b)
 write(ium) (h(i),i=1,b)

return
end

我知道a，b，c，d和e都是整数（虽然例程没有指定它们，这样可以吗？！）。整个输出进入一个二进制文件，他发送给我，我现在想要检索所有（分离的）信息。

我真的不太了解Fortran I / O所以我希望有人可以提供帮助...

Answer 1

这是一个简单的示例，基本上只需write交换read。注意首先分配数组。

program test
  implicit none

  integer,parameter   :: ium=1234
  integer             :: a=1, b=2, c=3, d=4, e=5
  REAL*8,allocatable  :: v(:), h(:), f(:)
  integer,allocatable :: iv(:), jv(:)
  integer             :: i, stat

  ! Set values
  allocate( v(a), h(b), f(b), iv(b+1), jv(a), stat=stat )
  if (stat/=0) stop 'Cannot allocate memory!'

  v=1.d0
  h=2.d0
  f=3.d0
  iv = 4
  jv = 5

  write(*,*) v, h, f

  ! Write back
  open(unit=ium, file='test',form='unformatted',status='replace',action='write')

  write(ium) a, b, c, d, e
  write(ium) (iv(i),i=1,b+1)
  write(ium) (jv(i),i=1,a)
  write(ium) (v(i),i=1,a)
  write(ium) (f(i),i=1,b)
  write(ium) (h(i),i=1,b)

  close(ium)

  ! Scratch
  deallocate( v, h, f, iv, jv )

  !========================================
  ! Read in
  open(unit=ium, file='test',form='unformatted',status='old',action='read')

  read(ium) a, b, c, d, e
  ! Allocate arrays
  allocate( v(a), h(b), f(b), iv(b+1), jv(a), stat=stat )
  if (stat/=0) stop 'Cannot allocate memory!'

  read(ium) (iv(i),i=1,b+1)
  read(ium) (jv(i),i=1,a)
  read(ium) (v(i),i=1,a)
  read(ium) (f(i),i=1,b)
  read(ium) (h(i),i=1,b)

  close(ium)
  write(*,*) v, h, f

  deallocate( v, h, f, iv, jv )
end program

根据您的需要进行调整。

在Fortran90中读取二进制输入

1 个答案: