Question

我需要调试一个GLSL程序，但我不知道如何输出中间结果。是否可以使用GLSL制作一些调试跟踪（如printf）？

Answer 1

您无法轻松地从GLSL内部与CPU通信。使用glslDevil或其他工具是您最好的选择。

printf需要尝试从运行GLSL代码的GPU返回CPU。相反，您可以尝试推进显示。而不是尝试输出文本，输出视觉上与屏幕不同的东西。例如，只有当您到达要添加printf的代码点时，才能绘制特定颜色的内容。如果需要printf值，可以根据该值设置颜色。

Answer 2

void main(){
  float bug=0.0;
  vec3 tile=texture2D(colMap, coords.st).xyz;
  vec4 col=vec4(tile, 1.0);

  if(something) bug=1.0;

  col.x+=bug;

  gl_FragColor=col;
}

Answer 3

我发现Transform Feedback是调试顶点着色器的有用工具。您可以使用它来捕获VS输出的值，并在CPU端读回它们，而无需通过光栅化器。

Here是转换反馈教程的另一个链接。

Answer 4

如果要在屏幕上显示值的变化，可以使用类似于此的热图函数（我在hlsl中编写它，但很容易适应glsl）：

float4 HeatMapColor(float value, float minValue, float maxValue)
{
    #define HEATMAP_COLORS_COUNT 6
    float4 colors[HEATMAP_COLORS_COUNT] =
    {
        float4(0.32, 0.00, 0.32, 1.00),
        float4(0.00, 0.00, 1.00, 1.00),
        float4(0.00, 1.00, 0.00, 1.00),
        float4(1.00, 1.00, 0.00, 1.00),
        float4(1.00, 0.60, 0.00, 1.00),
        float4(1.00, 0.00, 0.00, 1.00),
    };
    float ratio=(HEATMAP_COLORS_COUNT-1.0)*saturate((value-minValue)/(maxValue-minValue));
    float indexMin=floor(ratio);
    float indexMax=min(indexMin+1,HEATMAP_COLORS_COUNT-1);
    return lerp(colors[indexMin], colors[indexMax], ratio-indexMin);
}

然后在你的像素着色器中输出如下内容：

return HeatMapColor(myValue, 0.00, 50.00);

并且可以了解它在像素中的变化情况：

enter image description here

当然，你可以使用任何你喜欢的颜色。

Answer 5

对于着色器来说，

GLSL Sandbox对我来说非常方便。

不调试本身（已被回答为无能力），但很方便快速查看输出的变化。

Answer 6

离线渲染纹理并评估纹理的数据。您可以通过Google搜索“渲染到纹理”opengl找到相关代码然后使用glReadPixels将输出读入数组并对其执行断言（因为在调试器中查看这么大的数组通常不是很有用）。

此外，您可能希望禁用钳位以输出不在0和1之间的值，这仅支持floating point textures。

我个人对于正确调试着色器一段时间的问题感到困扰。似乎没有一个好方法 - 如果有人找到一个好的（而不是过时的/已弃用的）调试器，请告诉我。

Answer 7

我正在共享片段着色器示例，我实际上是如何调试的。

#version 410 core

uniform sampler2D samp;
in VS_OUT
{
    vec4 color;
    vec2 texcoord;
} fs_in;

out vec4 color;

void main(void)
{
    vec4 sampColor;
    if( texture2D(samp, fs_in.texcoord).x > 0.8f)  //Check if Color contains red
        sampColor = vec4(1.0f, 1.0f, 1.0f, 1.0f);  //If yes, set it to white
    else
        sampColor = texture2D(samp, fs_in.texcoord); //else sample from original
    color = sampColor;

}

enter image description here

Answer 8

现有的答案都是好东西，但我想分享一个小宝石，它在调整GLSL着色器中棘手的精度问题方面很有价值。对于表示为浮点的非常大的int数，需要注意正确使用floor（n）和floor（n + 0.5）来实现round（）到精确的int。然后可以通过以下逻辑呈现一个精确int的浮点值，以将字节组件打包为R，G和B输出值。

  // Break components out of 24 bit float with rounded int value
  // scaledWOB = (offset >> 8) & 0xFFFF
  float scaledWOB = floor(offset / 256.0);
  // c2 = (scaledWOB >> 8) & 0xFF
  float c2 = floor(scaledWOB / 256.0);
  // c0 = offset - (scaledWOB << 8)
  float c0 = offset - floor(scaledWOB * 256.0);
  // c1 = scaledWOB - (c2 << 8)
  float c1 = scaledWOB - floor(c2 * 256.0);

  // Normalize to byte range
  vec4 pix;  
  pix.r = c0 / 255.0;
  pix.g = c1 / 255.0;
  pix.b = c2 / 255.0;
  pix.a = 1.0;
  gl_FragColor = pix;

Answer 9

在这个答案的底部是一个GLSL代码示例，它允许输出完整的float值作为颜色，编码IEEE 754 binary32。我像下面这样使用它（这个片段给出了modelview矩阵的yy组件）：

vec4 xAsColor=toColor(gl_ModelViewMatrix[1][1]);
if(bool(1)) // put 0 here to get lowest byte instead of three highest
    gl_FrontColor=vec4(xAsColor.rgb,1);
else
    gl_FrontColor=vec4(xAsColor.a,0,0,1);

在屏幕上显示此内容后，您可以使用任何颜色选择器，将颜色格式设置为HTML（如果您不需要更高的精度，则将00附加到rgb值，以及如果你这样做，则进行第二次传递以获得较低的字节），并且float的十六进制表示为IEEE 754 binary32。

以下是toColor()的实际执行情况：

const int emax=127;
// Input: x>=0
// Output: base 2 exponent of x if (x!=0 && !isnan(x) && !isinf(x))
//         -emax if x==0
//         emax+1 otherwise
int floorLog2(float x)
{
    if(x==0.) return -emax;
    // NOTE: there exist values of x, for which floor(log2(x)) will give wrong
    // (off by one) result as compared to the one calculated with infinite precision.
    // Thus we do it in a brute-force way.
    for(int e=emax;e>=1-emax;--e)
        if(x>=exp2(float(e))) return e;
    // If we are here, x must be infinity or NaN
    return emax+1;
}

// Input: any x
// Output: IEEE 754 biased exponent with bias=emax
int biasedExp(float x) { return emax+floorLog2(abs(x)); }

// Input: any x such that (!isnan(x) && !isinf(x))
// Output: significand AKA mantissa of x if !isnan(x) && !isinf(x)
//         undefined otherwise
float significand(float x)
{
    // converting int to float so that exp2(genType) gets correctly-typed value
    float expo=float(floorLog2(abs(x)));
    return abs(x)/exp2(expo);
}

// Input: x\in[0,1)
//        N>=0
// Output: Nth byte as counted from the highest byte in the fraction
int part(float x,int N)
{
    // All comments about exactness here assume that underflow and overflow don't occur
    const float byteShift=256.;
    // Multiplication is exact since it's just an increase of exponent by 8
    for(int n=0;n<N;++n)
        x*=byteShift;

    // Cut higher bits away.
    // $q \in [0,1) \cap \mathbb Q'.$
    float q=fract(x);

    // Shift and cut lower bits away. Cutting lower bits prevents potentially unexpected
    // results of rounding by the GPU later in the pipeline when transforming to TrueColor
    // the resulting subpixel value.
    // $c \in [0,255] \cap \mathbb Z.$
    // Multiplication is exact since it's just and increase of exponent by 8
    float c=floor(byteShift*q);
    return int(c);
}

// Input: any x acceptable to significand()
// Output: significand of x split to (8,8,8)-bit data vector
ivec3 significandAsIVec3(float x)
{
    ivec3 result;
    float sig=significand(x)/2.; // shift all bits to fractional part
    result.x=part(sig,0);
    result.y=part(sig,1);
    result.z=part(sig,2);
    return result;
}

// Input: any x such that !isnan(x)
// Output: IEEE 754 defined binary32 number, packed as ivec4(byte3,byte2,byte1,byte0)
ivec4 packIEEE754binary32(float x)
{
    int e = biasedExp(x);
    // sign to bit 7
    int s = x<0. ? 128 : 0;

    ivec4 binary32;
    binary32.yzw=significandAsIVec3(x);
    // clear the implicit integer bit of significand
    if(binary32.y>=128) binary32.y-=128;
    // put lowest bit of exponent into its position, replacing just cleared integer bit
    binary32.y+=128*int(mod(float(e),2.));
    // prepare high bits of exponent for fitting into their positions
    e/=2;
    // pack highest byte
    binary32.x=e+s;

    return binary32;
}

vec4 toColor(float x)
{
    ivec4 binary32=packIEEE754binary32(x);
    // Transform color components to [0,1] range.
    // Division is inexact, but works reliably for all integers from 0 to 255 if
    // the transformation to TrueColor by GPU uses rounding to nearest or upwards.
    // The result will be multiplied by 255 back when transformed
    // to TrueColor subpixel value by OpenGL.
    return vec4(binary32)/255.;
}

Answer 10

您可以尝试以下操作：https://github.com/msqrt/shader-printf，该实现被称为“ GLSL的简单printf功能”。

您可能还想尝试ShaderToy，并可能从YouTube的“ The Art of Code” YouTube频道观看类似这样的视频（https://youtu.be/EBrAdahFtuo），在这里您可以看到一些对调试和可视化效果很好的技术。我强烈推荐他的频道，因为他写了一些非常不错的文章，并且他也有技巧以新颖，引人入胜且易于理解的格式展示复杂的想法（他的Mandelbrot视频就是一个极好的例子，{{3} }）

我希望没有人会介意这个较晚的答复，但是这个问题在Google搜索GLSL调试中的排名很高，而且在9年中，当然有了很多改变：-）

PS：其他替代方案也可能是NVIDIA nSight和AMD ShaderAnalyzer，它们为着色器提供了完整的步进调试器。

Answer 11

GLSL Shader源代码由图形驱动程序编译和链接，并在GPU上执行。
如果要调试着色器，则必须使用RenderDoc或NVIDIA Nsight之类的图形调试器。

Answer 12

我发现了一个非常好的 github 库 (https://github.com/msqrt/shader-printf) 您可以在着色器文件中使用 printf 函数。

如何调试GLSL着色器？

12 个答案: