Question

考虑一个问题，您希望将f（x，y）~cos（x）的频谱表示转换为坐标空间。所以exp（i * x）+ exp（-i * x）----＆gt; f（x，y），其中f（x，y）= some_factor * cos（x）。

在列主要布局中（我的示例在下面的Fortran 2003/8中写入），谱阵列将初始化为，

src=(0.,0.)
src(2,1)=(1.,0.)  .

在变换之后，应该得到一个 tgt 的实数（双精度）数组，其中所有列都相同，每列的行为都是cos（x）函数。

但是，使用下面给出的代码，我得到一个 tgt 数组，其中只有奇数列的行为正确，而偶数都是零。

如果我做错了什么？

我的fftw3版本是3.4.4。

    program c2r
  ! COMPLEX --> REAL 2D MPI TRANSFORM

  ! compiled using: mpif90 -O0 -g -I/usr/include c2rnot.F90 -o c2rnot -L /usr/lib/x86_64-linux-gnu -lfftw3_mpi -lfftw3
  use, intrinsic :: iso_c_binding
  use MPI

  implicit none
  include 'fftw3-mpi.f03'
  integer :: ierr,id

  ! logical dimensions of the transform
  integer(C_INTPTR_T), parameter :: N1 = 32
  integer(C_INTPTR_T), parameter :: N2 = 32

  ! helper variables: storage size, extents along the slow dim, offsets
  integer(C_INTPTR_T) :: alloc_local, slicec,slicer,offc,offr

  ! pointers to planner, real (image) and complex (original) arrays
  type(C_PTR) :: plan, ctgt, csrc

  ! fortran array representation of csrc ...
  complex(8), pointer :: src(:,:)
  ! ..., ctgt and a total array to hold the mpi-gathered result
  real(8), pointer :: tgt(:,:),total(:,:)


  integer(C_INTPTR_T) :: i,y0

  ! init mpi and fftw ...
  call mpi_init(ierr)

  call mpi_comm_rank(MPI_COMM_WORLD,id,ierr)

  call fftw_mpi_init()
  ! done with init


  ! calculate local complex array storage requirements and layout
  alloc_local = fftw_mpi_local_size_2d(N2,N1/2+1, &
        & MPI_COMM_WORLD,slicec,offc)
  ! allocate local complex array
  csrc = fftw_alloc_complex(alloc_local)
  ! fortran representation
  call c_f_pointer(csrc, src, [N1/2+1,slicec])

  ! allocate local real array
  ctgt = fftw_alloc_real(2*alloc_local)
  ! for non-transposed arrays slices are the same
  slicer=slicec
  offr=offc
  ! fortran representation
  call c_f_pointer(ctgt, tgt, [2*(N1/2+1),slicer])

  ! allocate global container (holds gathered tgt arrays)
  if (id==0) allocate(total(N1,N2))

  ! N1 - fast, N2 - slow dimension, in: src, out: tgt
  plan =  fftw_mpi_plan_dft_c2r_2d(N2,N1,src,tgt, MPI_COMM_WORLD, FFTW_MEASURE)


  src=(0.D0,0.D0)

  ! ~ exp(i*x) + exp(-i*x) which should turn into ~ cos(x)
  src(2,1)=(1.D0,0.D0)

  tgt=0.D0
  ! do transform
  call fftw_mpi_execute_dft_c2r(plan,src,tgt)

  ! collect tgt-s into total in process 0
  call mpi_gather(tgt(1:n1,1:slicer),slicer*n1,mpi_double,total,slicer*n1,mpi_double,0,mpi_comm_world,ierr)

  ! The scalar field total has x: 1..N1, y:1..N2 layout. Print
  ! behaviour along the x-axis for a given, constant y. The result
  ! should be ~ cos(x) function for any y0 in [1..N2]. However, I get
  ! such result only for odd y0. For even, total(i,y0) is 0.
  y0=3
  if (id == 0) then
     do i=1,n1
        print *, i, total(i,y0)
     enddo
  endif

  call mpi_finalize(ierr)
end program c2r

Answer 1

请记住，所有进程都在mpi中执行代码。

因此，当您编写src(2,1)=(1.D0,0.D0)时，您正在设置size个频率，每个进程一个。

因此，如果使用单个进程mpiexec -np 1 c2rnot，您的代码似乎有效。但如果您运行了许多流程mpiexec -np 2 c2rnot，那么您还可以获得其他内容......

你能试试if(id==0) src(2,1)=(1.D0,0.D0)吗？ id是等级，与您的代码一样。

您也可以在MPI_REAL8中使用mpi_gather()：我的编译器抱怨mpi_double没有IMPLICIT类型。

祝你好运！再见，

执行从复杂到真实的fftw3 MPI傅立叶变换时的奇怪行为

1 个答案: