Question

装置：特斯拉C2050
操作系统：Windows 7企业版
IDE：VS 2010
CUDA：5.0（最新）

第一次在这里提问。我在CUDA计划中遇到了一些问题。

我有数百万个四面体，其中一个点位于（0,0,0），所以我可以使用公式：

获得四面体的体积。

所以，这是代码：

struct Triangle
{
    double x1;
    double y1;
    double z1;
    double x2;
    double y2;
    double z2;
    double x3;
    double y3;
    double z3;
};

CUDA代码：

__global__ void getResult(double *d_volume ,Triangle *d_triangles, Origin *d_point)
{
    extern __shared__ Triangle s_data[];
    int tid = threadIdx.x;
    int i =  blockDim.x * blockIdx.x + threadIdx.x;
    s_data[tid] = d_triangles[i];
    __syncthreads();
    d_volume[i] =s_data[tid].x1 * s_data[tid].y2 * s_data[tid].z3 + \
                s_data[tid].y1 * s_data[tid].z2 * s_data[tid].x3 + \
                s_data[tid].x2 * s_data[tid].y3 * s_data[tid].z1 - \
                s_data[tid].x3 * s_data[tid].y2 * s_data[tid].z1 - \
                s_data[tid].x2 * s_data[tid].y1 * s_data[tid].z3 - \
                s_data[tid].y3 * s_data[tid].z2 * s_data[tid].x1;
}

我从其他函数中得到了数百万个四面体作为数组。

// Host
Triangle *h_triangles = triangles;
double *h_volume;
// Device
Triangle *d_triangles;
double *d_volume;

// define grid and block size
int numThreadsPerBlock = numTriangles;
int numBlocks = numTrianges / 512;

// Shard memory size
int sharedMemSize = numThreadsPerBlock * sizeof(Triangle);

// allocate host and device memory
size_t memSize_triangles = numBlocks * numThreadsPerBlock * sizeof(Triangle);
size_t memSize_volume = numBlocks * numThreadsPerBlock * sizeof(double);

cudaMalloc( (void **) &d_triangles, memSize_triangles );
cudaMalloc( (void **) &d_volume, memSize_volume );

// Copy host array to device array
cudaMemcpy( d_triangles, h_triangles, memSize_triangles, cudaMemcpyHostToDevice );
cudaMemcpy( d_point, h_point, memSize_point, cudaMemcpyHostToDevice );

// launch kernel
dim3 dimGrid(numBlocks);
dim3 dimBlock(numThreadsPerBlock);

getResult<<< dimGrid, dimBlock, sharedMemSize >>>( d_volume, d_triangles);

// block until the device has completed
cudaThreadSynchronize();

// device to host copy
cudaMemcpy( h_volume, d_volume, memSize_volume, cudaMemcpyDeviceToHost );

// free device memory
cudaFree(d_triangles);
cudaFree(d_volume);

// free host memory
free(h_triangles); 
free(h_volume);

到目前为止，一切正常。但是我花费的时间比想象的要多。我的设备是Tesla C2050（515Gflops），比我的CPU快20倍（单核，20.25Gflops）。但只能加速大约10倍（不包括在设备和主机之间复制内存的时间。）

我想知道如何使它比CPU代码快20倍（用于获取音量的循环）。

谢谢！

PS：也许cudaMallocPitch（）会帮助我，但三角形不是矩阵，我不能用cudaMemcpy2D（）复制内存而不是cudaMemcpy（）。有谁可以帮我解决这个问题？

Answer 1

与CPU相比，GPU上的峰值性能通常更难获得。其中一个原因是许多内核受带宽限制而不是计算限制。

因为你的内核的计算复杂度是O（n）。您可能应该使用带宽度量来计算理论峰值性能，如下所示

1024*1024*64 * sizeof(double) * (9  +   1)     / (144e9    *    8/9)     = 42 ms
#tetrahedron                     #input #output   peak mem bw   ECC cost

另一方面，您的内核可以进一步优化。

请仔细选择blockDim / gridDim，错误的数字有时会导致20％的性能下降。
不是每个线程计算一个卷，而是可以为每个线程计算多个卷，这将减少线程启动开销。
由于您不在线程之间共享数据，因此__syncthreads()可能会被淘汰。
由于非合并的mem访问，结构数组（AoS）通常比GPU上的阵列结构（SoA）慢。你也可以尝试改变你的数据结构。

更新

获得了一个具有大型L1缓存设置和最佳blockDim / gridDim选择的新内核。它快了15％。这是代码和配置文件的结果。我的设备是M2090。

profile result

#include <stdlib.h>
#include <thrust/transform.h>
#include <thrust/device_vector.h>
#include <thrust/host_vector.h>
#include <iterator>
#include <thrust/inner_product.h>

using namespace thrust::placeholders;

struct Triangle
{
    double x1;
    double y1;
    double z1;
    double x2;
    double y2;
    double z2;
    double x3;
    double y3;
    double z3;
};

__global__ void getResultNoSMem(double *d_volume, Triangle *d_triangles)
{
    int i = blockDim.x * blockIdx.x + threadIdx.x;
    d_volume[i] = d_triangles[i].x1 * d_triangles[i].y2 * d_triangles[i].z3 +
            d_triangles[i].y1 * d_triangles[i].z2 * d_triangles[i].x3 +
            d_triangles[i].x2 * d_triangles[i].y3 * d_triangles[i].z1 -
            d_triangles[i].x3 * d_triangles[i].y2 * d_triangles[i].z1 -
            d_triangles[i].x2 * d_triangles[i].y1 * d_triangles[i].z3 -
            d_triangles[i].y3 * d_triangles[i].z2 * d_triangles[i].x1;
}

__global__ void getResult(double *d_volume, Triangle *d_triangles)
{
    extern __shared__ Triangle s_data[];
    int tid = threadIdx.x;
    int i = blockDim.x * blockIdx.x + threadIdx.x;
    s_data[tid] = d_triangles[i];
//  __syncthreads();
    d_volume[i] = s_data[tid].x1 * s_data[tid].y2 * s_data[tid].z3 +
            s_data[tid].y1 * s_data[tid].z2 * s_data[tid].x3 +
            s_data[tid].x2 * s_data[tid].y3 * s_data[tid].z1 -
            s_data[tid].x3 * s_data[tid].y2 * s_data[tid].z1 -
            s_data[tid].x2 * s_data[tid].y1 * s_data[tid].z3 -
            s_data[tid].y3 * s_data[tid].z2 * s_data[tid].x1;
}

__global__ void getResultOpt(double *d_volume, Triangle *d_triangles, int len)
{
    const int gridSize = blockDim.x * gridDim.x;
    int i = blockDim.x * blockIdx.x + threadIdx.x;

    while (i < len)
    {
        d_volume[i] = d_triangles[i].x1 * d_triangles[i].y2 * d_triangles[i].z3 +
                d_triangles[i].y1 * d_triangles[i].z2 * d_triangles[i].x3 +
                d_triangles[i].x2 * d_triangles[i].y3 * d_triangles[i].z1 -
                d_triangles[i].x3 * d_triangles[i].y2 * d_triangles[i].z1 -
                d_triangles[i].x2 * d_triangles[i].y1 * d_triangles[i].z3 -
                d_triangles[i].y3 * d_triangles[i].z2 * d_triangles[i].x1;
        i += gridSize;
    }
}

int main(void)
{
    const int m = 1024 * 1024;
    thrust::host_vector<Triangle> data(m);
    for (int i = 0; i < m; i++)
    {
        data[i].x1 = (double) rand() / RAND_MAX;
        data[i].y1 = (double) rand() / RAND_MAX;
        data[i].z1 = (double) rand() / RAND_MAX;
        data[i].x2 = (double) rand() / RAND_MAX;
        data[i].y2 = (double) rand() / RAND_MAX;
        data[i].z2 = (double) rand() / RAND_MAX;
        data[i].x3 = (double) rand() / RAND_MAX;
        data[i].y3 = (double) rand() / RAND_MAX;
        data[i].z3 = (double) rand() / RAND_MAX;
    }

    thrust::device_vector<Triangle> triangles = data;
    thrust::device_vector<double> volume(m);
    thrust::device_vector<double> volumeOpt(m);

    Triangle* dTriangles = thrust::raw_pointer_cast(&triangles[0]);
    double* dVolume = thrust::raw_pointer_cast(&volume[0]);
    double* dVolumeOpt = thrust::raw_pointer_cast(&volumeOpt[0]);

    int g;
    int b;

    int threadUpperLimit = 48 * 1024 / sizeof(Triangle);

    //for (b = 32; b <= 1024; b += 32)
    {
        b = 64;
        int gridDim = (m + b - 1) / b;
        getResultNoSMem<<<gridDim, b, 0, 0>>>(dVolume, dTriangles);
    }

    //  for (b = 32; b <= threadUpperLimit; b += 32)
    {
        b = 64;
        int gridDim = (m + b - 1) / b;
        getResult<<<gridDim, b, b * sizeof(Triangle), 0>>>(dVolume, dTriangles);
    }

    //for (g = 32; g <= 512; g += 32)
    //  for (b = 32; b <= 1024; b += 32)
    {
        b = 64;
        g = 64;
        getResultOpt<<<g, b, 0, 0>>>(dVolumeOpt, dTriangles, m);
    }

    //for (g = 32; g <= 512; g += 32)
    //  for (b = 32; b <= 1024; b += 32)
    {
        b = 64;
        g = 512;
        cudaFuncSetCacheConfig(getResultOpt, cudaFuncCachePreferL1);
        getResultOpt<<<g, b, 0, 0>>>(dVolumeOpt, dTriangles, m);
    }

    thrust::device_vector<double> X = volume;
    thrust::device_vector<double> Y = volumeOpt;
    thrust::transform(X.begin(), X.end(), Y.begin(), X.begin(), _1 - _2);
    double result = thrust::inner_product(X.begin(), X.end(), X.begin(), 0.0);

    std::cout << "difference: " << result << std::endl;

    return 0;
}

Answer 2

正如Eric的回答所暗示的，你的内核需要9个64位加载和每个线程64位存储，但每个线程只执行17个FLOP。这可能意味着您的代码内存带宽有限，而不是计算有限，并且您不应期望能够达到此类代码的峰值FLOP / s吞吐量。

因此，最佳性能的关键很可能是内存带宽优化。目前，你的内核有几个明显的问题，其中一个是我在评论中提到的。你真的不需要在内核中写入共享内存 - 它比寄存器慢，并且使用它没有内存带宽的改进。 __syncthreads()的使用也会给内核增加不必要的延迟。你的代码可以简单地写成：

__global__ void getresult2(double *d_volume, Triangle *d_triangles)
{
    int i =  blockDim.x * blockIdx.x + threadIdx.x;
    Triangle t = d_triangles[i];
    d_volume[i] = t.x1 * t.y2 * t.z3 + 
                  t.y1 * t.z2 * t.x3 +
                  t.x2 * t.y3 * t.z1 -
                  t.x3 * t.y2 * t.z1 -
                  t.x2 * t.y1 * t.z3 - 
                  t.y3 * t.z2 * t.x1;
}

[免责声明，从未编译或运行，自担风险使用]

我希望它的性能优于共享内存版本。

第二个问题是内存合并问题。你拥有的结构相当大，每个加载Triangle完整实例的线程对内存合并或缓存重用都不是很友好。您可以尝试使用共享内存来提高内存负载性能，并通过执行以下操作来合并写入：

__global__ 
void __launch_bounds__(288, 3)getresult3(double *d_volume, Triangle *d_triangles)
{
    __shared__ double s_data[9*32];

    int i =  blockDim.x * blockIdx.x + threadIdx.x;
    double * t_data = reinterpret_cast<double *>(d_triangles);
    s_data[threadIdx.x] = t_data[i];
    __syncthreads();

    if (threadIdx.x < 32) {
        Triangle * t = reinterpret_cast<Triangle *>(&s_data[9*threadIdx.x]);
        d_volume[i] = t->x1 * t->y2 * t->z3 + 
            t->y1 * t->z2 * t->x3 +
            t->x2 * t->y3 * t->z1 -
            t->x3 * t->y2 * t->z1 -
            t->x2 * t->y1 * t->z3 - 
            t->y3 * t->z2 * t->x1;
    }
}

[免责声明，从未编译或运行，自担风险使用]

这里，288个线程的块在合并的加载中将32个Triangle实例提取到共享内存，然后块中的前32个线程执行计算并存储32个结果。如果内核实际上没有达到全球内存带宽吞吐量的很大一部分，那么这样的方案可能证明更快。 CUDA工具包分析工具具有一些非常有用的性能指标分析，可以帮助查明代码中的性能瓶颈。与所有优化练习一样，关键是仔细分析和基准测试，这是您无处可做的事情。

CUDA并行计算加快了容量计算

2 个答案:

更新