Question

我使用Away3D 4.1（2500立方体）创建了一个简单的测试，但性能比我预期的要低很多 - 只有10 FPS。

我假设我犯了一个noob错误（作为菜鸟和所有人）所以这里是相关的代码片段：

照明：

var light1:DirectionalLight = new DirectionalLight();
light1.position = new Vector3D(400, 300, -200);
light1.lookAt(new Vector3D());
light1.color = 0xFFFFFF;
light1.ambient = 0.25;
lightPicker = new StaticLightPicker([light1]);

创建多维数据集：

var material:ColorMaterial = new ColorMaterial(0x999999);
material.lightPicker = lightPicker;
material.specular = 0;
var mesh:Mesh = new Mesh(new CubeGeometry(50, 50, 50), material);

for (var i:uint = 0; i < 50; i++)
{
    for (var j:uint = 0; j < 50; j++)
    {
        var cube:Mesh = Mesh(mesh.clone());
        cube.x = 100*(i-25);
        cube.y = 25;
        cube.z = 100*(j-25);
        scene.addChild(cube);
    }
}

相机：

camera = new Camera3D();
camera.position = new Vector3D(0, 1000, -5000);
camera.lookAt(new Vector3D(0, 0, 0));
camera.lens.far = 10000;

Scout中的Stage3D输出显示每个drawTriangles调用之间有很多调用，我的基本理解告诉我drawTriangle调用应该是'batched'。

我知道其他一些框架都有批处理方法，但我找不到任何与Away3D相关的内容。

提前感谢您的帮助。

Answer 1

看起来像Merge（感谢Varnius发现它）是推荐使用以前版本的方法，但它在4.1中不起作用（见away3d forum thread）。

然而，用户kurono在论坛中发布了一个有效的解决方案（至少对于我的场景），所以我在这里重现它以防其他人有同样的问题：

var material:ColorMaterial = new ColorMaterial(0x999999);
material.lightPicker = lightPicker;
material.specular = 0;
var mesh:Mesh = new Mesh(new CubeGeometry(50, 50, 50));
var meshes:Vector.<Mesh> = new Vector.<Mesh>();
for (var i:uint = 0; i < 50; i++)
{
    for (var j:uint = 0; j < 50; j++)
    {
        var cube:Mesh = Mesh(mesh.clone());
        cube.x = 100*(i-25);
        cube.y = 25;
        cube.z = 100*(j-25);
        meshes.push(cube);
    }
}
var bigMesh:Mesh = doMerge(meshes, material);
scene.add(bigMesh);

魔术在doMerge（）方法中：

function doMerge(meshes:Vector.<Mesh>, material:MaterialBase):Mesh
{
    var isub:ISubGeometry;
    var rawVertsAll:Vector.<Number> = new Vector.<Number>();
    var rawIndicesAll:Vector.<uint> = new Vector.<uint>();
    var rawUVsAll:Vector.<Number> = new Vector.<Number>();
    var rawNormalsAll:Vector.<Number> = new Vector.<Number>();
    var rawTangentsAll:Vector.<Number> = new Vector.<Number>();
    var offset:uint = 0;
    var verts:Vector.<Number>;
    var normals:Vector.<Number>;
    var tangents:Vector.<Number>;
    var uvs:Vector.<Number>;
    var indices:Vector.<uint>;
    var i:uint;
    var j:uint;
    var k:uint;
    for (k = 0; k < meshes.length; k++)
    {
        var m:Mesh = meshes[k];
        isub = m.geometry.subGeometries[0].cloneWithSeperateBuffers();
        isub.applyTransformation(m.transform.clone());
        verts = new Vector.<Number>();
        normals = new Vector.<Number>();
        tangents = new Vector.<Number>();
        uvs = new Vector.<Number>();
        indices = isub.indexData;
        for (i = 0; i < isub.numVertices; i++)
        {
            verts.push(isub.vertexData[i * isub.vertexStride + isub.vertexOffset]);
            verts.push(isub.vertexData[i * isub.vertexStride + isub.vertexOffset + 1]);
            verts.push(isub.vertexData[i * isub.vertexStride + isub.vertexOffset + 2]);
            normals.push(isub.vertexNormalData[i * isub.vertexNormalStride + isub.vertexNormalOffset]);
            normals.push(isub.vertexNormalData[i * isub.vertexNormalStride + isub.vertexNormalOffset + 1]);
            normals.push(isub.vertexNormalData[i * isub.vertexNormalStride + isub.vertexNormalOffset + 2]);
            tangents.push(isub.vertexTangentData[i * isub.vertexTangentStride + isub.vertexTangentOffset]);
            tangents.push(isub.vertexTangentData[i * isub.vertexTangentStride + isub.vertexTangentOffset + 1]);
            tangents.push(isub.vertexTangentData[i * isub.vertexTangentStride + isub.vertexTangentOffset + 2]);
            uvs.push(isub.UVData[i * isub.UVStride + isub.UVOffset]);
            uvs.push(isub.UVData[i * isub.UVStride + isub.UVOffset + 1]);
        }
        for (j = 0; j < indices.length; j++)
        {
            indices[j] += offset;
        }
        offset += isub.numVertices;
        rawVertsAll = rawVertsAll.concat(verts);
        rawNormalsAll = rawNormalsAll.concat(normals);
        rawTangentsAll = rawTangentsAll.concat(tangents);
        rawUVsAll = rawUVsAll.concat(uvs);
        rawIndicesAll = rawIndicesAll.concat(indices);
    }
    var geometry:Geometry = new Geometry();
    var subGeometry:SubGeometry = new SubGeometry();
    subGeometry.updateVertexData(rawVertsAll);
    subGeometry.updateIndexData(rawIndicesAll);
    subGeometry.updateUVData(rawUVsAll);
    subGeometry.updateVertexNormalData(rawNormalsAll);
    subGeometry.updateVertexTangentData(rawTangentsAll);
    geometry.subGeometries.push(subGeometry);

    return new Mesh(geometry, material);
}

瞧！ 10fps变为60fps

Answer 2

是的，您应该批量绘制调用。我对Away3D没有多少经验，但在快速查看其API参考后，似乎away3d.tools.commands.Merge应该可以帮助您将所有这些立方体合并为一个大型批量网格。

Answer 3

你在调试播放器或发行版中获得10 fps吗？

我运行了你的代码并在调试播放器中获得了20 fps但在发布版本中获得了50+ fps。

我尝试合并，但没有看到任何改进。另外，如果要访问单个多维数据集，合并将使这非常复杂：） enter image description here

Away3D 4.1性能问题 - 如何使用许多相同的网格优化场景？

3 个答案: