Question

我正在为AVR Atmega328p微控制器编写代码。微控制器应该读取编码器，并根据编码器的旋转递增或递减r23。不幸的是，此时输出只会下降，直到它达到0然后从255开始，而不管我转动编码器的方向。

我的代码非常简单，它基于一个表查找值，它结合了编码器的先前状态和当前状态。如果先前状态和当前状态不组合以创建有效转弯，则返回错误并且代码不执行任何操作。如果发生有效的状态变化，则通过r24将1或-1添加到r23。

让微控制器读取编码器没有问题，但我无法弄清楚如何防止r23溢出。我的问题是当我达到255并加1时，寄存器溢出并转到0.我不希望寄存器变为零;我希望它保持在255，直到我以相反的方向旋转编码器。我有同样的问题0.如果寄存器为0并且我加-1，我不希望寄存器转到255，我希望它保持为0直到我向相反方向旋转它。

我在框外思考时没有问题。如果您有解决方案或想法，请随时发布。

;**** A P P L I C A T I O N   N O T E  *************************************
;*
;* Title:       
;* Version:     
;* Last updated:    
;* Target:  AVR Dragon  
;*
;*
;* DESCRIPTION
;*
;*.device   ATmega328P @ 1M  clock speed
;* 
;* This is a simple program to test an optical encoder
;***************************************************************************

.include "m328Pdef.inc"
.org 0x0000
    jmp RESET   ;Reset Handle

.org 0x0008
    jmp Interrupt1 ; PCINT1 Handler

enc_states:
.db 0,-1,1,0,1,0,0,-1,-1,0,0,1,0,1,-1,0 

RESET:

;Setup stack pointer
    ldi temp, low(RAMEND)   
    out SPL, temp
    ldi temp, high(RAMEND)
    out SPH, temp

//Set Port B pins to output
    ser     temp            ; Set Register Rd <-- 0xff (output)
    out     DDRB,temp       ; set all PORTB bits as output

//Clear analog input pins and enable pull ups on Pin 0 and 1 (Port C)
    clr     temp
    out     DDRC, temp      ;all pins input
    ldi     temp, (1<<PC1)|(1<<PC0)
    out     PORTC,temp      ;Enable pullups on Pin 0 and 1

//Set Port D pins to output
    ser     temp            ; Set Register Rd <-- 0xff
    out     DDRD,temp       ; set all PORTD bits as output

//Enable encoder pins interrupt sources (Encoder 1)
    ldi     temp, (1<<PCINT9)|(1<<PCINT8)
    sts     PCMSK1, temp

//Enable encoder pins interrupt sources (Encoder 2)
//  ldi     temp, (1<<PCINT11)|(1<<PCINT10)
//  sts     PCMSK1, temp

//Enable pin change interrupts
    ldi     temp, (1<<PCIE1)
    sts     PCICR, temp

//Enable global interrupts
    sei

//Lookup table initial value
    ldi     ZL, 0x00   ;lookup table index and initial state

.def temp   = r16
    clr     r25
    clr     r24
    clr     r23

loop:
    out PORTB, r23
    jmp loop

Interrupt1:
// Push SREG, etc
    in      r25, PORTC  ;encoder value from PORTC

    ldi   ZH, High(enc_states*2)   ; setup Z pointer hi
    ldi   ZL, Low (enc_states*2)   ; setup Z pointer lo
    rol     r22     ;remember previous state and shift left twice
    rol     r22
    cbr     r25, 0xFC  ;clear encoder bits 7:2
    mov     r21,r25
    or      r25, r22   ;combine encoder bits with old bits
    cbr     r25, 0xF0  ;clear bits 7:4 for table lookup
    mov     r22, r25   ;save table lookup value
    mov     ZL, r25    ;load index value into table
    lpm     r24, z      ;get result
    add     r23,r24

// Pop SREG, etc.
    reti

Answer 1

'Saturation'可以通过利用进位标志非常简单地完成，如：

  mov __tmp_reg__, r23
  add __tmp_reg__, r24   ; do the addition

  brcs saturated          ; if the carry flag is set we have an overflow and should discard the result

    mov r23, __tmp_reg__ ; there was no overflow so we store the result

  saturated:

使用上面的代码替换ISR末尾的add r23,r24，您应该没问题。（显然，您可能需要将__tmp_reg__更改为可用作临时存储的某个寄存器。）

考虑到r24可能是正数，负数或零，所有案例都可以通过稍微扩展上述原则来正确处理：

  mov __tmp_reg__, r23

  tst r24 

  breq doreturn  ; if r24 == 0 we have nothing to do and may just return

  brmi subtract  ; if r24 is 'negative' we need to subtract

    add __tmp_reg__, r24  ; if r24 is not negative we just add
    rjmp store            ; and go to where the result may be stored

  subtract:

    neg r24  ; r24 := -r24
    sub __tmp_reg__, r24   ; do the subtraction

  store:

  brcs doreturn          ; if the carry flag is set we have an overflow and should discard the result

    mov r23, __tmp_reg__ ; there was no overflow so we store the result

  doreturn:

仔细看看你的代码，在我看来，当Z指针的计算完成时，还有另一个'故障'：

ldi   ZH, High(enc_states*2)   ; setup Z pointer hi
ldi   ZL, Low (enc_states*2)   ; setup Z pointer lo

和

mov     ZL, r25    ;load index value into table

看起来有问题：Z地址的下半部分被忽略并被索引值覆盖。如果Low (enc_states*2)不恰好是0，这会造成麻烦;您可能需要执行add ZL, r25和adc ZH, __zero_reg__（16位添加）而不是mov ZL, r25。

另一种想法可能会降低日常工作的复杂性：

增量式旋转编码器的输出可以解释为某种同步串行数据：一个输出（比如'A'）代表'时钟'信号，而另一个输出（'B'）代表'数据'信号。

您可以自由选择哪个输出用于哪个信号，以及您选择的“时钟”极性。该算法非常简单：

（去抖动）检测'时钟'信号上的上升（或下降，你选择）过渡
一旦检测到“时钟”边缘，只需读取“数据”信号的电平 - 此处不需要去抖动
然后读取的单个“数据”位直接指示编码器刚刚进入的方向：“0”或“1”，一个方向或另一个方向。

在伪代码中，这可能看起来像：

bit lastClockState;

void readEncoder() {

    bit currentClockState = readClockPin();

    if ( lastClockState == 1 && currentClockState == 0 ) {
        // A (falling) edge was detected...

        // Get the direction of the rotation:
        bit direction = readDataPin();

        if ( direction == 1 ) {
            value++;
        } else {
            value--;
        }
    }

    lastClockState = currentClockState; // Update the lastClockState for the next iteration

}

让它执行，例如，每10毫秒执行一次，你已经有了一些免费的简约去除功能。

（顺便说一下，总结之前许多人学到的经验：不要试图使用一些外部/引脚更改中断来检测（未去抖动）任何机械开关或机械编码器产生的信号转换重要的是。机械元件的弹跳特性将确保永远不会按预期工作。）

Answer 2

您只需要为边界情况添加一些测试。多年来我没有做任何组装，这段代码可能与您的架构无关，但它类似于：

    lpm     r24, z      ;get result
    cmp     r23, 0
    je      rot_lo      ; if val is 0
    cmp     r23, 255
    je      rot_hi      ; if val is 255
    jmp     rot_add

rot_lo:
    cmp     r24, 0
    jl      rot_ret     ; don't add if delta less than 0
    jmp     rot_add

rot_hi:
    cmp     r24, 0
    jg      rot_ret     ; don't add if delta greater than 0
    jmp     rot_add     ; (or just fall through here)

rot_add:
    add     r23, r24

rot_ret:
    reti

旋转编码器溢出预防

2 个答案: