Question

我想知道是否有人能指出我这样做的有效方法：

最大化6行x 10列数组中所选元素的总和，这样每列中只选择3个元素，每行中选择5个元素。

我没有看到将分配问题（和匈牙利算法）扩展到此任务的简单方法。我们需要为更大的问题做成千上万的这些问题，所以蛮力是不可能的。

Answer 1

正如Vaughn所写，解决问题的一种快速简便的方法是将其转换为Integer Linear Programming问题，然后使用众多专门解算器之一解决问题。那就让我们做吧！

建模

首先，我们需要一种建模语言。我将使用GNU建模语言MathProg，它与AMPL的（子集）非常相似。

我们问题的一般模型：（max.mod）

param rows;
param columns;
param matrix{i in 1..rows, j in 1..columns}; # the input matrix

## the variables of our problem. choose[i,j] = 1 means that we 
## pick element (i,j), otherwise is choose[i,j] = 0
var choose{i in 1..rows, j in 1..columns} binary; 

## the linear function we want to maximize: the sum of all the 
## choosen elements in the matrix.
maximize Sum:
    sum{i in 1..rows, j in 1..columns} choose[i,j] * matrix[i,j];

## first linear constraint: we have to choose exactly 3 elements for each column
subject to Cols{j in 1..columns}:
    sum{i in 1..rows} choose[i,j] = 3;

## second linear constraint: we have to choose exactly 5 elements for each row
subject to Rows{i in 1..rows}:
    sum{j in 1..columns} choose[i,j] = 5;

solve;

## to print the solution
printf "Solution: \n";
for{i in 1..rows}
{
    for{j in 1..columns}
    {
        printf (if choose[i,j] = 1 then "%d " else "- "), matrix[i,j];
    }
    printf "\n";
}
printf "\nSum = %d", sum{i in 1..rows, j in 1..columns} choose[i,j]*matrix[i,j];

我们也需要一个数据文件：（max.dat）

param rows := 6;
param columns := 10;

param matrix : 
    1 2 3 4 5 6 7 8 9 10 :=
1   1 6 9 1 0 7 5 4 3 2
2   9 7 4 6 4 3 2 1 4 9
3   9 6 4 3 2 1 5 7 8 9
4   6 5 4 3 7 8 9 6 4 2
5   7 5 4 3 2 8 9 6 7 8 
6   9 7 6 5 3 9 6 3 2 1;

求解

现在我们需要一个求解器。我将从命令行使用nice GLPK（GNU Linear Programming Kit），但它有一组很好的接口，可用于一堆编程语言。

alberto@alberto-notebook:~/Desktop$ glpsol --model max.mod --data max.dat

INTEGER OPTIMAL SOLUTION FOUND
Time used:   0.0 secs
Memory used: 0.2 Mb (235703 bytes)

Solution: 
- 6 9 - - 7 5 - 3 - 
9 7 - 6 4 - - - - 9 
9 - - 3 - - - 7 8 9 
- - 4 - 7 8 9 6 - - 
- - - - - 8 9 6 7 8 
9 7 6 5 3 - - - - - 

Sum = 203

多分配/矩阵最大化

1 个答案:

建模

求解