Question

我正在尝试从亚马逊的CloudFront / S3服务流式传输视频。尽管我的文件名正确，并且“NetConnection.Connect.Success”状态，我的NetConnection onBWDone回调给我一个“未定义”错误，视频无法播放或出现在舞台上的任何位置。连接报告它成功，所以我不知道问题出在哪里。这是我的代码：

var amazonCloudFrontDomain:String = "myCloudFrontDistributionID.cloudfront.net";
var amazonCloudFrontStreamURL:String = "rtmp://" + amazonCloudFrontDomain + "/cfx/st/";
var videoFileName:String = "myVideo.flv";

Security.allowDomain(amazonCloudFrontDomain);
Security.allowDomain("rtmp://" + amazonCloudFrontDomain);
Security.allowDomain(amazonCloudFrontStreamURL);


var client:Object = new Object();
client.onBWDone   = function(e){trace("onBWDone: " + e);}
client.onMetaData = function(e){trace("onMetaData: " + e);}
client.onCuePoint = function(e){trace("onCuePoint: " + e);}


var video:Video = new Video(300, 400);  //  create a new Video item and set its width and height
video.x = 0;  //  position the video's x position
video.y = 0;  //  position the video's y position
var duration:Number;  //  use this later to get the duration of the video being played
this.addChild(video);

var nc:NetConnection = new NetConnection();  //  variable for a new NetConnection
nc.client = client;
nc.addEventListener(NetStatusEvent.NET_STATUS,netConnectionStatusHandler,false,0,true);
nc.connect(amazonCloudFrontStreamURL);  //  set the nc variable to null

var ns:NetStream;
function netConnectionStatusHandler(e):void
{
    switch(e.info.code)
    {
        case "NetConnection.Connect.Success":
            trace("S3 Connected");

            ns = new NetStream(nc);  // create a variable for a new NetStream connection & connect it to the nc variable
            ns.addEventListener(NetStatusEvent.NET_STATUS, netStreamStatusHandler);  //  add a listener to the NetStream to listen for any changes that happen with the NetStream
            ns.addEventListener(AsyncErrorEvent.ASYNC_ERROR, netStreamAsyncErrorHandler);  //  add a listener to the NetStream for any errors that may happen
            ns.client = client;

            video.attachNetStream(ns);  // attach the NetStream variable to the video object
            video.smoothing = true;
            video.deblocking = 1;

            ns.bufferTime = 5;  // set the buffer time to 5 seconds
            ns.play(videoFileName);  //  tell the netstream what video to play and play it
            break;
    }
    trace(e.info.code);
}


function netStreamAsyncErrorHandler(Event:AsyncErrorEvent):void
{
    // trace(event.text);  // this will handle any errors with video playback
}

function netStreamStatusHandler(event:NetStatusEvent):void
{
    trace(event.info.code);  // this will handle any events that are fired when the video is playing back
    switch(event.info.code)  //  switch statement to handle the various events with the NetConnection
    {

        case "NetStream.Buffer.Full":  //  when the buffer is full fire the code below
            ns.bufferTime = 10;  // set buffer time to 10 seconds       break;
        case "NetStream.Buffer.Empty":  //  when the buffer is empty fire, code below
            ns.bufferTime = 10;  // set buffer time to 10 seconds
        break;
        case "NetStream.Play.Start":  //  when the video starts playing, fire the code below
            ns.bufferTime = 10;  // set the buffer time to 10 seconds
        break;
        case "NetStream.Seek.Notify":  // when you seek with the scrubber it sends a notify signal of the time
            ns.bufferTime = 10;  // set the buffer time to 10 seconds
        break;
        case "NetStream.Seek.InvalidTime":  // when you release the scrubber ahead of the video that has been loaded, you get this error.  it will jump you back to the last frame that has been loaded
            ns.bufferTime = 10;  // set the buffer time to 10 seconds
        break;
        case "NetStream.Play.Stop":  // when you reach the end of the video
            ns.pause();  // pause the video
            ns.seek(1);  // seek the video to the first frame
        break;
    }
}

这是控制台输出：

S3 Connected
netConnectionStatusHandler: NetConnection.Connect.Success
onBWDone: undefined
NetStream.Play.Reset
NetStream.Play.Start

......没有任何反应。没有视频，没有音频，没有。任何人都可以看到我的代码有任何问题吗？

Answer 1

我相信并非所有流应用程序都必须使用onBWDone函数，因此如果它们不使用它，它可能会将null或undefined传递给函数而不是kbps。

因此，下面的跟踪声明中的e可能会出现问题：

client.onBWDone   = function(e){trace("onBWDone: " + e);}

此外，该函数不接收事件对象，而是一个... rest数组，通常只有一个项目。试试这个：

client.onBWDone   = function(... rest){  //
    if(rest && rest.length > 0){  //since the function might not get any data, you need to check before trying to trace it out
        trace("onBWDone: " + rest[0]); //this is the kbps of the bandwidth available
    }
};

您可以在Adobe文档中了解更多信息： http://help.adobe.com/en_US/FlashMediaServer/3.5_Deving/WS5b3ccc516d4fbf351e63e3d11a0773d56e-7ffa.html

修改

关于您的视频路径：

通过rtmp以下格式访问Flash Media Server应用程序：“server：port / application / instance”。对于VOD，instance是您文件的名称，对于FLV，它不需要扩展名。

http://help.adobe.com/en_US/FlashMediaServer/3.5_Deving/WS5b3ccc516d4fbf351e63e3d11a0773cfae-7ff3.html

Answer 2

我改变了

var videoFileName:String = "myVideo.flv";

到

var videoFileName:String = "myVideo";

现在它有效。出于某种原因，排除文件扩展名使其适用于我。我不知道为什么......很奇怪。

视频流：“onBWDone：undefined”，视频无法播放

2 个答案: