Question

我一直在调查Allen Bauer的通用多播事件调度员代码（请参阅他关于它的博客文章here）。

他提供足够的代码让我想要使用它，不幸的是他还没有发布完整的资源。我有一个bash让它工作，但我的汇编技能是不存在的。

我的问题是InternalSetDispatcher方法。天真的方法是使用与其他InternalXXX方法相同的汇编程序：

procedure InternalSetDispatcher;
begin
   XCHG  EAX,[ESP]
   POP   EAX
   POP   EBP
   JMP   SetEventDispatcher
end;

但这用于具有一个const参数的过程，如下所示：

procedure Add(const AMethod: T); overload;

SetDispatcher有两个参数，一个是var：

procedure SetEventDispatcher(var ADispatcher: T; ATypeData: PTypeData);

所以，我认为堆栈会被破坏。我知道代码在做什么（通过弹出对self的隐藏引用来清理堆栈帧从调用到InternalSetDispatcher，我假设返回地址），但我只是无法弄清楚那个小小的汇编程序来获取整个代码事情进展。

编辑：只是为了澄清，我正在寻找的是我可以用来使InternalSetDispatcher方法工作的汇编程序，即汇编程序用两个参数清理一个过程的堆栈，一个是变量。

编辑2：我已经修改了一下这个问题，感谢梅森到目前为止的答案。我应该提一下上面的代码不起作用，当SetEventDispatcher返回时，会引发AV。

Answer 1

在我在Web上进行了大量的操作后，答案是汇编程序假定在调用InternalSetDispatcher时存在堆栈框架。

似乎没有为InternalSetDispatcher调用生成堆栈帧。

因此，修复就像使用{$ stackframes on}编译器指令打开堆栈帧并重建一样简单。

感谢Mason的帮助，让我得到了这个答案。：）

编辑2012-08-08 ：如果您热衷于使用此功能，可能需要查看Delphi Sping Framework中的实施情况。我没有对它进行测试，但看起来它比这段代码更好地处理不同的调用约定。

编辑：根据要求，我对Alan的代码的解释如下。除了需要打开堆栈框架之外，我还需要在项目级别启用优化才能使其正常工作：

unit MulticastEvent;

interface

uses
  Classes, SysUtils, Generics.Collections, ObjAuto, TypInfo;

type

  // you MUST also have optimization turned on in your project options for this
  // to work! Not sure why.
  {$stackframes on}
  {$ifopt O-}
    {$message Fatal 'optimisation _must_ be turned on for this unit to work!'}
  {$endif}
  TMulticastEvent = class
  strict protected
    type TEvent = procedure of object;
  strict private
    FHandlers: TList<TMethod>;
    FInternalDispatcher: TMethod;

    procedure InternalInvoke(Params: PParameters; StackSize: Integer);
    procedure SetDispatcher(var AMethod: TMethod; ATypeData: PTypeData);
    procedure Add(const AMethod: TEvent); overload;
    procedure Remove(const AMethod: TEvent); overload;
    function IndexOf(const AMethod: TEvent): Integer; overload;
  protected
    procedure InternalAdd;
    procedure InternalRemove;
    procedure InternalIndexOf;
    procedure InternalSetDispatcher;

  public
    constructor Create;
    destructor Destroy; override;

  end;

  TMulticastEvent<T> = class(TMulticastEvent)
  strict private
    FInvoke: T;
    procedure SetEventDispatcher(var ADispatcher: T; ATypeData: PTypeData);
  public
    constructor Create;
    procedure Add(const AMethod: T); overload;
    procedure Remove(const AMethod: T); overload;
    function IndexOf(const AMethod: T): Integer; overload;

    property Invoke: T read FInvoke;
  end;

implementation

{ TMulticastEvent }

procedure TMulticastEvent.Add(const AMethod: TEvent);
begin
  FHandlers.Add(TMethod(AMethod))
end;

constructor TMulticastEvent.Create;
begin
  inherited;
  FHandlers := TList<TMethod>.Create;
end;

destructor TMulticastEvent.Destroy;
begin
  ReleaseMethodPointer(FInternalDispatcher);
  FreeAndNil(FHandlers);
  inherited;
end;

function TMulticastEvent.IndexOf(const AMethod: TEvent): Integer;
begin
  result := FHandlers.IndexOf(TMethod(AMethod));
end;

procedure TMulticastEvent.InternalAdd;
asm
  XCHG  EAX,[ESP]
  POP   EAX
  POP   EBP
  JMP   Add
end;

procedure TMulticastEvent.InternalIndexOf;
asm
  XCHG  EAX,[ESP]
  POP   EAX
  POP   EBP
  JMP   IndexOf
end;

procedure TMulticastEvent.InternalInvoke(Params: PParameters; StackSize: Integer);
var
  LMethod: TMethod;
begin
  for LMethod in FHandlers do
  begin
    // Check to see if there is anything on the stack.
    if StackSize > 0 then
      asm
        // if there are items on the stack, allocate the space there and
        // move that data over.
        MOV ECX,StackSize
        SUB ESP,ECX
        MOV EDX,ESP
        MOV EAX,Params
        LEA EAX,[EAX].TParameters.Stack[8]
        CALL System.Move
      end;
    asm
      // Now we need to load up the registers. EDX and ECX may have some data
      // so load them on up.
      MOV EAX,Params
      MOV EDX,[EAX].TParameters.Registers.DWORD[0]
      MOV ECX,[EAX].TParameters.Registers.DWORD[4]
      // EAX is always "Self" and it changes on a per method pointer instance, so
      // grab it out of the method data.
      MOV EAX,LMethod.Data
      // Now we call the method. This depends on the fact that the called method
      // will clean up the stack if we did any manipulations above.
      CALL LMethod.Code
    end;
  end;
end;

procedure TMulticastEvent.InternalRemove;
asm
  XCHG  EAX,[ESP]
  POP   EAX
  POP   EBP
  JMP   Remove
end;

procedure TMulticastEvent.InternalSetDispatcher;
asm
  XCHG  EAX,[ESP]
  POP   EAX
  POP   EBP
  JMP   SetDispatcher;
end;

procedure TMulticastEvent.Remove(const AMethod: TEvent);
begin
  FHandlers.Remove(TMethod(AMethod));
end;

procedure TMulticastEvent.SetDispatcher(var AMethod: TMethod;
  ATypeData: PTypeData);
begin
  if Assigned(FInternalDispatcher.Code) and Assigned(FInternalDispatcher.Data) then
    ReleaseMethodPointer(FInternalDispatcher);
  FInternalDispatcher := CreateMethodPointer(InternalInvoke, ATypeData);
  AMethod := FInternalDispatcher;
end;

{ TMulticastEvent<T> }

procedure TMulticastEvent<T>.Add(const AMethod: T);
begin
  InternalAdd;
end;

constructor TMulticastEvent<T>.Create;
var
  MethInfo: PTypeInfo;
  TypeData: PTypeData;
begin
  MethInfo := TypeInfo(T);
  TypeData := GetTypeData(MethInfo);
  inherited Create;
  Assert(MethInfo.Kind = tkMethod, 'T must be a method pointer type');
  SetEventDispatcher(FInvoke, TypeData);
end;

function TMulticastEvent<T>.IndexOf(const AMethod: T): Integer;
begin
  InternalIndexOf;
end;

procedure TMulticastEvent<T>.Remove(const AMethod: T);
begin
  InternalRemove;
end;

procedure TMulticastEvent<T>.SetEventDispatcher(var ADispatcher: T;
  ATypeData: PTypeData);
begin
  InternalSetDispatcher;
end;

end.

Answer 2

来自博文：

此功能的作用是删除本身和来自的直接来电者呼叫链并直接转移控制到相应的“不安全” 保留传入的方法参数（一个或多个）。

代码消除了InternalAdd的堆栈帧，它只有一个参数Self。它对您传入的事件没有影响，因此只使用一个参数和寄存器调用约定复制任何其他函数是安全的。

编辑：在回复评论时，您有一点缺失。当你写下“我知道代码在做什么（从父调用中清理堆栈帧）时，”你错了。 它不会触及父呼叫。它不是从Add清理堆栈帧，而是从当前调用InternalAdd清理堆栈帧。

这里有一些基本的OO理论，因为你在这一点上似乎有点困惑，我承认这有点令人困惑。添加不真的有一个参数，而SetEventDispatcher没有两个参数。他们实际上分别有两个和三个。未声明为 static 的任何方法调用的第一个参数是Self，并且编译器无形地添加它。所以三个内部函数都有一个参数。这就是我写这篇文章时的意思。

Allen的代码正在做的是解决编译器限制。每个事件都是一个方法指针，但是对于泛型没有“方法约束”，因此编译器不知道T总是会成为可以转换为TMethod的8字节记录。（事实上，它不一定是。如果你真的想以新的和有趣的方式打破你的程序，你可以创建一个TMulticastEvent<byte>。）内部方法使用程序集通过剥离自己来手动模拟类型转换调用堆栈完全和JMPing（基本上是GOTO）到适当的方法，留下与调用它的函数相同的参数列表。

所以当你看到

procedure TMulticastEvent.Add(const AMethod: T);
begin
  InternalAdd;
end;

它正在做的事情等同于以下内容，如果它会编译：

procedure TMulticastEvent.Add(const AMethod: T);
begin
  Add(TEvent(AMethod));
end;

你的InternalSetDispatcher想要做同样的事情：剥离它自己的单参数调用，然后跳转到SetDispatcher，其参数列表与调用方法SetEventDispatcher完全相同。调用函数具有什么参数或它跳转到的函数无关紧要。重要的是（这很关键！）是SetEventDispatcher和SetDispatcher具有相同的调用签名。

所以是的，您发布的假设代码将正常工作，并且不会破坏调用堆栈。

让Allen Bauer的TMulticastEvent <t>工作</t>

2 个答案: