Question

我经常需要将函数应用于非常大的DataFrame（混合数据类型）的组，并希望利用多个核心。

我可以从组中创建一个迭代器并使用多处理模块，但效率不高，因为每个组和函数的结果都必须在进程之间进行消息传递。

有没有办法避免酸洗甚至完全避免复制DataFrame？看起来多处理模块的共享内存函数仅限于numpy数组。还有其他选择吗？

Answer 1

从上面的评论来看，这似乎计划在pandas一段时间（我刚刚注意到这里也是一个有趣的rosetta project。

然而，在将pandas中的每个并行功能合并到一起之前，我注意到它很容易编写高效的＆amp;使用cython + OpenMP和C ++直接复制到pandas的并行扩充。

以下是编写并行groupby-sum的简短示例，其用法如下：

import pandas as pd
import para_group_demo

df = pd.DataFrame({'a': [1, 2, 1, 2, 1, 1, 0], 'b': range(7)})
print para_group_demo.sum(df.a, df.b)

，输出为：

注意毫无疑问，这个简单示例的功能最终将成为pandas的一部分。但是，有些事情在C ++中进行并行化一段时间会更自然，要知道将它组合到pandas是多么容易，这很重要。

为此，我编写了一个简单的单源文件扩展名，其代码如下。

首先是一些导入和类型定义

from libc.stdint cimport int64_t, uint64_t
from libcpp.vector cimport vector
from libcpp.unordered_map cimport unordered_map

cimport cython
from cython.operator cimport dereference as deref, preincrement as inc
from cython.parallel import prange

import pandas as pd

ctypedef unordered_map[int64_t, uint64_t] counts_t
ctypedef unordered_map[int64_t, uint64_t].iterator counts_it_t
ctypedef vector[counts_t] counts_vec_t

C ++ unordered_map类型用于由单个线程求和，vector用于所有线程的求和。

现在到函数sum。它从typed memory views开始，以便快速访问：

def sum(crit, vals):
    cdef int64_t[:] crit_view = crit.values
    cdef int64_t[:] vals_view = vals.values

该函数继续将半等分为线程（此处硬编码为4），并让每个线程对其范围内的条目求和：

    cdef uint64_t num_threads = 4
    cdef uint64_t l = len(crit)
    cdef uint64_t s = l / num_threads + 1
    cdef uint64_t i, j, e
    cdef counts_vec_t counts
    counts = counts_vec_t(num_threads)
    counts.resize(num_threads)
    with cython.boundscheck(False):
        for i in prange(num_threads, nogil=True): 
            j = i * s
            e = j + s
            if e > l:
                e = l
            while j < e:
                counts[i][crit_view[j]] += vals_view[j]
                inc(j)

当线程完成后，函数会将所有结果（来自不同范围）合并为一个unordered_map：

    cdef counts_t total
    cdef counts_it_t it, e_it
    for i in range(num_threads):
        it = counts[i].begin()
        e_it = counts[i].end()
        while it != e_it:
            total[deref(it).first] += deref(it).second
            inc(it)

剩下的就是创建一个DataFrame并返回结果：

    key, sum_ = [], []
    it = total.begin()
    e_it = total.end()
    while it != e_it:
        key.append(deref(it).first)
        sum_.append(deref(it).second)
        inc(it)

    df = pd.DataFrame({'key': key, 'sum': sum_})
    df.set_index('key', inplace=True)
    return df

有效地将函数并行应用于分组的pandas DataFrame

1 个答案: