Question

我想将BitmapData缩放到不同的尺寸，例如200,400,600和800.

这样做的好方法是什么？

Answer 1

您不能直接缩放BitmapData，但可以对其进行缩放克隆。以下是缩放BitmapData：

的快速示例

package {
import flash.display.Bitmap;
import flash.display.BitmapData;
import flash.display.Sprite;
import flash.geom.Matrix;

import mx.core.BitmapAsset;

public class Test extends Sprite {


    [Embed(source="test.jpg")]
    private var Image:Class;

    public function Test() {

        var originalBitmapData:BitmapData = BitmapAsset(new Image()).bitmapData;

        function scaleBitmapData(bitmapData:BitmapData, scale:Number):BitmapData {
            scale = Math.abs(scale);
            var width:int = (bitmapData.width * scale) || 1;
            var height:int = (bitmapData.height * scale) || 1;
            var transparent:Boolean = bitmapData.transparent;
            var result:BitmapData = new BitmapData(width, height, transparent);
            var matrix:Matrix = new Matrix();
            matrix.scale(scale, scale);
            result.draw(bitmapData, matrix);
            return result;
        }

        var bitmapA:Bitmap = new Bitmap(originalBitmapData);
        addChild(bitmapA);

        var bitmapB:Bitmap = new Bitmap(scaleBitmapData(originalBitmapData, 0.5));
        addChild(bitmapB);

    }
}
}

Answer 2

设置位图对象的宽度和高度会缩放该图像，因此使用bitmapData创建位图，然后使用宽度/高度进行缩放，或者如果要使用缩放值，则使用scaleX / Y.

var bmp:Bitmap = new Bitmap(bmpData);
bmp.width = 400; //  or 600,800 etc.
bmp.height = 400;

如果您不想使用位图对象并直接缩放BitmapData，请参阅此内容 What is the best way to resize a BitmapData object?

AS3 - 缩放BitmapData

2 个答案: