Question

我有很多pdf文档要合并在一起，所以我写了这段代码来做。它适用于我只有两个pdf文档要合并的情况，但是如果我给它两个以上，那么额外的文档会出现乱码。你能帮我找到什么问题吗？

#!/usr/bin/perl

use PDF::API2;
use List::Util qw( reduce );


# Given two pdfs and a page number, appends the given page of the second pdf to the first pdf
sub append_page_to_pdf {
    my ( $pdf1, $pdf2, $pg ) = @_;
    $pdf1->importpage( $pdf2, $pg );
}

# Given two pdfs, appends the second to the first.  Closes pdf2
sub merge_2_pdfs {
    my ($pdf1, $pdf2) = @_;
    map &append_page_to_pdf( $pdf1, $pdf2, $_ ), 1..$pdf2->pages;
    $pdf2->end;
    return $pdf1;
}

# does what it says
sub open_pdf {
    my $file = $_[0];
    my $pdf = PDF::API2->open( $file );
    print "Opened pdf ( $file )\n";
    return $pdf;
}

# reduces merge_2_pdfs over an array of pdfs
sub merge_pdfs {
    my @files = @_;
    my $starting_filename = shift @files;
    my $start_pdf = &open_pdf( $starting_filename );
    my $final_pdf = reduce { &merge_2_pdfs( $a, &open_pdf( $b ) ) } $start_pdf, @files;
    return $final_pdf;
}

# Get the arguments ie save_name, file1, file2, file3, ...
my @files = @ARGV;
my $save_name = shift @files;
my $save = &merge_pdfs( @files );
$save->saveas( $save_name );

Answer 1

代码中的实际问题是因为在合并之前你有shift个文件关闭了。

my $save_name = shift @files; 
# which should be 
my $save_name = $files[0];

否则，代码实际上有效，我没有发现任何乱码。

一些提示：

use strict和use warnings
现在的一般做法是省略子程序调用中的&。 See here表示该规则的例外情况。

在这种情况下，子程序会使您的代码变得冗长，这使得它更难以遵循。这里有一些更简洁的东西。

use strict;
use warnings;
use List::Util 'reduce';
use PDF::API2;

my $new
  = reduce { $a->importpage($b, $_) foreach 1 .. $b->pages; $a }
    map { PDF::API2->open($_) }
    @ARGV;
$new->saveas('new.pdf');

一个简单的循环比使用reduce更简单易读。

use PDF::API2;

my $new = PDF::API2->new;
foreach my $filename (@ARGV) {
    my $pdf = PDF::API2->open($filename);
    $new->importpage($pdf, $_) foreach 1 .. $pdf->pages;
}
$new->saveas('new.pdf');

Answer 2

PDF::Reuse

prFile('myFile.pdf');
for my $pdf (@PDFS) {
    prDoc($pdf);
}
prEnd();

Answer 3

另一种可能性是我的图书馆，CAM::PDF。

my $pdf1 = CAM::PDF->new($file1) or die;
my $pdf2 = CAM::PDF->new($file2) or die;
my $pdf3 = CAM::PDF->new($file3) or die;
$pdf1->appendPDF($pdf2);
$pdf1->appendPDF($pdf3);
$pdf1->cleanoutput($outfile);

或者将它包装在@ARGV上的循环中。对于两个PDF，我有一个简单的cmdline包装器来做同样的事情：

appendpdf.pl file1.pdf file2.pdf out.pdf

如何使用PDF :: API2将多个pdf合并为一个与Perl？

3 个答案: